11.逻辑运算
11.1、说明
Gremlin支持在遍历器上加上逻辑运算进行过滤,只有满足该逻辑条件的元素才会进入下一个遍历器中。
下面讲解实现上述功能的具体Step:
is()
:可以接受一个对象(能判断相等)或一个判断语句(如:P.gt()
、P.lt()
、P.inside()
等),当接受的是对象时,原遍历器中的元素必须与对象相等才会保留;当接受的是判断语句时,原遍历器中的元素满足判断才会保留,其实接受一个对象相当于P.eq()
;and()
:可以接受任意数量的遍历器(traversal),原遍历器中的元素,只有在每个新遍历器中都能生成至少一个输出的情况下才会保留,相当于过滤器组合的与条件;or()
:可以接受任意数量的遍历器(traversal),原遍历器中的元素,只要在全部新遍历器中能生成至少一个输出的情况下就会保留,相当于过滤器组合的或条件;not()
:仅能接受一个遍历器(traversal),原遍历器中的元素,在新遍历器中能生成输出时会被移除,不能生成输出时则会保留,相当于过滤器的非条件。
这四种逻辑运算Step除了像一般的Step写法以外,
and()
和or()
还可以放在where()
中以中缀符的形式出现。
11.2、实例讲解
11.2.1、 is()
// 筛选出顶点属性“age”等于28的属性值,与`is(P.eq(28))`等效
g.V().values('age').is(28)
当没有任何一个顶点的属性“age”为28时,输出为空。
// 筛选出顶点属性“age”大于等于28的属性值
g.V().values('age').is(gte(28))
// 筛选出顶点属性“age”属于区间(27,29)的属性值
g.V().values('age').is(inside(27, 29))
P.inside(a, b)
是左开右开区间(a,b)
// 筛选出由两个或两个以上的人参与创建(“created”)的顶点
// 注意:这里筛选的是顶点
g.V().where(__.in('created').count().is(gt(2))).values('name')
where()
Step可以接受一些过滤条件
// 筛选出有创建者(“created”)的年龄(“age”)在20~29之间的顶点
g.V().where(__.in('created').values('age').is(between(20, 29))).values('name')
11.2.2、 and()
,逻辑与
// 所有包含出边“supports”的顶点的名字“name”
g.V().and(outE('supports')).values('name')
// 所有包含出边“supports”和“implements”的顶点的名字“name”
g.V().and(outE('supports'), outE('implements')).values('name')
// 包含边“created”并且属性“age”为28的顶点的名字“name”
g.V().and(outE('created'), values('age').is(28)).values('name')
上面的缀符写法
// 包含边“created”并且属性“age”为28的顶点的名字“name”
g.V().where(outE('created')
.and()
.values('age').is(28))
.values('name')
11.2.3、 or()
,逻辑或
// 所有包含出边“supports”的顶点的名字“name”
g.V().or(outE('supports')).values('name')
只有一个条件时,
and()
与or()
的效果一样的。
// 所有包含出边“supports”或“implements”的顶点的名字“name”
g.V().or(outE('supports'), outE('implements')).values('name')
注意对比与
g.V().and(outE('supports'), outE('implements')).values('name')
的差别
// 包含边“created”或属性“age”为28的顶点的名字“name”
g.V().or(outE('created'), values('age').is(28)).values('name')
注意对比与
g.V().and(outE('created'), values('age').is(28)).values('name')
的差别
上面的 缀符写法
// 包含边“created”或属性“age”为28的顶点的名字“name”
g.V().where(outE('created')
.or()
.values('age').is(28))
.values('name')
11.2.4、 not()
,逻辑非
// 筛选出所有不是“person”的顶点的“label”
g.V().not(hasLabel('person')).label()
// 筛选出所有包含不少于两条(大于等于两条)“created”边的“person”的名字“name”
g.V().hasLabel('person').not(out('created').count().is(lt(2))).values('name')
11.3、综合运用
目标:获取所有最多只有一条“created”边并且年龄不等于28的“person”顶点
// 与(含有小于等于一条“created”边,年龄不等于28)
g.V().hasLabel('person')
.and(outE('created').count().is(lte(1)),
values("age").is(P.not(P.eq(28))))
.values('name')
// 非(或(含有多于一条“created”边,年龄等于28))
g.V().hasLabel('person')
.not(or(out('created').count().is(gt(1)),
values('age').is(28)))
.values('name')