Halcon 药水水平线检测

上结果：

上原图：

贴代码：

* 此示例代码，通过测量的手段，确定各瓶药水是否OK
* 药水水平线在容许的范围内为OK
* 药水水平线高于容许的范围或者低于容许的范围都为NG

* 读取图像
dev_close_window ()
dev_update_off ()
read_image (Image, 'ampoules/ampoules_01')
get_image_size (Image, Width, Height)
dev_open_window_fit_image (Image, 0, 0, -1, -1, WindowHandle)
dev_set_line_width (2)
dev_set_draw ('margin')
set_display_font (WindowHandle, 16, 'mono', 'true', 'false')

* 增加显示图像的代码
dev_display (Image)

* 
* Create a model for the ampoule head to align the measure handle
* 创建模板
* 生成ROI矩形，不带方向的矩形
gen_rectangle1 (Rectangle, 230, 280, 317, 330)
* 抠图
reduce_domain (Image, Rectangle, ImageModel)
* 创建模板
create_shape_model (ImageModel, 'auto', 0, 0, 'auto', 'auto', 'use_polarity', 'auto', 'auto', ModelID)
* 
* Initialize the measure handle
* 在原点处生成一个初始的测量矩形，得到测量句柄
gen_measure_rectangle2 (0, 0, rad(90), 75, 20, Width, Height, 'bilinear', MeasureHandle)
Tolerance := 15
* 
* Determine the fill level
NumImages := 8
for Index := 1 to NumImages by 1
    * 读取图像
    read_image (Image, 'ampoules/ampoules_' + Index$'.2d')
    ColumnEdges := []
    FillLevelHeight := []
    * 
    * 模板匹配，此步骤是为了定位每一个药瓶一个位置的中心点坐标
    * 为后续确定药水水平线的位置做准备
    find_shape_model (Image, ModelID, 0, 0, 0.7, 0, 0.1, 'least_squares', 0, 0.9, Row, Column, Angle, Score)
    * 对找到的所有，行坐标求平均值
    MeanRow := mean(Row)
    * 确定药水的水平线位置：以模板匹配获得的各个药水瓶的行坐标平均值为基准，
    * 获得药水线的基准参考位置
    RefLevel := MeanRow - 160
    * Display tolerance area
    dev_display (Image)
    dev_set_line_width (1)
    dev_set_color ('white')
    * 以基准容忍度为准，生成带方向的矩形
    gen_rectangle2 (AcceptLevel, RefLevel, mean(Column), 0, 30 + (max(Column) - min(Column)) / 2, Tolerance)
    dev_display (AcceptLevel)
    dev_set_line_width (2)
    * 
    *  Determine fill level of each ampoule
    Errors := 0
    for Idx := 0 to |Score| - 1 by 1
        * 平移MeasureHandle句柄对应的测量对象
        translate_measure (MeasureHandle, MeanRow - 135, Column[Idx])
        * Search for the topmost edge
        * 通过测量的方式，得到药水线的位置
        measure_pos (Image, MeasureHandle, 2, 7, 'all', 'first', RowEdge, ColumnEdge, Amplitude, Distance)
        * 下面的代码作用：显示各个药水瓶的药水线的位置，并且标识出是OK还是NG
        * 判断的标准是：测量获得药水线高度坐标与药水线参考高度之间不能超过设置的
        * 容忍范围（此处容忍范围是15）。
        * 超过容忍范围，为NG
        FillLevelHeight := [FillLevelHeight,RowEdge]
        ColumnEdges := [ColumnEdges,ColumnEdge]
        * 在此瓶药水的水平线处生成十字交叉
        gen_cross_contour_xld (Cross, RowEdge, ColumnEdge, 15, 0)
        * 以药水水平线中心点位基础生成矩形，小矩形
        gen_rectangle2 (FillLevel, RowEdge, ColumnEdge, 0, 28, 20)
        * 如果药水水平线超出可容忍范围，那么认为该瓶药水不合格
        if (abs(FillLevelHeight[Idx] - RefLevel) >= Tolerance)
            * 生成矩形，此矩形覆盖整个药水瓶
            gen_rectangle2 (ChamberSingle, MeanRow - 133, Column[Idx], 0, 35, 90)
            * 在此瓶药水的水平线处生成十字交叉
            gen_cross_contour_xld (Cross, FillLevelHeight[Idx], ColumnEdges[Idx], 15, 0)
            * 生成包括十字交叉的小矩形
            gen_rectangle2 (FillLevel, FillLevelHeight[Idx], ColumnEdges[Idx], 0, 28, 20)
            * 计数此图像中error的药水瓶个数
            Errors := Errors + 1
            dev_set_color ('red')
            dev_display (ChamberSingle)
            * 显示NG的信息
            disp_message (WindowHandle, 'NG', 'image', FillLevelHeight[Idx] - 50, ColumnEdges[Idx] - 10, 'red', 'false')
        else
            * 显示OK的信息
            disp_message (WindowHandle, 'OK', 'image', FillLevelHeight[Idx] - 50, ColumnEdges[Idx] - 10, 'green', 'false')
            dev_set_color ('green')
        endif
        dev_display (FillLevel)
        dev_display (Cross)
    endfor
    * 
    * Check, whether the fill level is within the allowed range - does not deviate too much
    * from average fill level
    * 
    * Display statistics
    if (Errors > 0)
        * 显示error的个数
        disp_message (WindowHandle, Errors + ' BAD', 'window', 10, 12, 'red', 'true')
    else
        * 显示所有都OK的信息
        disp_message (WindowHandle, 'All OK', 'window', 10, 12, 'forest green', 'true')
    endif
    if (Index < NumImages)
        disp_continue_message (WindowHandle, 'black', 'true')
        stop ()
    endif
endfor
* 
* 释放测量句柄资源
close_measure (MeasureHandle)
* 释放模板句柄资源
clear_shape_model (ModelID)