Built-in转URP Chapter7(3)-NormalMap-切线空间处理

话不多说，直接上代码，具体区别我后边会补充上，

暂时委屈各位，先锻炼下自己的“找不同”的能力，哈哈：

Built-CG写法：

	Properties {
		_Color("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex("Main Tex", 2D) = "white"{}
		_BumpMap("Bump Map", 2D) = "bump"{}
		_Specular("Specular",Color) = (1, 1, 1, 1)
		_Gloss("Gloss", Range(10, 256)) = 20
		_BumpScale("BumpScale", Range(-2, 2)) = 1.0
		// _BumpScale("BumpScale", Float) = 1.0
	}

	SubShader {
		Pass {
			Tags {
				"LightMode"="ForwardBase"
			}

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			fixed4 _Color;
			sampler2D  _MainTex;
			float4 _MainTex_ST;
			sampler2D _BumpMap;
			float4 _BumpMap_ST;
			fixed4 _Specular;
			float _Gloss;
			float _BumpScale;

			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 tangent : TANGENT;
				float4 texcoord : TEXCOORD0;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				float4 uv : TEXCOORD0;
				float3 tangentLightDir : TEXCOORD1;
				float3 tangentViewDir : TEXCOORD2;
			};

			// 顶点着色器中完成  灯光、视角 模型空间到切线空间的转换
			// 模型空间->切线空间矩阵求法：
			// 因为知道切线相对模型空间的向量，因此将切线空间的三轴按照列排布即为  切线空间->模型空间的矩阵
			// 因为切线空间是正交矩阵，因此转置矩阵等于逆矩阵，那么只需要将 切线空间->模型空间转置（按照行排布），即可得到 模型空间->切线空间
			v2f vert(a2v data) {
				v2f v;				
				v.pos = UnityObjectToClipPos(data.vertex);
				v.uv.xy = data.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				v.uv.zw = data.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

				float3 binormal = cross(data.normal, data.tangent.xyz) * data.tangent.w;

				// tangent、binormal、normal为模型坐标系下的表示
				// 转置摆放后（按行摆放，按列摆放的话为 切线空间->模型空间）即为 模型空间->切线空间 的矩阵
				float3x3 rotation = float3x3(data.tangent.xyz, binormal, data.normal);
				// TANGENT_SPACE_ROTATION;

				v.tangentLightDir = mul(rotation, ObjSpaceLightDir(data.vertex)).xyz;
				v.tangentViewDir = mul(rotation, ObjSpaceViewDir(data.vertex)).xyz;

				return v;
			}


			fixed4 frag(v2f v) : SV_Target {

				// return half4(v.tangentViewDir, 1);
				fixed3 tangentLightDir = normalize(v.tangentLightDir);
				fixed3 tangentViewDir = normalize(v.tangentViewDir);

				// 获取法线值
				// 如果texture不是法线贴图
				float4 packedNormal = tex2D(_BumpMap, v.uv.zw);
				float3 tangentNormal;
				// tangentNormal.xy = (packedNormal.xy * 2 - 1) * _BumpScale;
				// tangentNormal.z = sqrt(1 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));

				// 如果texture是法线贴图
				tangentNormal = UnpackNormal(packedNormal);
				tangentNormal.xy *= _BumpScale;
				tangentNormal.z = sqrt(1 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));

				fixed3 albedo = tex2D(_MainTex, v.uv.xy).rgb * _Color.rgb;

				// 环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

				// 漫反射
				fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(tangentLightDir, tangentNormal));

				// 高光
				fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
				fixed3 specular = _LightColor0.rgb * _Specular * pow(saturate(dot(tangentNormal, halfDir)), _Gloss);

				return fixed4(ambient + diffuse + specular, 1);
			}

			ENDCG
		}
	}
	FallBack "Specular"
}

URP+HLSL写法：

