激光三角测量物体高度

1、硬件搭建

        激光与相机的夹角在30°到60°之间，越大精度越高，但同时带来被测物体的阴影越大。

        景深越大可以测得的物体高度越大，可通过调小光圈使景深变大，同时增加曝光或增益补偿亮度。

        假设被拍摄物体的长度确定，传送带速度固定，及传送带运动的时间等于相机扫描的时间，因此相机每秒扫的线数越快，获得的点云越多，精度越高

2、参数标定

        需要知道像素坐标、摄像机坐标、世界坐标的概念。其中摄像机坐标为相机位置为原点的三维坐标系。

2.1、相机内参

         采用张正友标定法，准备最少10张标定板在不同视场下的图片，所有图片加起来尽可能覆盖整个相机视野。

2.2、光平面位姿标定

           即标定激光平面在摄像机坐标下的相对位姿。三点确定一个平面，因此我们求出光平面上不在一条线上的三个点即可。采取的做法是把标定板放在两个不同的视场下（不同高度）拍摄四张标定图片，分别在打开光源关闭激光（关闭光源打开激光）下的高度1（2）拍摄，取其中三点即可确定光平面。

            其中，世界坐标点集+像素坐标点集+相机内参+畸变系数可求得该标定板下的相机外参（RT），参考OpenCV中的solvePnP；相机外参+标定板的一个世界坐标点可求得该点的摄像机坐标，标定板上的坐标点需要在光条上，可通过相对标定板原点的位置求出。

2.3、移动位姿标定

          即获取点云时相机每拍摄一次被拍物体对应位姿。采取的做法是关闭激光，让标定板在传送带上被扫描，拍摄保存起始及停止时的两张照片，记录拍摄次数（扫描线数）。

         根据世界坐标点集+像素坐标点集+相机内参+畸变系数可分别求得该标定板下运动前后的相机外参（位姿），即可推断出停止时的位姿相对与开始时的位姿。除以拍摄次数（扫描线数），即为移动位姿。

2.4、光条重心提取

 

2.5、厂家提供标定参数

以上为自己搭建相机及激光，也可以直接购买激光三角相机，厂家已经标定好，直接输入参数即可，价钱高，精度高。

3、点云测高

3.1、获取三维模型

下面为Smart Ray采集三维图片代码。

*打开3D传感器
open_framegrabber ('GenICamTL', 0, 0, 0, 0, 0, 0, 'progressive', -1, 'default', -1, 'false', 'default', 'default', 0, -1, AcqHandle)
*设置延时
set_framegrabber_param (AcqHandle, 'grab_timeout', 10000)
*加载型号
get_framegrabber_param (AcqHandle, 'Parameter_Set_values', ParameterSetValues)
tuple_regexp_select (ParameterSetValues, '.*_3D_Repeat_Snapshot', ParameterSet)
set_framegrabber_param (AcqHandle, 'Parameter_Set', ParameterSet)
*设置标定数据
set_framegrabber_param (AcqHandle, 'Activate_Calibration', true)
*可以获得中间结果
get_framegrabber_param (AcqHandle, 'Width', Width)
get_framegrabber_param (AcqHandle, 'Height', Height)
get_framegrabber_param (AcqHandle, 'Number_of_Profiles_to_Capture', NumberOfZILCaptured)
get_framegrabber_param (AcqHandle, 'ZMap_Lateral_Resolution', ZILLatRes)
get_framegrabber_param (AcqHandle, 'ZMap_Vertical_Resolution', ZILVerRes)
*初始化传感器
grab_image_start (AcqHandle, -1)
*抓取深度图（Z-map）
grab_image_async (PointCloudZ, AcqHandle, -1)

 另外也可以通过普通相机获得的一张张扫描图自己构建，以下参考Halcon实例中的reconstruct_connection_rod_calib.hdev。

