uboot 之uboot.lds分析

本文基于arm920t cpu分析uboot.lds。

/*指定输出可执行文件是elf格式,32位ARM指令,小端*/
OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
/*指定输出可执行文件的平台为ARM*/
OUTPUT_ARCH(arm)
/*指定函数入口点为_start,在cpu/arm920t/start.S中定义*/
ENTRY(_start)

SECTIONS
{
/*指定可执行image文件的全局入口点，通常这个地址都放在ROM(flash)0x0位置。必须使编译器知道这个地址，通常都是修改此处来完成*/
   . = 0x00000000;             /*从0x0位置开始*/

   . = ALIGN(4);               /*代码以4字节对齐*/
   .text    :
   {
   cpu/arm920t/start.o (.text) /*代码的第一个代码部分*/
   *(.text)                    /*其它代码部分*/
   }

   . = ALIGN(4);
   .rodata : { *(.rodata) }    /*指定只读数据段*/

    . = ALIGN(4);
   .data : { *(.data) }        /*指定读/写数据段*/

   . = ALIGN(4);
   .got : { *(.got) }          /*指定got段, got段式是uboot自定义的一个段, 非标准段*/

   __u_boot_cmd_start = .;          /*把__u_boot_cmd_start赋值为当前位置, 即起始位置*/                    
   .u_boot_cmd : { *(.u_boot_cmd) } /*u_boot_cmd段存放所有的uboot命令*/
   __u_boot_cmd_end = .;

   . = ALIGN(4);
   __bss_start = .;          /*把__bss_start赋值为当前位置,即bss段的开始位置*/
   .bss : { *(.bss) }      
   _end = .;            
}

在裸机中，指定程序的链接地址有2种方法：

1. 在Makefile中ld的flags用-Ttext 0x00来指定；
2. 在链接脚本的SECTIONS开头用.=0x00来指定。

两种都可以实现相同效果。当这两种方式一起使用时，以-Ttext指定的为准。

在代码段中注意文件排列的顺序。指定必须放在前面部分的那些文件就是那些必须安排在前4KB内（SRAM中）的文件，这些文件中的函数在前4KB会被调用。在后面第二部分（SDRAM中）中调用的程序，前后顺序就无所谓了。

链接脚本中除了.text .data .rodata .bss段等编译工具自带的段之外，编译工具还允许我们自定义段。譬如uboot总的.u_boot_cmd段就是自定义段。