Shader "Unity Shaders Book/Chapter 7/Normal Map In Tangent Space" {

	Properties {
		_Color("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex("Main Tex", 2D) = "white"{}
		_BumpMap("Bump Map", 2D) = "bump"{}
		_Specular("Specular",Color) = (1, 1, 1, 1)
		_Gloss("Gloss", Range(10, 256)) = 20
		_BumpScale("BumpScale", Range(-2, 2)) = 1.0
	}

	SubShader {
		Tags {
			"RenderPipeline"="UniversalPipeline"
		}
		Pass {
			Tags {
				"LightMode"="UniversalForward"
			}

			HLSLPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
			#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"

CBUFFER_START(UnityPerMaterial)
			half4 _Color;
			float4 _MainTex_ST;
			float4 _BumpMap_ST;
			half4 _Specular;
			float _Gloss;
			float _BumpScale;
CBUFFER_END

			TEXTURE2D(_MainTex);
			SAMPLER(sampler_MainTex);

			TEXTURE2D(_BumpMap);
			SAMPLER(sampler_BumpMap);

			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 tangent : TANGENT;
				float4 texcoord : TEXCOORD0;
			};

			struct v2f {
				float4 pos : SV_POSITION;
				float4 uv : TEXCOORD0;
				float3 tangentLightDir : TEXCOORD1;
				float3 tangentViewDir : TEXCOORD2;
			};

			// 顶点着色器中完成  灯光、视角 模型空间到切线空间的转换
			// 模型空间->切线空间矩阵求法：
			// 因为知道切线相对模型空间的向量，因此将切线空间的三轴按照列排布即为  切线空间->模型空间的矩阵
			// 因为切线空间是正交矩阵，因此转置矩阵等于逆矩阵，那么只需要将 切线空间->模型空间转置（按照行排布），即可得到 模型空间->切线空间
			v2f vert(a2v data) {
				v2f v;				
				v.pos = TransformObjectToHClip(data.vertex.xyz);
				v.uv.xy = data.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				v.uv.zw = data.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

				float3 binormal = cross(data.normal, data.tangent.xyz) * data.tangent.w;

				// tangent、binormal、normal为模型坐标系下的表示
				// 转置摆放后（按行摆放，按列摆放的话为 切线空间->模型空间）即为 模型空间->切线空间 的矩阵
				float3x3 rotation = float3x3(data.tangent.xyz, binormal, data.normal);
				// TANGENT_SPACE_ROTATION;

				// URP 中没有 ObjSpaceLightDir
				half3 objectSpaceLightDir = TransformWorldToObjectDir(_MainLightPosition.xyz);
				v.tangentLightDir = mul(rotation, objectSpaceLightDir).xyz;

				// URP 中没有 ObjSpaceViewDir
				half3 objectSpaceViewDir = half3(TransformWorldToObject(_WorldSpaceCameraPos.xyz) - data.vertex.xyz);
				v.tangentViewDir = mul(rotation, objectSpaceViewDir).xyz;

				return v;
			}


			half4 frag(v2f v) : SV_Target {
				
				half3 tangentLightDir = normalize(v.tangentLightDir);
				half3 tangentViewDir = normalize(v.tangentViewDir);

				// 获取法线值
				// 如果texture不是法线贴图
				float4 packedNormal = SAMPLE_TEXTURE2D(_BumpMap, sampler_BumpMap, v.uv.zw);
				half3 tangentNormal;
				// tangentNormal.xy = (packedNormal.xy * 2 - 1) * _BumpScale;
				// tangentNormal.z = sqrt(1 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));

				// 如果texture是法线贴图
				tangentNormal = UnpackNormal(packedNormal);
				tangentNormal.xy *= _BumpScale;
				tangentNormal.z = sqrt(1 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));

				half3 albedo = SAMPLE_TEXTURE2D(_MainTex, sampler_MainTex, v.uv.xy).rgb * _Color.rgb;

				// 环境光
				half3 ambient = half3(unity_SHAr.w, unity_SHAg.w, unity_SHAb.w) * albedo;

				// 漫反射
				half3 diffuse = _MainLightColor.rgb * albedo * saturate(dot(tangentLightDir, tangentNormal));

				// 高光
				half3 halfDir = normalize(tangentLightDir + tangentViewDir);
				half3 specular = _MainLightColor.rgb * _Specular * pow(saturate(dot(tangentNormal, halfDir)), _Gloss);

				return half4(ambient + diffuse + specular , 1);
			}

			ENDHLSL
		}
	}
	FallBack "Universal Render Pipeline/Simple Lit"
}