DSP28377S_程序从FLASH部分复制到RAM中运行详解

为什么要复制到RAM中运行

DSP的程序下载执行方式有两种：一种是下载到RAM中在线执行，一种是下载到FLASH中执行。在RAM中执行时，具有执行速度快，可以无限次下载的特点，但是RAM的特点是掉电丢失数据。FLASH具有掉电不丢失数据的特点，但是同时存在执行速度慢和擦写次数有限的缺点，尤其在电机控制运用时，会造成响应慢、混乱等问题，原本在RAM中调试成功的程序烧写到FLASH中无法使用的情况。因此综合两者的特点，在DSP的开发过程中一般会结合使用两者。在前期程序调试过程，由于需要频繁的擦写，所以一般选择在RAM中进行。而程序调试完成后，由于需要脱离下载器而独立执行，因此需要烧写到掉电不丢失数据的FLASH中。下面将以利用CCS8.3对TMS320F28377S进行程序在FLASH中的烧写为例，介绍一下将程序烧写到FLASH中的操作过程。
程序从在RAM中执行改为下载到FLASH中需要对工程文件做一些修改。而程序烧写到FLASH中后，又根据程序执行时的存储区间的不同，分为程序部分拷贝到RAM中执行和程序整体复制到RAM中执行两种，两种执行需要对工程作不同的修改和设置，这里仅介绍部分程序复制，满足目的即可，节省RAM资源。

CMD文件中对存储空间的分配

TI在进行分配时，除去一些特殊用途的存储空间，基本上每段存储空间的命名与长度与TMS320F2837xS数据手册中Memory Map一致，PAGE0通常为程序空间，PAGE1为数据空间，下面为2837xS_Generic_FLASH_lnk.cmd中对于存储空间的分配，关注下FLASHD与RAMLS0，后面有用到：

PAGE 0 :  /* Program Memory */
          /* Memory (RAM/FLASH) blocks can be moved to PAGE1 for data allocation */
          /* BEGIN is used for the "boot to Flash" bootloader mode   */
   BEGIN            : origin = 0x080000, length = 0x000002
   RAMM0            : origin = 0x000122, length = 0x0002DE
   RAMD0            : origin = 0x00B000, length = 0x000800
   RAMLS0           : origin = 0x008000, length = 0x000800
   RAMLS1           : origin = 0x008800, length = 0x000800
   RAMLS2           : origin = 0x009000, length = 0x000800
   RAMLS3           : origin = 0x009800, length = 0x000800
   RAMLS4           : origin = 0x00A000, length = 0x000800
   RESET            : origin = 0x3FFFC0, length = 0x000002
   /* Flash sectors */
   FLASHA           : origin = 0x080002, length = 0x001FFE /* on-chip Flash */
   FLASHB           : origin = 0x082000, length = 0x002000 /* on-chip Flash */
   FLASHC           : origin = 0x084000, length = 0x002000 /* on-chip Flash */
   FLASHD           : origin = 0x086000, length = 0x002000 /* on-chip Flash */
   FLASHE           : origin = 0x088000, length = 0x008000 /* on-chip Flash */
   FLASHF           : origin = 0x090000, length = 0x008000 /* on-chip Flash */
   FLASHG           : origin = 0x098000, length = 0x008000 /* on-chip Flash */
   FLASHH           : origin = 0x0A0000, length = 0x008000 /* on-chip Flash */
   FLASHI           : origin = 0x0A8000, length = 0x008000 /* on-chip Flash */
   FLASHJ           : origin = 0x0B0000, length = 0x008000 /* on-chip Flash */
   FLASHK           : origin = 0x0B8000, length = 0x002000 /* on-chip Flash */
   FLASHL           : origin = 0x0BA000, length = 0x002000 /* on-chip Flash */
   FLASHM           : origin = 0x0BC000, length = 0x002000 /* on-chip Flash */
   FLASHN           : origin = 0x0BE000, length = 0x002000 /* on-chip Flash */
PAGE 1 : /* Data Memory */
         /* Memory (RAM/FLASH) blocks can be moved to PAGE0 for program allocation */
   BOOT_RSVD       : origin = 0x000002, length = 0x000120     /* Part of M0, BOOT rom will use this for stack */
   BOOT_RSVD       : origin = 0x000002, length = 0x000120     /* Part of M0, BOOT rom will use this for stack */
   RAMM1           : origin = 0x000400, length = 0x000400     /* on-chip RAM block M1 */
   RAMD1           : origin = 0x00B800, length = 0x000800

   RAMLS5      : origin = 0x00A800, length = 0x000800
   
   RAMGS0      : origin = 0x00C000, length = 0x001000
   RAMGS1      : origin = 0x00D000, length = 0x001000
   RAMGS2      : origin = 0x00E000, length = 0x001000
   RAMGS3      : origin = 0x00F000, length = 0x001000
   RAMGS4      : origin = 0x010000, length = 0x001000
   RAMGS5      : origin = 0x011000, length = 0x001000
   RAMGS6      : origin = 0x012000, length = 0x001000
   RAMGS7      : origin = 0x013000, length = 0x001000
   RAMGS8      : origin = 0x014000, length = 0x001000
   RAMGS9      : origin = 0x015000, length = 0x001000
   RAMGS10     : origin = 0x016000, length = 0x001000
   RAMGS11     : origin = 0x017000, length = 0x001000
   
   CANA_MSG_RAM     : origin = 0x049000, length = 0x000800//2019.12.12修改
   CANB_MSG_RAM     : origin = 0x04B000, length = 0x000800//2019.12.12修改

