话不多说,直接上代码,具体区别我后边会补充上,
暂时委屈各位,先锻炼下自己的“找不同”的能力,哈哈:
Built-CG写法:
Shader "Unity Shaders Book/Chapter 9/Alpha Test With Shadow" {
Properties {
_Color("Color Tint", Color) = (1,1,1,1)
_MainTex("Main Tex", 2D) = "white" {}
_Cutoff("Alpha Cutoff", Range(0, 1)) = 0.5
}
SubShader {
Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
Pass {
Tags {"LightMode"="ForwardBase"}
Cull off
CGPROGRAM
#include "Lighting.cginc"
#include "AutoLight.cginc"
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_fwdbase
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
fixed _Cutoff;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
float2 uv : TEXCOORD2;
SHADOW_COORDS(3)
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldPos = mul(unity_ObjectToWorld, v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target{
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 lightDir = UnityWorldSpaceLightDir(i.worldPos);
fixed3 viewDir = UnityWorldSpaceViewDir(i.worldPos);
fixed4 texColor = tex2D(_MainTex, i.uv);
clip(texColor.a - _Cutoff);
fixed3 albedo = texColor.rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(lightDir, i.worldNormal));
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
return fixed4(ambient + diffuse * atten, 1.0);
}
ENDCG
}
Pass {
Tags {"LightMode"="ForwardAdd"}
Cull off
CGPROGRAM
#include "Lighting.cginc"
#include "AutoLight.cginc"
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_fwdadd_fullshadows
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
fixed _Cutoff;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldPos : TEXCOORD0;
float3 worldNormal : TEXCOORD1;
float2 uv : TEXCOORD2;
SHADOW_COORDS(3)
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex);
o.uv = v.texcoord.xy * _MainTex_ST;
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
fixed4 texColor = tex2D(_MainTex, i.uv);
clip(texColor.a - _Cutoff);
fixed3 albedo = texColor.rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(i.worldNormal, lightDir));
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
return fixed4(ambient + diffuse * atten, 1.0);
}
ENDCG
}
}
FallBack "Transparent/Cutout/VertexLit"
}
URP+HLSL写法:
Shader "Unity Shaders Book/Chapter 9/Alpha Test With Shadow" {
Properties {
_BaseColor("Color Tint", Color) = (1,1,1,1)
_BaseMap("Main Tex", 2D) = "white" {}
_Cutoff("Alpha Cutoff", Range(0, 1)) = 0.5
[Toggle(_AdditionalLights)] _AddLights("AddLights", Float) = 1
}
SubShader {
Tags {
"RenderPipeline"="UniversalPipeline"
"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"
}
Pass {
Tags {"LightMode"="UniversalForward"}
// Cull off
HLSLPROGRAM
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Shadows.hlsl"
#pragma vertex vert
#pragma fragment frag
#pragma shader_feature _AdditionalLights
// #pragma multi_compile_fwdbase
// 具体解释看 Chapter9-Shadow.shader
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS_CASCADE
#pragma multi_compile_fragment _ _ADDITIONAL_LIGHT_SHADOWS
#pragma multi_compile _ _ADDITIONAL_LIGHTS_VERTEX _ADDITIONAL_LIGHTS
#pragma multi_compile_fragment _ _SHADOWS_SOFT
CBUFFER_START(UnityPerMaterial)
half4 _BaseColor;
float4 _BaseMap_ST;
half _Cutoff;
CBUFFER_END
TEXTURE2D(_BaseMap);
SAMPLER(sampler_BaseMap);
struct a2v {
float4 vertex : POSITION;
half3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
half3 worldNormal : TEXCOORD0;
half3 worldPos : TEXCOORD1;
float2 uv : TEXCOORD2;
// SHADOW_COORDS(3)
};
v2f vert(a2v v) {
v2f o;
o.pos = TransformObjectToHClip(v.vertex.xyz);
o.worldPos = mul(UNITY_MATRIX_M, v.vertex).xyz;
o.worldNormal = TransformObjectToWorldNormal(v.normal);
o.uv = v.texcoord.xy * _BaseMap_ST.xy + _BaseMap_ST.zw;
// TRANSFER_SHADOW(o);
return o;
}
half3 LightingBased(half3 lightColor, half3 lightDir, half lightAtten, half3 worldNormal, half3 viewDir, half3 albedo) {
lightDir = normalize(lightDir);
viewDir = normalize(viewDir);
half3 diffuse = lightColor * albedo * saturate(dot(worldNormal, lightDir) * 0.5 + 0.5);
return diffuse * lightAtten;
}
half3 LightingBased(Light light, half3 worldNormal, half3 viewDir, half3 albedo) {
return LightingBased(light.color, light.direction, light.shadowAttenuation * light.distanceAttenuation, worldNormal, viewDir, albedo);
}
half4 frag(v2f i) : SV_Target{
half3 worldNormal = normalize(i.worldNormal);
half3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos);
half4 texColor = SAMPLE_TEXTURE2D(_BaseMap, sampler_BaseMap, i.uv);
clip(texColor.a - _Cutoff);
half3 albedo = texColor.rgb * _BaseColor.rgb;
// half3 lightDir = UnityWorldSpaceLightDir(i.worldPos);
// half3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
// half3 diffuse = _LightColor0.rgb * albedo * saturate(dot(lightDir, i.worldNormal));
// UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
// return half4(ambient + diffuse * atten, 1.0);
float4 shadowCoord = TransformWorldToShadowCoord(worldNormal);
Light mainLight = GetMainLight(shadowCoord);
half3 color = LightingBased(mainLight, worldNormal, viewDir, albedo);
#if _AdditionalLights
uint addLightCount = GetAdditionalLightsCount();
for(uint iu = 0; iu < addLightCount; iu++) {
Light addLight = GetAdditionalLight(iu, i.worldPos);
color += LightingBased(addLight, worldNormal, viewDir, albedo);
}
#endif
half3 ambient = SampleSH(worldNormal);
return half4(color + ambient, 1.0);
}
ENDHLSL
}
// 自己计算阴影的Pass
Pass
{
Tags { "LightMode" = "ShadowCaster" }
Cull Off
ZWrite On
ZTest LEqual
ColorMask 0
HLSLPROGRAM
// 设置关键字
#pragma shader_feature _ALPHATEST_ON
#pragma vertex vert
#pragma fragment frag
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Shadows.hlsl"
float3 _LightDirection;
CBUFFER_START(UnityPerMaterial)
half4 _BaseColor;
float4 _BaseMap_ST;
half _Cutoff;
CBUFFER_END
TEXTURE2D(_BaseMap);
SAMPLER(sampler_BaseMap);
struct a2v
{
float4 vertex: POSITION;
float3 normal: NORMAL;
float2 texcoord: TEXCOORD0;
};
struct v2f
{
float2 uv: TEXCOORD0;
float4 pos: SV_POSITION;
};
// 获取裁剪空间下的阴影坐标
float4 GetShadowPositionHClips(a2v v)
{
float3 positionWS = TransformObjectToWorld(v.vertex.xyz);
float3 normalWS = TransformObjectToWorldNormal(v.normal);
// 获取阴影专用裁剪空间下的坐标
float4 positionCS = TransformWorldToHClip(ApplyShadowBias(positionWS, normalWS, _LightDirection));
// 判断是否是在DirectX平台翻转过坐标
#if UNITY_REVERSED_Z
positionCS.z = min(positionCS.z, positionCS.w * UNITY_NEAR_CLIP_VALUE);
#else
positionCS.z = max(positionCS.z, positionCS.w * UNITY_NEAR_CLIP_VALUE);
#endif
return positionCS;
}
v2f vert(a2v v)
{
v2f o;
o.uv = TRANSFORM_TEX(v.texcoord, _BaseMap);
o.pos = GetShadowPositionHClips(v);
return o;
}
half4 frag(v2f i): SV_TARGET
{
// Alpha(SampleAlbedoAlpha(i.uv, TEXTURE2D_ARGS(_BaseMap, sampler_BaseMap)).a, _BaseColor, _Cutoff);
half4 texColor = SAMPLE_TEXTURE2D(_BaseMap, sampler_BaseMap, i.uv);
clip(texColor.a - _Cutoff);
return 0;
}
ENDHLSL
}
}
// // 不知道为什么不产生阴影
// FallBack "Universal Render Pipeline/Simple Lit"
}