wds - 为什么要重定位呢？

芯片上电时，会将 Nand中的前4K复制到SDRAM（硬件实现）

从Nand 0地址开始运行

什么要重定位呢？

情形一：程序从Nand中启动

• 如果是从Nand中启动，Soc上电后硬件会自动把Nand的前4K代码拷贝到Soc内部的SRAM中，并从SRAM开始运行；（因为内部SRAM只有4K）
• 由于这个4K的限制，代码超过4K就无法运行，所以，需要Nand上的程序首要任务就是把Nand的代码全部拷贝的外部的64K的SDRAM中，然后在SDRAM中运行程序。

情形二：程序从NOR中启动

• 如果是从NOR中启动，上电后就直接在NOR上运行代码
• 由于NORFlash的一个特性——读很快，写的话很繁琐；所以NOR上的程序只能读，不能写，一些变量什么的，也就用不了了；所以还是需要把NOR 上的代码全部拷贝到外部SDRAM去，然后在SDRAM中去运行。

由上可知；重定位就是将程序上的text、data、rodata重新复制到SDRAM中，同时也把地址重定位。

---

预备知识

一个程序中包含有

• text——代码段
• data——数据段——全局变量
• rodata——const变量
• bss——初始值为0，无初始值的全局变量（不保存在bin中）
• commit——注释（不保存在bin中）

---

举个例子：

D:\100 - 韦东山系列视频\01 - 第1期 - ARM裸板\3 - 源码&PPT\源码文档图片\源码\源码_20180321_添加传感器\012_relocate_013

启动文件【start.S】在做什么？

• 关闭看门狗
• 设置系统时钟
• 设置栈——区分系统是从NORFlash启动还是NandFlash启动，然后设置栈顶的地址：如果是Nor，栈顶地址为0x40000000+4096；如果是Nand为4096；（ 为什么要加4096呢？——芯片内部的SRAM大小为4K，sp指向栈顶，从上向下存储）
• 初始化SDRAM（外部的）
• 重定位text, rodata, data，即将链接文件中__code_start到__bss_start的数据复制到SDRAM中；
• 清空bss段（注释，无效变量）

.text
.global _start

_start:

    /* 关闭看门狗 */
    ldr r0, =0x53000000
    ldr r1, =0
    str r1, [r0]

    /* 设置MPLL, FCLK : HCLK : PCLK = 400m : 100m : 50m */
    /* LOCKTIME(0x4C000000) = 0xFFFFFFFF */
    ldr r0, =0x4C000000
    ldr r1, =0xFFFFFFFF
    str r1, [r0]

    /* CLKDIVN(0x4C000014) = 0X5, tFCLK:tHCLK:tPCLK = 1:4:8  */
    ldr r0, =0x4C000014
    ldr r1, =0x5
    str r1, [r0]

    /* 设置CPU工作于异步模式 */
    mrc p15,0,r0,c1,c0,0
    orr r0,r0,#0xc0000000   //R1_nF:OR:R1_iA
    mcr p15,0,r0,c1,c0,0

    /* 设置MPLLCON(0x4C000004) = (92<<12)|(1<<4)|(1<<0)
     *  m = MDIV+8 = 92+8=100
     *  p = PDIV+2 = 1+2 = 3
     *  s = SDIV = 1
     *  FCLK = 2*m*Fin/(p*2^s) = 2*100*12/(3*2^1)=400M
     */
    ldr r0, =0x4C000004
    ldr r1, =(92<<12)|(1<<4)|(1<<0)
    str r1, [r0]

    /* 一旦设置PLL, 就会锁定lock time直到PLL输出稳定
     * 然后CPU工作于新的频率FCLK
     */
   
    /* 设置内存: sp 栈 */
    /* 分辨是nor/nand启动
     * 写0到0地址, 再读出来
     * 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
     * 否则就是nor启动
     */
    mov r1, #0
    ldr r0, [r1] /* 读出原来的值备份 */
    str r1, [r1] /* 0->[0] */
    ldr r2, [r1] /* r2=[0] */
    cmp r1, r2   /* r1==r2? 如果相等表示是NAND启动 */
    ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
    moveq sp, #4096  /* nand启动 */
    streq r0, [r1]   /* 恢复原来的值 */

    bl sdram_init
    //bl sdram_init2     /* 用到有初始值的数组, 不是位置无关码 */

    /* 重定位text, rodata, data段整个程序 */
    bl copy2sdram

    /* 清除BSS段 */
    bl clean_bss

    //bl main  /* 使用BL命令相对跳转, 程序仍然在NOR/sram执行 */
    ldr pc, =main  /* 绝对跳转, 跳到SDRAM */

halt:
    b halt