CMD文件中对段的定义

C语言生成的段大致分为两大类：初始化和未初始化，已初始化的段含有真正的指令和数据，未初始化段只是保留变量的地址空间。已初始化段通常放在程序空间，未初始化段通常放在数据空间。
已初始化段：
.text——C语言编译生成的汇编指令代码存放于此
.cinit——存放初始化的全局和静态变量
.const——字符串常量和const定义的全局和静态变量
.econst——字符串常量和far const定义的全局和静态变量
.print——全局构造器(C++)程序列表
.switch——存放switch语句产生的常数表格
未初始化段：
.bss——为全局变量和局部变量保留的空间，程序上电时，.cinit空间中的数据复制出来并存放在.bss空间中
.ebss——为使用大寄存器模式时预留的全局和局部变量空间，程序上电时，.cinit空间中的数据复制出来并存放在.bss空间中
.stack——堆栈空间，主要用于函数传递变量或为局部变量分配空间
.system——为动态存储分配保留的空间(malloc)，如果有宏函数，此空间被占用
.esystem——为动态存储分配保留的空间(far malloc)，如果有far函数，此空间会被占用
下面为2837xS_Generic_FLASH_lnk.cmd中对于段的定义：

/* Allocate program areas: */
.cinit    : > FLASHB      PAGE = 0, ALIGN(4)
.pinit    : > FLASHB,     PAGE = 0, ALIGN(4)
.text     : >> FLASHB | FLASHC | FLASHD | FLASHE      PAGE = 0, ALIGN(4)
codestart : > BEGIN       PAGE = 0, ALIGN(4)
/* Allocate uninitalized data sections: */
.stack    : > RAMM1        PAGE = 1
.ebss     : >> RAMLS5 | RAMGS0 | RAMGS1       PAGE = 1
.esysmem  : > RAMLS5       PAGE = 1
/* Initalized sections go in Flash */
.econst   : >> FLASHF | FLASHG | FLASHH      PAGE = 0, ALIGN(4)
.switch   : > FLASHB      PAGE = 0, ALIGN(4)
.reset    : > RESET,     PAGE = 0, TYPE = DSECT /* not used, */

语法备注：
> 等效为 load =
>>表示多片空间串起来

CMD文件中FLASH部分复制到RAM中的定义

在28377S的CMD文件中，可以看到与28335的CMD文件不同之处，新的编译器使用.TI.ramfunc作为原本的ramfuncs段定义，考虑到兼容性，用预编译进行区分。在用#pragma有一些细节之处“点我点我点我”。从FLASH中复制代码到RAM中运行时，尽量保证FLASH与RAM的空间大小一致，即便是FLASH没用光，为避免意想不到的问题，也尽量如此做。

#ifdef __TI_COMPILER_VERSION__
   #if __TI_COMPILER_VERSION__ >= 15009000
    .TI.ramfunc : {} LOAD = FLASHD,//8k
                         RUN = RAMLS0 | RAMLS1 | RAMLS2 |RAMLS3,//2k * 4 = 8k
                         LOAD_START(_RamfuncsLoadStart),
                         LOAD_SIZE(_RamfuncsLoadSize),
                         LOAD_END(_RamfuncsLoadEnd),
                         RUN_START(_RamfuncsRunStart),
                         RUN_SIZE(_RamfuncsRunSize),
                         RUN_END(_RamfuncsRunEnd),
                         PAGE = 0, ALIGN(4)
   #else
   ramfuncs            : LOAD = FLASHD,
                         RUN = RAMLS0 | RAMLS1 | RAMLS2 |RAMLS3,
                         LOAD_START(_RamfuncsLoadStart),
                         LOAD_SIZE(_RamfuncsLoadSize),
                         LOAD_END(_RamfuncsLoadEnd),
                         RUN_START(_RamfuncsRunStart),
                         RUN_SIZE(_RamfuncsRunSize),
                         RUN_END(_RamfuncsRunEnd),
                         PAGE = 0, ALIGN(4)   
   #endif
#endif

语法备注：
LOAD_START(_RamfuncsLoadStart)为程序下载到FLSAH的首地址
LOAD_SIZE(_RamfuncsLoadSize)为程序下载到FLSAH的大小
LOAD_END(_RamfuncsLoadEnd)为程序下载到FLSAH的尾地址
RUN_START(_RamfuncsRunStart)为程序运行在RAM的首地址
RUN_SIZE(_RamfuncsRunSize)为程序运行在RAM的大小
RUN_END(_RamfuncsRunEnd)为程序运行在RAM的尾地址

