08_SPI-Flash 扇区擦除实验

最新推荐文章于 2024-07-20 23:36:24 发布
最新推荐文章于 2024-07-20 23:36:24 发布
阅读量906 收藏
点赞数
分类专栏： # Verilog学习强化案例 文章标签： fpga开发
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/HeElLose/article/details/131654996
版权
该文描述了一个针对SPI-Flash的扇区擦除实验，目标是擦除特定扇区以阻止流水灯程序运行。实验涉及扇区擦除指令、操作时序以及相应的硬件模块设计。在RTL层面，展示了状态机控制扇区擦除的过程，并提供了Testbench进行仿真验证。
摘要由CSDN通过智能技术生成

08_SPI-Flash 扇区擦除实验

1. 实验目标

编写扇区擦除工程，擦除事先烧录到 Flash 中的流水灯程序所占的某个扇区，使流水灯程序不能正常工作。在此次实验工程，我们选择擦除第 0 个扇区，擦除地址为24’h00_04_25。

2. 操作时序

2.1 扇区擦除操作指令

扇区擦除(Sector Erase)操作，简称 SE，操作指令为 8’b1101_0000(D8h)。
在这里插入图片描述

2.2 完整扇区擦除操作时序

在这里插入图片描述
在这里插入图片描述
在这里插入图片描述

3. 程序框图

3.1 顶层框图

在这里插入图片描述

3.2 扇区擦除模块

在这里插入图片描述
在这里插入图片描述

4. 波形图

在这里插入图片描述
在这里插入图片描述

5. RTL

5.1 flash_se_ctrl

