编写CPU 0号中断处理程序

编写CPU 0号中断处理程序

下面的程序实现将0号中断处理程序放进内存中一段不会被调用的空间内，以确保CPU除法溢出时始终能够调用到对应的中断处理程序。

因此首先要解决的问题就是，寻找一段系统不会占用的内存空间，这里确定为0000:0200H后的一段空间，事实上这段空间属于中断向量表的空间，只是不存在对应的中断向量。

接下来只需解决两个问题：

1. 安装中断处理程序
2. 设置中断向量表，将0号中断向量指向0000:0200H

最后在中断处理程序中，要注意字符串"divide error!"应该放在不会被系统调用的内存空间内，以避免当安装程序执行完后，所占用的内存空间被释放，'divide error!'所在的内存空间数据被覆盖。（所以在编写中断处理程序的同时，定义字符串即可，此时字符串将被保存在0000:0200H后的一段空间内）

一个问题：是谁将计算机自身的中断处理程序挂载到内存中的？是操作系统吗？

附：中断过程描述

assume cs:code

code segment
	
	start:
	mov ax,0
	mov es,ax
	mov di,200h
	
	mov ax,cs
	mov ds,ax
	mov si,offset do0
	
	mov cx,offset do0end - offset do0;设置代码长度
	cld
	rep movsb
	
	;设置中断向量表
	mov ax,0
	mov es,ax
	mov word ptr es:[0*4],200h
	mov word ptr es:[0*4+2],0
	
	mov ax,4c00h
	int 21h
	
	do0:
	jmp short do0start
	db 'divide error!';字符串放在不会被其他程序覆盖的内存空间内
	do0start:
	mov ax,cs
	mov ds,ax
	mov si,202h
	
	mov ax,0b800h
	mov es,ax
	mov di,12*160+36*2
	
	mov cx,13
	s:
	mov al,[si]
	mov es:[di],al
	inc si
	add di,2
	loop s
	
	mov ax,4c00h
	int 21h
	do0end:
	nop

code ends

end start