Silvaco TCAD（一）结构搭建

步骤一：使用atlas工具，simflags="-P 3"表示使用3颗CPU执行仿真计算

go atlas simflags="-P 3"

步骤二：创建网格 

首先设置网格基准，默认为1

Mesh

如果是三维建模则如下

#Mesh three.d

接下来设置网格mesh，坐标单位默认是微米(um). loc表示在哪里画一条网格线，spac表示在loc附近按照设定值进行画网格线

x.mesh loc=0 spac=0.05

x.mesh loc=0.1 spac=0.02

x.mesh loc=0.35 spac=0.01

x.mesh loc=0.6 spac=0.1

x.mesh loc=0.85 spac=0.01

x.mesh loc=1.1 spac=0.02

x.mesh loc=1.2 spac=0.1

上面是在垂直x轴方向画线，下面是在垂直y轴方向上画线

y.mesh loc=-0.3 spac=0.05

y.mesh loc=-0.21 spac=0.05

y.mesh loc=-0.01 spac=0.002

y.mesh loc=0 spac=0.002

y.mesh loc=10 spac=1

更准确的网格划分

x.mesh loc=0 spac=0.05

x.mesh loc=0.1 spac=0.05

x.mesh loc=0.1 spac=0.01

x.mesh loc=0.6 spac=0.01

x.mesh loc=0.6 spac=0.03

x.mesh loc=0.85 spac=0.03

x.mesh loc=0.85 spac=0.02

x.mesh loc=1.1 spac=0.02

x.mesh loc=1.1 spac=0.1

x.mesh loc=1.2 spac=0.1

三维的话需要加上z轴

#z.mesh loc=0 spac=0.05

#z.mesh loc=0.3507 spac=0.05

#z.mesh loc=0.4007 spac=0.05

步骤三：搭建结构

首先对上面的网格进行区域划分，region关键字，然后区域编号，给出区域（矩形）范围，给定区域材料，网格所有区域都要有材料覆盖，没有的用air替代

region number=1 x.min=0 x.max=1.2 y.min=0 y.max=10 material=silicon

region number=2 x.min=0 x.max=1.2 y.min=-0.3 y.max=0 material=oxide

指sio2

region number=3 x.min=0.35 x.max=0.85 y.min=-0.21 y.max=-0.01 material=poly

指polysilicon多晶硅

region number=4 x.min=0.35 x.max=0.85 y.min=-0.3 y.max=-0.21 material=aluminum

region number=5 x.min=0 x.max=0.1 y.min=-0.3 y.max=0.0 material=aluminum

region number=6 x.min=1.1 x.max=1.2 y.min=-0.3 y.max=0.0 material=aluminum

三维在选择区域的时候要选择三维区域

#region num=1 material=silicon x.min=0 x.max=1 y.min=0 y.max=2.1 z.min=0 z.max=0.05

#region num=2 material=SiO2 x.min=0 x.max=1 y.min=0 y.max=2.1  z.min=0.05 z.max=0.35

#region num=3 material=iron x.min=0 x.max=1 y.min=0 y.max=2.1  z.min=0.35 z.max=0.3507

设置电极，electrode是关键字，reg表示设置的区域，name就是电极名字

electrode reg=4 name=gate

electrode reg=5 name=source

electrode reg=6 name=drain

electrode bottom name=substrate

下面是对各个区域做掺杂，doping还是关键字，uniform表示均匀掺杂，然后设置要掺杂的区域，选定p/n型掺杂，给定掺杂浓度

doping uniform region=1 x.min=0 x.max=1.2 y.min=0 y.max=10 p.type concentration=1e17

doping uniform region=3 x.min=0.35 x.max=0.85 y.min=-0.21 y.max=-0.01 n.type concentration=5e20

uniform -> gauss 就是表示高斯掺杂，区域只给x值，表示横向扩散，然后junc是结深，rat是扩散比率（一般都是0.6~0.7），conc是结处的浓度

doping gauss region=1 x.min=0 x.max=1.2 junc=0.02 rat=0.6 p.type concentration=5e17

doping gauss region=1 x.min=0 x.max=0.35 junc=0.05 rat=0.6 n.type concentration=4e18

doping gauss region=1 x.min=0.85 x.max=1.2 junc=0.05 rat=0.6 n.type concentration=4e18

doping gauss region=1 x.min=0 x.max=0.15 junc=0.2 rat=0.6 n.type concentration=5e20

doping gauss region=1 x.min=1.05 x.max=1.2 junc=0.2 rat=0.6 n.type concentration=5e20

自定义材料

#material material=MoS2 user.group=conductor user.default=polysilicon permittivity=7.71\

 eg300=1.3 affinity=4 mun=8 nc300=7e19 nv300=1.2e20

步骤四：保存结构

输出文件，命名为nMOS_atlas.str

save outf=nMOS_atlas.str

也可以直接通过下面导入网格文件 inf可以理解为 input file

#mesh inf=nMOS_atlas.str