话不多说,直接上代码,具体区别我后边会补充上,
暂时委屈各位,先锻炼下自己的“找不同”的能力,哈哈:
Built-CG写法:
Properties {
_MainTex("Main Tex", 2D) = "while"{}
}
SubShader {
Pass {
Tags {"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
sampler2D _MainTex;
float4 _MainTex_ST;
struct a2v {
float4 vertex: POSITION;
float4 texcoord: TEXCOORD0;
};
struct v2f {
float4 position: SV_POSITION;
float2 uv: TEXCOORD0;
};
v2f vert(a2v v) {
v2f o;
o.position = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed4 c = tex2D(_MainTex, i.uv);
return fixed4(c.rgb, 1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}
URP+HLSL写法:
Shader "Unity Shaders Book/Chapter 7/Texture Properties" {
Properties {
_MainTex("Main Tex", 2D) = "while"{}
}
SubShader {
Tags {
"RenderPipeline"="UniversalPipeline"
}
Pass {
Tags {"LightMode" = "UniversalForward"}
HLSLPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
CBUFFER_START(UnityPerMaterial)
float4 _MainTex_ST;
CBUFFER_END
TEXTURE2D(_MainTex);
SAMPLER(sampler_MainTex);
struct a2v {
float4 vertex: POSITION;
float4 texcoord: TEXCOORD0;
};
struct v2f {
float4 position: SV_POSITION;
float2 uv: TEXCOORD0;
};
v2f vert(a2v v) {
v2f o;
o.position = TransformObjectToHClip(v.vertex.xyz);
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
return o;
}
half4 frag(v2f i) : SV_Target {
half4 c = SAMPLE_TEXTURE2D(_MainTex, sampler_MainTex, i.uv);
return half4(c.rgb, 1.0);
}
ENDHLSL
}
}
FallBack "Universal Render Pipeline/Simple Lit"
}