main中的操作

在系统初始化时，将要从FLASH中复制到RAM中运行的程序进行操作。首先在F2837xS_GlobalPrototypes.h中声明下外部变量。

//
// External symbols created by the linker cmd file
// DSP28 examples will use these to relocate code from one LOAD location
// in Flash to a different RUN location in internal
// RAM
//
extern Uint16 RamfuncsLoadStart;
extern Uint16 RamfuncsLoadEnd;
extern Uint16 RamfuncsLoadSize;
extern Uint16 RamfuncsRunStart;
extern Uint16 RamfuncsRunEnd;
extern Uint16 RamfuncsRunSize;

然后在main中进行相应的顺序操作。

int main(void)
{
//  Initialize System Control:PLL, WatchDog, enable Peripheral Clocks
     InitSysCtrl();
     ...
     ...
}

使用_FLASH“开关”，操作是否要下载至FLASH中。

void InitSysCtrl(void)
{
     DisableDog();
#ifdef _FLASH
    //
    // Copy time critical code and Flash setup code to RAM. This includes the
    // following functions: InitFlash()
    //
    // The  RamfuncsLoadStart, RamfuncsLoadSize, and RamfuncsRunStart
    // symbols are created by the linker. Refer to the device .cmd file.
    //
     memcpy(&RamfuncsRunStart, &RamfuncsLoadStart, (size_t)&RamfuncsLoadSize);
     InitFlash_Bank0();
#endif
     ...
     ...
}

将InitFlash_Bank0放入.TI.ramfunc段中（FLASHD），搬运至RAM中运行。memcpy要放在InitFlash_Bank0前面，搬完后就在RAM中初始化。如果颠倒，相当于在FLASH中初始化FLASH完了再复制，没起到应有的作用。这里解释一下为什么要将FLASH的初始化放入RAM中运行：①如果FLASH中运行的程序对FLASH进行配置的修改，是被禁止的，有概率会导致程序出错；②对FLASH进行初始化，可以提高FLASH中程序的运行速度，相比较于未修改过的FLASH配置。（主要是waitstates变短和启用缓存和预取机制提高程序执行速度）

//
// InitFlash_Bank0 - This function initializes the Flash Control registers for
//                   Bank 0.
//
//      *CAUTION*
// This function MUST be executed out of RAM. Executing it out of OTP/Flash
// will yield unpredictable results.
//
#ifdef __cplusplus
    #ifdef __TI_COMPILER_VERSION__
        #if __TI_COMPILER_VERSION__ >= 15009000
            #pragma CODE_SECTION(".TI.ramfunc");
        #else
            #pragma CODE_SECTION("ramfuncs");
        #endif
    #endif
#endif
void InitFlash_Bank0(void)
{
    EALLOW;
    ...
    ...
    // Minimum waitstates required for the flash operating at a given CPU rate
    // must be characterized by TI. Refer to the datasheet for the latest
    // information.
    //
    #if CPU_FRQ_200MHZ
    Flash0CtrlRegs.FRDCNTL.bit.RWAIT = 0x3;
    #endif
    //
    // Enable Cache and prefetch mechanism to improve performance of code
    // executed from Flash.
    //
    Flash0CtrlRegs.FRD_INTF_CTRL.bit.DATA_CACHE_EN = 1;
    Flash0CtrlRegs.FRD_INTF_CTRL.bit.PREFETCH_EN = 1;
    ...
    ...
}

想要延时准确，将DELAY_US也放入.TI.ramfunc段中（FLASHD），搬运至RAM中运行。

       .def _F28x_usDelay
       .sect ".TI.ramfunc"
       
       .global  __F28x_usDelay
_F28x_usDelay:
        SUB    ACC,#1
        BF     _F28x_usDelay,GEQ    ;; Loop if ACC >= 0
        LRETR

编译后如何检查分配结果

.map文件为调试人员提供详细的空间分配结果。编译完成之后，打开.map文件，可以看出程序下载到FLASHD中的痕迹，在RAMLS0的区域，划分出0x72的区域，给从FLASHD中复制过来的程序运行。InitFlash_Bank1、 FlashOff_Bank0、 FlashOff_Bank1 函数前也用了#pragma声明，只不过前面代码没贴。

结束语

因为网上关于DSP28377S程序从FLASH部分复制到RAM中运行的讲解基本为零，只能参考DSP28335、2407等，故笔者整理、实际编译了一下，供有需者查阅。关于CMD的高级操作，目前笔者尚未有实际需求，暂时搁置吧。
笔者水平有限，欢迎大佬来锤，促进笔者水平的提升。

参考资料目录

《CMD文件的原理----玄德（网名）2009年3月》
《TMS320F2837xS数据手册》Detailed Description 章节
《TMS320C28x Optimizing C/C++ Compiler v19.6.0.STS User’s Guide》
Linking C/C++ Code 章节
《TMS320C28x Assembly Language Tools v19.6.0.STS User’s Guide》
Linker Description章节
《TMS320F2837xS技术参考手册》System Control章节