OneDrive卸载后重新安装没有反应的解决办法

最新推荐文章于 2025-03-25 20:07:23 发布

a136498491

最新推荐文章于 2025-03-25 20:07:23 发布

阅读量1.5w

点赞数

分类专栏： Windows应用文章标签： Onedrive

Windows应用专栏收录该内容

4 篇文章

订阅专栏

自从安装了Onedrive，它的自动安装程序，总是会时不时的占用25%的CPU，然后提示更新失败。

今天又遇到这个问题，一生气直接卸载和删除了Onedrive，之后从官网下载了Onedrive安装文件，但是安装文件总是卡死在那里，试了管理员权限、命令行等都不管用。思考可能是因为Onedrive没有正确卸载。

最后从知乎专栏找到一个一键删除Onedrive的脚本，文章地址：https://zhuanlan.zhihu.com/p/21278319

脚本内容：

@echo off
title 一键删除OneDrive
::获取管理员权限
%Windir%\System32\FLTMC.exe >nul 2>&1 || (
    IF EXIST "%TEMP%\AdminRun.vbs" DEL /f /q "%TEMP%\AdminRun.vbs" 2>nul
    ECHO CreateObject^("Shell.Application"^).ShellExecute "%~f0", "%1", "", "runas", 1 >> "%TEMP%\AdminRun.vbs"
    ECHO CreateObject^("Scripting.filesystemobject"^).DeleteFile ^(WScript.ScriptFullName^) >> "%TEMP%\AdminRun.vbs"
    %Windir%\System32\CSCRIPT.exe //Nologo "%TEMP%\AdminRun.vbs"
    Exit /b
)
echo.
echo 即将删除OneDrive，是否继续？
echo.
echo 是：请按任意键继续。
echo 否：点击右上角，关闭本窗口。
echo.
echo 如有安全软件弹出拦截提示，放行即可。
pause
echo 正在调用OneDrive自带卸载功能，请稍后。
for /d %%f in (%localappdata%\Microsoft\OneDrive\*) do (if exist "%%f\OneDriveSetup.exe" %%f\OneDriveSetup.exe /uninstall)
echo OneDrive卸载完成！
del /f /s /q %localappdata%\Microsoft\OneDrive\*.*
rd /s /q %localappdata%\Microsoft\OneDrive\
echo OneDrive残留文件删除完成！
reg add "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /v Attributes /t REG_DWORD /d "0xf090004d" /f
echo OneDrive导航栏选项删除完成！
echo 删除导航栏OneDrive图标将会在重启Windows资源管理器后生效。
echo.
echo.
echo 已将OneDrive彻底卸载。如有残留文件无法删除，重启后手工删除即可。
echo 请按任意键退出本程序。
pause

将以上内容保存到xx.CMD文件中，运行，按照提示，任意键、任意键、完毕。

然后重新运行Onedrive安装程序，OK，搞定。