`timescale  1ns/1ns




module  flash_se_ctrl
(
    input   wire    sys_clk     ,   //系统时钟，频率50MHz
    input   wire    sys_rst_n   ,   //复位信号,低电平有效
    input   wire    key         ,   //按键输入信号

    output  reg     cs_n        ,   //片选信号
    output  reg     sck         ,   //串行时钟
    output  reg     mosi            //主输出从输入数据
);

//********************************************************************//
//****************** Parameter and Internal Signal *******************//
//********************************************************************//

//parameter define
parameter   IDLE    =   4'b0001 ,   //初始状态
            WR_EN   =   4'b0010 ,   //写状态
            DELAY   =   4'b0100 ,   //等待状态
            SE      =   4'b1000 ;   //扇区擦除状态
parameter   WR_EN_INST  =   8'b0000_0110,   //写使能指令
            SE_INST     =   8'b1101_1000;   //扇区擦除指令
parameter   SECTOR_ADDR =   8'b0000_0000,   //扇区地址
            PAGE_ADDR   =   8'b0000_0100,   //页地址
            BYTE_ADDR   =   8'b0010_0101;   //字节地址

//reg   define
reg     [3:0]   cnt_byte;   //字节计数器
reg     [3:0]   state   ;   //状态机状态
reg     [4:0]   cnt_clk ;   //系统时钟计数器
reg     [1:0]   cnt_sck ;   //串行时钟计数器
reg     [2:0]   cnt_bit ;   //比特计数器

//********************************************************************//
//***************************** Main Code ****************************//
//********************************************************************//

//cnt_clk:系统时钟计数器，用以记录单个字节
always@(posedge sys_clk or  negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        cnt_clk  <=  5'd0;
    else    if(state != IDLE)
        cnt_clk  <=  cnt_clk + 1'b1;

//cnt_byte:记录输出字节个数和等待时间
always@(posedge sys_clk or  negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        cnt_byte    <=  4'd0;
    else    if((cnt_clk == 5'd31) && (cnt_byte == 4'd9))
        cnt_byte    <=  4'd0;
    else    if(cnt_clk == 31)
        cnt_byte    <=  cnt_byte + 1'b1;

//cnt_sck:串行时钟计数器，用以生成串行时钟
always@(posedge sys_clk or  negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        cnt_sck <=  2'd0;
    else    if((state == WR_EN) && (cnt_byte == 1'b1))
        cnt_sck <=  cnt_sck + 1'b1;
    else    if((state == SE) && (cnt_byte >= 4'd5) && (cnt_byte <= 4'd8))
        cnt_sck <=  cnt_sck + 1'b1;

//cs_n:片选信号
always@(posedge sys_clk or  negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        cs_n    <=  1'b1;
    else    if(key == 1'b1)
        cs_n    <=  1'b0;
    else    if((cnt_byte == 4'd2) && (cnt_clk == 5'd31) && (state == WR_EN))
        cs_n    <=  1'b1;
    else    if((cnt_byte == 4'd3) && (cnt_clk == 5'd31) && (state == DELAY))
        cs_n    <=  1'b0;
    else    if((cnt_byte == 4'd9) && (cnt_clk == 5'd31) && (state == SE))
        cs_n    <=  1'b1;

//sck:输出串行时钟
always@(posedge sys_clk or  negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        sck <=  1'b0;
    else    if(cnt_sck == 2'd0)
        sck <=  1'b0;
    else    if(cnt_sck == 2'd2)
        sck <=  1'b1;

//cnt_bit:高低位对调，控制mosi输出
always@(posedge sys_clk or  negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        cnt_bit <=  3'd0;
    else    if(cnt_sck == 2'd2)
        cnt_bit <=  cnt_bit + 1'b1;

//state:两段式状态机第一段，状态跳转
always@(posedge sys_clk or  negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        state   <=  IDLE;
    else
    case(state)
        IDLE:   if(key == 1'b1)
                state   <=  WR_EN;
        WR_EN:  if((cnt_byte == 4'd2) && (cnt_clk == 5'd31))
                state   <=  DELAY;
        DELAY:  if((cnt_byte == 4'd3) && (cnt_clk == 5'd31))
                state   <=  SE;
        SE:     if((cnt_byte == 4'd9) && (cnt_clk == 5'd31))
                state   <=  IDLE;
        default:    state   <=  IDLE;
    endcase

//mosi:两段式状态机第二段，逻辑输出
always@(posedge sys_clk or  negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        mosi    <=  1'b0;
    else    if((state == WR_EN) && (cnt_byte == 4'd2))
        mosi    <=  1'b0;
    else    if((state == SE) && (cnt_byte == 4'd9))
        mosi    <=  1'b0;
    else    if((state == WR_EN) && (cnt_byte == 4'd1) && (cnt_sck == 5'd0))
        mosi    <=  WR_EN_INST[7 - cnt_bit];  //写使能指令
    else    if((state == SE) && (cnt_byte == 4'd5) && (cnt_sck == 5'd0))
        mosi    <=  SE_INST[7 - cnt_bit];    //扇区擦除指令
    else    if((state == SE) && (cnt_byte == 4'd6) && (cnt_sck == 5'd0))
        mosi    <=  SECTOR_ADDR[7 - cnt_bit];  //扇区地址
    else    if((state == SE) && (cnt_byte == 4'd7) && (cnt_sck == 5'd0))
        mosi    <=  PAGE_ADDR[7 - cnt_bit];    //页地址
    else    if((state == SE) && (cnt_byte == 4'd8) && (cnt_sck == 5'd0))
        mosi    <=  BYTE_ADDR[7 - cnt_bit];    //字节地址

endmodule

5.2 spi_flash_se

`timescale  1ns/1ns




module  spi_flash_se
(
    input   wire    sys_clk     ,   //系统时钟，频率50MHz
    input   wire    sys_rst_n   ,   //复位信号,低电平有效
    input   wire    pi_key      ,   //按键输入信号

    output  wire    cs_n        ,   //片选信号
    output  wire    sck         ,   //串行时钟
    output  wire    mosi            //主输出从输入数据
);

//********************************************************************//
//****************** Parameter and Internal Signal *******************//
//********************************************************************//
//parameter define
parameter   CNT_MAX =   20'd999_999;    //计数器计数最大值

//wire  define
wire    po_key  ;

