如何在一个正交相机下，控制物体切换透视/正交渲染

Javier_Wang

已于 2023-11-30 19:32:35 修改

阅读量293

点赞数

分类专栏： unity 文章标签： unity

于 2023-11-14 19:56:41 首次发布

本文链接：https://blog.csdn.net/Gril_Wang/article/details/134406317

版权

unity 专栏收录该内容

1 篇文章 0 订阅

订阅专栏

此需求，需要理解unity常用几个空间的概念及作用

模型空间：模型本身的顶点，片面，法线等信息
世界空间：模型在世界中的信息
观察空间：模型在摄像机照射区域中的信息
裁剪空间：模型在屏幕空间上的信息
在这里插入图片描述

实现思路：

现象1：一个模型的数据在转换到观察空间之前，对于透视摄像机和正交摄像机而言，数据是一致的。
现象2: 正交摄像机和透视摄像机的共有属性，nearClipPlane，farClipPlane
现象3：正交摄像机的重点属性，orthographicSize（视口大小）
现象4：透视摄像机的重点属性，fov（视锥夹角）
现象5：我们在固定正交相机和透视相机的位置后，在某个平面上找到摄像机视口完全重叠的一个平面
现象6：这个平面经过视锥口角度的限制调整后，就是透视，没有视锥角度的限制就是正交
我们是否可以根据正交相机的参数，模拟出透视相机的视锥角度？

解决方案：

1. 解决视锥角度的计算
我们可以基于摄像机自身视口前方固定距离的位置，画一个板，并圈出正交相机的视口，如下图
在这里插入图片描述

我们可以根据图上信息，求出角c的角度。用角c的2倍作为透视相机的视锥角度。
2. 解决观察矩阵的转化
好在unity有现成的算法，套用一下即可得出正交摄像机到透视摄像机的转化矩阵

float fov = 2f * Mathf.Rad2Deg * Mathf.Atan2(m_camera.orthographicSize, Mathf.Abs(m_camera.transform.position.z));//这一步的做法是让同一深度的物体，透视和正交比例一致
Matrix4x4 projmtx = Matrix4x4.Perspective(fov, m_camera.aspect, m_camera.nearClipPlane, m_camera.farClipPlane);
Matrix4x4 proj = GL.GetGPUProjectionMatrix(projmtx, false);

3. 指定某个物体是否转化为透视渲染
我们需要改造下shader，默认的顶点算法，是直接将模型顶点数据转化成裁剪空间的数据，如下

o.vertex = UnityObjectToClipPos(v.vertex);//计算正交投影

这段代码是经过Unity封装后的，方法内部实现如下

// Tranforms position from object to homogenous space  
inline float4 UnityObjectToClipPos(in float3 pos)  
{  
    // More efficient than computing M*VP matrix product  
    //模型空间转到世界空间，再转到裁剪空间
    return mul(UNITY_MATRIX_VP, mul(unity_ObjectToWorld, float4(pos, 1.0)));  
}

我们需要动的是在从模型空间转换到观察空间时，算上我们得出的转化矩阵，如下

//观察空间mul模型空间 裁剪空间
   o.vertex = mul(mul(_PerspCamProj, UNITY_MATRIX_MV), v.vertex);// 计算透视投影
   o.vertex.z = p.z * o.vertex.w;//修正齐次坐标w

4. 最终shader（基于Half-lambert光照模型，理论上standard shader也是改的，不过没找到可编辑的standard）

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unlit/Test"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal: NORMAL;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
                float3 worldNormal: TEXCOORD1;
                float3 worldPos:TEXCOORD2;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            uniform float4x4 _PerspCamProj;

            v2f vert (appdata v)
            {
                v2f o;
                float4 p = UnityObjectToClipPos(v.vertex);
                o.vertex = mul(mul(_PerspCamProj, UNITY_MATRIX_MV), v.vertex);
                o.vertex.y *= -1;//在第二个项目里使用时发现y轴反掉了，目前还不确定是什么原因╮(╯▽╰)╭
                o.vertex.z = p.z * o.vertex.w;

                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                o.worldNormal = normalize(UnityObjectToWorldNormal(v.normal));

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);

                float3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos);
                float Nol = dot(i.worldNormal, worldLightDir);
                float halfLambert = Nol * 0.5 + 0.5;
                return col*halfLambert;
            }
            ENDCG
        }
    }
}

//摄像机fov计算
float fov = 2f * Mathf.Rad2Deg * Mathf.Atan2(m_camera.orthographicSize, Mathf.Abs(m_camera.transform.position.z));
Matrix4x4 projmtx = Matrix4x4.Perspective(fov, m_camera.aspect, m_camera.nearClipPlane, m_camera.farClipPlane);
Matrix4x4 proj = GL.GetGPUProjectionMatrix(projmtx, false);
Shader.SetGlobalMatrix("_PerspCamProj", proj);

效果如下：

https://live.csdn.net/v/343446

文章参考：
Unity Shader入门精要笔记 UNITY_MATRIX_MVP 和 _worldspacecamerapos
Unity3D正交-透视混合相机的实现
 Hi Shader