* Set the poses and camera parameters required to compute
* a calibrated measurement
gen_cam_par_area_scan_polynomial (0.0126514, 640.275, -2.07143e+007, 3.18867e+011, -0.0895689, 0.0231197, 6.00051e-006, 6e-006, 387.036, 120.112, 752, 240, CamParam)
create_pose (-0.00164029, 1.91372e-006, 0.300135, 0.575347, 0.587877, 180.026, 'Rp+T', 'gba', 'point', CamPose)
create_pose (0.00270989, -0.00548841, 0.00843714, 66.9928, 359.72, 0.659384, 'Rp+T', 'gba', 'point', LightplanePose)
create_pose (7.86235e-008, 0.000120112, 1.9745e-006, 0, 0, 0, 'Rp+T', 'gba', 'point', MovementPose)
* 
* Create a model in order to process the profile images
* and set the required parameters for the model.
gen_rectangle1 (ProfileRegion, 120, 75, 195, 710)
create_sheet_of_light_model (ProfileRegion, ['min_gray','num_profiles','ambiguity_solving'], [70,290,'first'], SheetOfLightModelID)
set_sheet_of_light_param (SheetOfLightModelID, 'calibration', 'xyz')
set_sheet_of_light_param (SheetOfLightModelID, 'scale', 'mm')
set_sheet_of_light_param (SheetOfLightModelID, 'camera_parameter', CamParam)
set_sheet_of_light_param (SheetOfLightModelID, 'camera_pose', CamPose)
set_sheet_of_light_param (SheetOfLightModelID, 'lightplane_pose', LightplanePose)
set_sheet_of_light_param (SheetOfLightModelID, 'movement_pose', MovementPose)
* 
* Measure the profile from successive images
for Index := 1 to 290 by 1
    read_image (ProfileImage, 'sheet_of_light/connection_rod_' + Index$'.3')
    dev_display (ProfileImage)
    dev_display (ProfileRegion)
    measure_profile_sheet_of_light (ProfileImage, SheetOfLightModelID, [])
endfor

3.2、获取物体相对高度

*读入点云数据（文件中）
read_object_model_3d ('./2020-01-10-235331.om3', 'm', [], [], ObjectModel3D, Status)
dev_open_window (0, 0, 512, 512, 'black', WindowHandle)
visualize_object_model_3d (WindowHandle, ObjectModel3D, [], [], ['lut','color_attrib','disp_pose'], ['color1','coord_z','true'], [], [], [], PoseOut)
*2得到电池表面点云的数据（mm)
get_object_model_3d_params (ObjectModel3D, 'point_coord_z', GenParamValue)
*去掉噪点
select_points_object_model_3d (ObjectModel3D, 'point_coord_z', 15, 16, ObjectModel3DThresholded)
visualize_object_model_3d (WindowHandle, ObjectModel3DThresholded, [], [], ['lut','color_attrib','disp_pose'], ['color1','coord_z','true'], [], [], [], PoseOut1)
connection_object_model_3d (ObjectModel3DThresholded, 'distance_3d', 1, ObjectModel3DConnected)
get_object_model_3d_params (ObjectModel3DConnected, 'num_points', GenParamValue1)
select_object_model_3d (ObjectModel3DConnected, 'num_points', 'and', 1000, 50000, ObjectModel3DBattery)
visualize_object_model_3d (WindowHandle, ObjectModel3DBattery, [], [], ['lut','color_attrib','disp_pose'], ['color1','coord_z','true'], [], [], [], PoseOut1)
*3得到背景的点云数据集合（mm)
select_points_object_model_3d (ObjectModel3D, 'point_coord_z', 12, 14, ObjectModel3DBackGround)
visualize_object_model_3d (WindowHandle, ObjectModel3DBackGround, [], PoseOut1,  ['lut','color_attrib','disp_pose'], ['color1','coord_z','true'], [], [], [], PoseOut2)
*4求电池上表面点云的z坐标值
get_object_model_3d_params (ObjectModel3DBattery, 'point_coord_z', GenParamValue1)
*5求背景表面的点云的z坐标值
get_object_model_3d_params (ObjectModel3DBackGround, 'point_coord_z', GenParamValue2)
*6求电池上表面点云的z坐标的平均值
A:=mean(GenParamValue1)
*7求背景表面点云的z坐标的平均值
B:=mean(GenParamValue2)
*8求电池表面的高度
H:=A-B
Param[0]:='Shift+left button Zoom'
Param[1]:='ctrl+ left button Move'
Param[2]:='left button Rotat'
visualize_object_model_3d (WindowHandle, ObjectModel3D, [], [], ['lut','color_attrib','disp_pose'], ['color1','coord_z','true'], '电池点云的高度为'+H+'mm', 'Battery Object', Param, PoseOut)