//********************************************************************//
//*************************** Instantiation **************************//
//********************************************************************//
//------------- key_filter_inst -------------
key_filter
#(
    .CNT_MAX    (CNT_MAX    )   //计数器计数最大值
)
key_filter_inst
(
    .sys_clk    (sys_clk    ),  //系统时钟，频率50MHz
    .sys_rst_n  (sys_rst_n  ),  //复位信号,低电平有效
    .key_in     (pi_key     ),  //按键输入信号

    .key_flag   (po_key     )   //消抖后信号
);

//------------- flash_se_ctrl_inst -------------
flash_se_ctrl  flash_se_ctrl_inst
(
    .sys_clk    (sys_clk    ),  //系统时钟，频率50MHz
    .sys_rst_n  (sys_rst_n  ),  //复位信号,低电平有效
    .key        (po_key     ),  //按键输入信号

    .sck        (sck        ),  //片选信号
    .cs_n       (cs_n       ),  //串行时钟
    .mosi       (mosi       )   //主输出从输入数据
);

endmodule

6. Testbench

6.1 tb_flash_se_ctrl

`timescale  1ns/1ns




module  tb_flash_se_ctrl();

//wire  define
wire    cs_n;
wire    sck ;
wire    mosi ;

//reg   define
reg     sys_clk     ;
reg     sys_rst_n   ;
reg     key         ;

//时钟、复位信号、模拟按键信号
initial
    begin
        sys_clk     =   0;
        sys_rst_n   <=  0;
        key <=  0;
        #100
        sys_rst_n   <=  1;
        #1000
        key <=  1;
        #20
        key <=  0;
    end

always  #10 sys_clk <=  ~sys_clk;

//写入Flash仿真模型初始值(全F)
defparam memory.mem_access.initfile = "initmemory.txt";

//------------- flash_se_ctrl_inst -------------
flash_se_ctrl  flash_se_ctrl_inst
(
    .sys_clk    (sys_clk    ),  //系统时钟，频率50MHz
    .sys_rst_n  (sys_rst_n  ),  //复位信号,低电平有效
    .key        (key        ),  //按键输入信号
                                
    .sck        (sck        ),  //串行时钟
    .cs_n       (cs_n       ),  //片选信号
    .mosi       (mosi       )   //主输出从输入数据
);

//------------- memory -------------
m25p16  memory
(
    .c          (sck    ),  //输入串行时钟,频率12.5Mhz,1bit
    .data_in    (mosi   ),  //输入串行指令或数据,1bit
    .s          (cs_n   ),  //输入片选信号,1bit
    .w          (1'b1   ),  //输入写保护信号,低有效,1bit
    .hold       (1'b1   ),  //输入hold信号,低有效,1bit

    .data_out   (       )   //输出串行数据
);

endmodule

6.2 tb_spi_flash_se

`timescale  1ns/1ns




module  tb_spi_flash_se();

//wire  define
wire    cs_n;
wire    sck ;
wire    mosi ;

//reg   define
reg     clk     ;
reg     rst_n   ;
reg     key     ;

//时钟、复位信号、模拟按键信号
initial
    begin
        clk =   0;
        rst_n   <=  0;
        key <=  0;
        #100
        rst_n   <=  1;
        #1000
        key <=  1;
        #20
        key <=  0;
    end

always  #10 clk <=  ~clk;

defparam memory.mem_access.initfile = "initmemory.txt";

//-------------spi_flash_se-------------
spi_flash_se    spi_flash_se_inst
(
    .sys_clk    (clk    ),  //系统时钟，频率50MHz
    .sys_rst_n  (rst_n  ),  //复位信号,低电平有效
    .pi_key     (key    ),  //按键输入信号

    .sck        (sck    ),  //串行时钟
    .cs_n       (cs_n   ),  //片选信号
    .mosi       (mosi   )   //主输出从输入数据
);

