qt的pro文件编写记录

# 生成目录
MOC_DIR     = temp/moc
RCC_DIR     = temp/rcc
UI_DIR      = temp/ui
OBJECTS_DIR = temp/obj
DESTDIR     = bin

# 将版本号加入宏定义
message(当前软件版本：$$SPEED_VERSION)
DEFINES += VERSION=\\\"$${SPEED_VERSION}\\\"

# 软件名称如果没有指定，则设置默认的软件名称
isEmpty(APP_NAME): APP_NAME = inspection

# 将软件名称加入宏定义
DEFINES += APP_NAME=\\\"$${APP_NAME}\\\"

# 指定生成的 exe 名称 【名称_v版本号】
# TARGET = $${APP_NAME}_v$${VERSION}
TARGET = $${APP_NAME}

isEmpty(VERSION) {
    # 从 git 信息中自动获取版本号
    system(git --version):HAVE_GIT=1
    defined(HAVE_GIT, var) {
        SPEED_VERSION_COMMIT = $$system(git rev-parse --short HEAD)
        SPEED_VERSION_REVNUM = $$system(git rev-list --count HEAD)
    } else {
        SPEED_VERSION_COMMIT = ??
        SPEED_VERSION_REVNUM = 0
        warning("Git is not in PATH, cannot find commit ID nor revision number")
    }

    SPEED_VERSION_MAJ = 4
    SPEED_VERSION_MIN = 0
    SPEED_VERSION_PAT = 0
    VERSION = $${SPEED_VERSION_MAJ}.$${SPEED_VERSION_MIN}.$${SPEED_VERSION_PAT}.$${SPEED_VERSION_REVNUM}
    SPEED_VERSION = $${VERSION}-$$SPEED_VERSION_COMMIT
} else {
    SPEED_VERSION = $${VERSION}
}

#配置项目的构建选项
CONFIG(debug, debug|release) {
    LIBS += -L$$(ENVPATH)/lib -lDebugLib
}
else{
	LIBS += -L$$(ENVPATH)/lib -lReleaseLib    
}

#添加模块库
contains(DEFINES, ENABLE_PCL) {
    include(libs/PCL/PCL.pri)
}

# 导入开发配置
exists(Config.pri) {
    include(Config.pri)
}