m25p16  memory
(
    .c          (sck    ),  //输入串行时钟,频率12.5Mhz,1bit
    .data_in    (mosi   ),  //输入串行指令或数据,1bit
    .s          (cs_n   ),  //输入片选信号,1bit
    .w          (1'b1   ),  //输入写保护信号,低有效,1bit
    .hold       (1'b1   ),  //输入hold信号,低有效,1bit

    .data_out   (       )   //输出串行数据
);


endmodule
@大宁字
关注
专栏目录
NAND FLASH的擦除、读写测试程序
09-25
NAND FLASH的擦除、读写测试程序
基于SPI协议的Flash扇区擦除实验
最新发布
qq_52438147的博客
10-05 614
基于SPI协议的Flash扇区擦除实验
关于flash擦除方式
读书 行路 做人 成事
07-20 1067
不同类型的Flash存储器支持的擦除方式可能会有所不同。例如，NAND Flash通常不支持字节级别的擦除，而NOR Flash则可以。擦除操作的具体实现也会受到Flash控制器和存储器本身的设计影响。在进行擦除操作时，还需要注意Flash存储器的耐久性，因为每个存储单元都有有限的擦写次数。这些差异使得NAND Flash和NOR Flash适用于不同的应用场景。NAND Flash适合大容量存储，而NOR Flash适合代码存储和执行。二、NAND Flash和NOR Flash在擦除操作上的区别。
利用FPGA（verilog）实现SPI-FLASH芯片扇区擦除
qq_45742083的博客
12-02 1085
本设计使用了M25P16flash芯片，它拥有16Mbit的空间。M25P16flash芯片有32个扇区，每个扇区有256页，每页有256个位空间。因此它的地址有24位。它的各扇区地址如下表。同全擦除一样，首先得发送写允许指令，然后发送扇区擦除指令。和全擦除不同的是它的扇区擦除指令后面得加一个24位的地址。例如我们现在要把第一扇区擦除，地址的高八位就得是01h，另外24位可以为0000h-ffffh中的任意值。和块擦除不同的是，扇区擦除是要指定扇区地址，扇区擦除前也需要发送写使能指令。
SPI_FLASH（W25X16）擦除、读数据以及写数据等操作
weixin_72238916的博客
01-17 1869
SPI_FLASH（W25X16）擦除、读数据以及写数据等操作
SPI FLASH扇区擦除
xiaolizaixian的博客
04-08 3363
cs拉低之后，直接发送（06h），再将cs拉高，完成写使能。
SPI-FLASH实验.rar_SPI-FLASH实验_byrts_spi_spi flash_spi flash
09-20
SPI-FLASH实验是一个深入探索和理解SPI接口与Flash存储器交互的实践项目。在嵌入式系统中，SPI-FLASH通常被用作非易失性存储器，用于存储程序代码、配置数据或其他重要信息。本实验旨在帮助学习者掌握如何通过SPI...
SPI-FLASH.rar_spi flash stm32_spi；flash；stm32_stm32 flash_stm32
09-14
1. 擦除操作通常分为扇区擦除、块擦除和整个芯片擦除，每个操作都有相应的指令。 2. 写入操作前，需要确保目标区域已被擦除，否则新数据可能无法覆盖原有数据。 3. 注意等待状态，写入和擦除操作可能需要一定时间，...
D1-H_Linux_SPI-NAND_开发指南1
08-03
- `aw_spinand_chip_erase_sector`：擦除SPI-NAND的一个扇区。 通过理解这些接口和数据结构，开发者能够构建和优化针对SUNXI平台的SPI-NAND驱动，确保高效、稳定地使用NAND闪存。此外，还需要熟悉ECC算法和坏块管理...
spi-flash.rar_C语言_flash_stm32 spi_stm32 spi flash_whisperedeqx
09-23
写入Flash则需要先擦除相应区域，再写入数据，因为Flash具有固定的擦写周期和最小擦写单位（通常是扇区）。写操作通常包括： 1. 选择Flash。 2. 发送擦除命令，如0xD8（擦除整个芯片）或0x20（擦除扇区）。 3. 发送...
08_spi_flash_test.zip
06-03
SPI Flash测试是一个重要的步骤，特别是在嵌入式系统和微控制器应用中，..."08_spi_flash_test.zip"中的资源提供了进行此类测试的工具，帮助开发者或工程师验证SPI Flash的功能和性能，确保其在实际应用中的可靠性。
Flash 存储器的擦除（二）
11-04
Flash 存储器的擦除必须是以1KB 为单位对齐的地址并指定哪一区块被擦除，或者全部擦除。也就是说以区块是Flash 擦除的最小单位。 　　●执行 1-KB 页的擦除 　　执行 1KB 页的擦除步骤如下： 　　(1) 将页地址写入FMA 寄存器 　　(2) 将Flash 写入匙码(flash write key)写入FMC 寄存器，并将ERASE 位置位（写入0xA4420002）。 　　(3) 查询FMC 寄存器直至ERASE 位被清零。 　　如图 3 所示： 图3 执行1KB 页的擦除步骤示意图 　　实例程序如程序清单 1 所示： 程序清单 1 　　●执行 F
基于SPI协议的Flash驱动控制-扇区擦除
wszwszwszqwer的博客
11-16 1173
基于SPI的Flash扇区擦除，包括原理讲解和verilog代码实现
STM32 FLASH读、写、擦除
热门推荐
魏波
05-08 4万+
分享STM32 FLASH 擦除（以及防止误擦除程序代码）、写入作者:黄宾山 来源:本站原创编译环境：我用的是(Keil)MDK4.7.2   stm32库版本：我用的是3.5.0一、本文不对FLASH的基础知识做详细的介绍，不懂得地方请查阅有关资料。　　对STM32 内部FLASH进行编程操作，需要遵循以下流程：　　FLASH解锁　　清除相关标志位　　擦除FLASH(先擦除后写入的原因是为了工业...
三大通信协议（3）SPI——flash擦除实验
求学者
10-28 3602
提示：文章写完后，目录可以自动生成，如何生成可参考右边的帮助文档 文章目录 前言 一、pandas是什么？ 二、使用步骤 1.引入库 2.读入数据 总结 一、知识储备 在编写完Verilog程序后，需要将程序下载到硬件FPGA中进行上板验证，通常有两种下载方式：1.直接生成.sof文件，通过JTAG接口下载到FPGA中，这种方式下载速度较快，操作简单，但是由于它是将程序直接烧录到FPGA内部的SRAM中，因此，断电后程序自动丢失。2.通过转换，将生成的.so...
存储器Flash页、扇区、块的区别
strongerHuang
11-21 3万+
关注+星标公众号，不错过精彩内容作者| strongerHuang微信公众号 | 嵌入式专栏大家都知道Flash是用于存储数据的存储器，但很多读者看到页(Page)、扇区(Sector)...
Flash相关知识学习记录（以W25Q128为例）
Qqzodp的博客
03-24 4657
Flash相关知识学习记录（以W25Q128为例）
Flash页、扇区、块的区别
诊断协议那些事儿's blog
06-21 684
FLASH 存储器又称闪存，它结合了ROM和RAM的长处，不仅具备电子可擦除可编程（EEPROM）的性能，还不会断电丢失数据同时可以快速读取数据（NVRAM 的优势），U盘和MP3里用的就是这种存储器。在过去的20年里，嵌入式系统一直使用ROM（EPROM）作为它们的存储设备，然而近年来Flash全面代替了ROM（EPROM）在嵌入式系统中的地位，用作存储Bootloader以及操作系统或者程序代码或者直接当硬盘使用（U盘）。
片外存储器_FLASH的页、扇区、块介绍
w237838的博客
01-20 2013
FLASH属于广义的ROM，因为它也是带电擦除的ROM。但是为了区别于一般的按字节为单位的擦写的E2PROM，我们叫它FLASH。FLASH做的改进就是擦除时不再以字节为单位，而是以块为单位。FLASH分为Nor FLASH和NAND FLASH。NOR FLASH数据线和地址线分开，可以实现RAM一样的随机寻址功能，可以读取任何一个字节。但是擦除仍要按块来擦。NAND FLASH同样是按块擦除，但是数据线和地址线复用，不能利用地址线随机寻址。读取只能按页来读取（
"SPI-Flash与FatFS配置实用文档【STM32存储方案】
disk_ioctl(BYTE pdrv, BYTE cmd, void *buff)函数用于对设备进行控制操作，如擦除扇区、获取设备信息等。 6. 获取当前时间 get_fattime()函数用于获取当前时间，FATFS在创建或修改文件时会使用到该函数获取时间...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

@大宁字

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值