源码-PL/SQL从入门到精通-第十章-使用游标-Part 2

最新推荐文章于 2021-12-29 15:04:37 发布
最新推荐文章于 2021-12-29 15:04:37 发布
阅读量2.3k 收藏 1
点赞数 1
分类专栏： 数据库（DB） 文章标签： oracle 11g PLSQL 基础 源码
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/hpdlzu80100/article/details/51969354
版权

虽说下个项目中要用到PL/SQL，但还不清楚需要用到哪些具体的知识点？估计游标是不可或缺了，如果能在现有代码的基础上改一改就能满足项目要求，现在的工作也就更有价值了。

--代码10.14 基本的Loop循环结构
DECLARE
   dept_row dept%ROWTYPE;                      --定义游标结果记录变量
   CURSOR dept_cursor IS SELECT * FROM dept;   --定义游标变量
BEGIN 
   OPEN dept_cursor;                           --打开游标
   LOOP                                        --简单循环
      FETCH dept_cursor INTO dept_row;         --提取游标数据
      EXIT WHEN dept_cursor%NOTFOUND;          --退出循环的控制语句
      DBMS_OUTPUT.PUT_LINE('部门名称：'||dept_row.dname);
   END LOOP;
   CLOSE dept_cursor;                          --关闭游标
END;   

--代码10.15 使用WHILE循环循环检索游标数据
DECLARE
   dept_row dept%ROWTYPE;                      --定义游标结果记录变量
   CURSOR dept_cursor IS SELECT * FROM dept;   --定义游标变量
BEGIN 
   OPEN dept_cursor;                           --打开游标
   FETCH dept_cursor INTO dept_row;            --提取游标数据   
   WHILE dept_cursor%FOUND  LOOP                 
      DBMS_OUTPUT.PUT_LINE('部门名称：'||dept_row.dname);
      FETCH dept_cursor INTO dept_row;         --提取游标数据         
   END LOOP;
   CLOSE dept_cursor;                          --关闭游标
END;   


--代码10.16 使用游标For循环检索数据
DECLARE
   CURSOR dept_cursor IS SELECT * FROM dept;   --定义游标变量
BEGIN 
   FOR dept_row IN dept_cursor LOOP            --在游标FOR循环中检索数据
     DBMS_OUTPUT.PUT_LINE('部门名称：'||dept_row.dname);
   END LOOP;
END;   

--代码10.17 游标For循环子查询语句（简洁就是好！）
BEGIN 
   FOR dept_row IN (SELECT * FROM dept) LOOP    --在游标FOR循环中检索数据
     DBMS_OUTPUT.PUT_LINE('部门名称：'||dept_row.dname);
   END LOOP;
END;   

--代码10.18 使用游标更新数据
DECLARE
   CURSOR emp_cursor (p_deptno IN NUMBER)
   IS
      SELECT  *
            FROM emp
           WHERE deptno = p_deptno
      FOR UPDATE;                              --使用FOR UPDATE子句添加互斥锁
BEGIN
   FOR emp_row IN emp_cursor (20)              --使用游标FOR循环检索游标
   LOOP
      UPDATE emp                      
         SET comm = comm * 1.12
       WHERE CURRENT OF emp_cursor;            --使用WHERE CURRENT OF更新游标数据
   END LOOP;
   COMMIT;                                     --提交更改
END;

--代码10.18 使用游标删除数据
DECLARE
   CURSOR emp_cursor (p_empno IN NUMBER)
   IS
      SELECT  *
            FROM emp
           WHERE empno = p_empno 
      FOR UPDATE;                              --使用FOR UPDATE子句添加互斥锁
BEGIN
   FOR emp_row IN emp_cursor (7369)              --使用游标FOR循环检索游标
   LOOP
    DELETE FROM emp
       WHERE CURRENT OF emp_cursor;            --使用WHERE CURRENT OF删除游标数据
   END LOOP;
END;

--代码10.20 游标变量使用示例
DECLARE
   TYPE emp_type IS REF CURSOR RETURN emp%ROWTYPE;       --定义游标变量类型
   emp_cur   emp_type;                                   --声明游标变量
   emp_row   emp%ROWTYPE;                                --定义游标结果值变量
BEGIN
   OPEN emp_cur FOR SELECT * FROM emp;                   --打开游标
   LOOP
      FETCH emp_cur INTO emp_row;                        --循环提取游标数据
      EXIT WHEN emp_cur%NOTFOUND;                        --循环退出检测
      DBMS_OUTPUT.put_line ('员工名称：' || emp_row.ename);
   END LOOP;
END;

--代码10.21 定义游标变量
DECLARE
   TYPE emp_type IS REF CURSOR RETURN emp%ROWTYPE;      --定义游标类型
   TYPE gen_type IS REF CURSOR;                         
   emp_cur emp_type;                                   --声明游标变量
   gen_cur gen_type;
BEGIN
   OPEN emp_cur FOR SELECT * FROM emp WHERE deptno=20;
END;   
   

DECLARE
    gen_type SYS_REFCURSOR;
BEGIN
END;       

--代码10.22 大咖游标变量示例
DECLARE
   TYPE emp_curtype IS REF CURSOR;                       --定义游标类型
   emp_cur emp_curtype;                                  --声明游标类型的变量
BEGIN
   OPEN emp_cur FOR SELECT * FROM emp;                   --打开游标,查询emp所有列
   OPEN emp_cur FOR SELECT empno FROM emp;               --打开游标,查询emp表empno列 
   OPEN emp_cur FOR SELECT deptno FROM dept;             --打开游标,查询dept表deptno列
END;


--使用Fetch语句提取游标变量数据
DECLARE
   TYPE emp_type IS REF CURSOR RETURN emp%ROWTYPE;       --定义游标类型
   emp_cur emp_type;                                     --声明游标变量
   emp_row emp%ROWTYPE;
BEGIN
   IF NOT emp_cur%ISOPEN THEN                            --如果游标变量没有打开
   OPEN emp_cur FOR SELECT * FROM emp WHERE deptno=20;   --打开游标变量
   END IF;
   LOOP
     FETCH emp_cur INTO emp_row;                         --提取游标变量
     EXIT WHEN emp_cur%NOTFOUND;                         --如果提取完成则退出循环
     DBMS_OUTPUT.PUT_LINE('员工名称：'||emp_row.ename
                         ||' 员工职位：'||emp_row.job);  --输出员工信息
   END LOOP;
END;   


--使用close语句关闭游标变量（不关闭也不会报错）
DECLARE
   TYPE emp_type IS REF CURSOR RETURN emp%ROWTYPE;       --定义游标类型
   emp_cur emp_type;                                     --声明游标变量
   emp_row emp%ROWTYPE;
BEGIN
   OPEN emp_cur FOR SELECT * FROM emp WHERE deptno=20;   --打开游标
   FETCH emp_cur INTO emp_row;                           --提取游标
   WHILE emp_cur%FOUND LOOP                              --循环提取游标
     DBMS_OUTPUT.PUT_LINE('员工名称：'||emp_row.ename);
     FETCH emp_cur INTO emp_row;       
   END LOOP;
   CLOSE emp_cur;                                        --关闭游标
END;   

--以下代码不能通过编译（使用fetch语句前，应先使用open语句）
DECLARE
   TYPE emp_curtype IS REF CURSOR;                       --定义游标类型
   emp_cur emp_curtype;                                  --声明游标类型的变量
   emp_row emp%ROWTYPE;
BEGIN   
   FETCH emp_cur INTO emp_row;
END;

--代码10.25 处理Invalid_cursor异常（不太明白）
DECLARE
   TYPE emp_curtype IS REF CURSOR;                       --定义游标类型
   emp_cur1 emp_curtype;                                 --声明游标类型的变量
   emp_cur2 emp_curtype;
   emp_row emp%ROWTYPE;                                  --定义保存游标数据的记录类型
BEGIN   
   OPEN emp_cur1 FOR SELECT * FROM emp WHERE deptno=20;  --打开第1个游标
   FETCH emp_cur1 INTO emp_row;                          --提取并显示游标信息
   DBMS_OUTPUT.PUT_LINE('员工名称：'||emp_row.ename||' 部门编号：'||emp_row.deptno);
   FETCH emp_cur2 INTO emp_row;                          --提取第2个游标变量将引发异常
EXCEPTION
   WHEN INVALID_CURSOR THEN                              --异常处理
      emp_cur2:=emp_cur1;                                --将emp_cur1指向的查询区域赋给emp_cur2
      FETCH emp_cur2 INTO emp_row;                       --现在emp_cur1与emp_cur2指向相同的查询
      DBMS_OUTPUT.PUT_LINE('员工名称：'||emp_row.ename||' 部门编号：'||emp_row.deptno);
      OPEN emp_cur2 FOR SELECT * FROM emp WHERE deptno=30; --重新打开emp_cur2游标变量，利用相同的查询区域
      FETCH emp_cur1 INTO emp_row;                         --由于emp_cur1与emp_cur2共享相同的查询区域，因此结果相同
      DBMS_OUTPUT.PUT_LINE('员工名称：'||emp_row.ename||' 部门编号：'||emp_row.deptno);      
END;


--处理Rowtype_mismatch异常
DECLARE
   TYPE emp_curtype IS REF CURSOR;                       --定义游标类型
   emp_cur emp_curtype;                                  --声明游标类型的变量
   emp_row emp%ROWTYPE;                                  --声明游标数据结果类型
   dept_row dept%ROWTYPE;                               
BEGIN   
   OPEN emp_cur FOR SELECT * FROM emp WHERE deptno=20;   --打开游标变量
   FETCH emp_cur INTO dept_row;                          --提取到一个不匹配的类型中
EXCEPTION
   WHEN ROWTYPE_MISMATCH THEN                            --处理ROWTYPE_MISMATCH异常
     FETCH emp_cur INTO emp_row;                         --再次提取游标变量数据，输出结果
     DBMS_OUTPUT.PUT_LINE('员工名称：'||emp_row.ename||' 部门编号：'||emp_row.deptno);       
END;


--使用Sys_refcursor类型
DECLARE
   emp_cur SYS_REFCURSOR;                               --定义弱类型游标变量
   emp_row emp%ROWTYPE;
   dept_row dept%ROWTYPE;
BEGIN   
   OPEN emp_cur FOR SELECT * FROM emp WHERE deptno=20;  --打开游标数据
   FETCH emp_cur INTO dept_row;
EXCEPTION
   WHEN ROWTYPE_MISMATCH THEN                           --处理ROWTYPE_MISMATCH异常
     FETCH emp_cur INTO emp_row;                        --重新提取并输出异常结果
     DBMS_OUTPUT.PUT_LINE('员工名称：'||emp_row.ename||' 部门编号：'||emp_row.deptno);       
END;

--代码10.28 在包中使用游标变量
--创建包规范
CREATE OR REPLACE PACKAGE emp_data_action AS
   TYPE emp_type IS REF CURSOR RETURN emp%ROWTYPE;         --定义强类型游标类型
   --定义使游标变量的子程序  
   PROCEDURE getempbydeptno(emp_cur IN OUT emp_type,p_deptno NUMBER); 
END emp_data_action;

--实现包体
CREATE OR REPLACE PACKAGE BODY emp_data_action AS
   --创建在包规范中定义的过程   
   PROCEDURE getempbydeptno(emp_cur IN OUT emp_type,p_deptno NUMBER) IS
     emp_row emp%ROWTYPE;
   BEGIN
     OPEN emp_cur FOR SELECT * from emp WHERE deptno=p_deptno;  --打开游标变量
     LOOP
       FETCH emp_cur INTO emp_row;                              --提取数据
       EXIT WHEN emp_cur%NOTFOUND;
       --输出游标数据
       DBMS_OUTPUT.PUT_LINE('员工名称：'||emp_row.ename||' 部门编号：'||emp_row.deptno);
     END LOOP;
     CLOSE emp_cur;
   END;
END emp_data_action;




DECLARE
   emp_cursors   emp_data_action.emp_type;         --定义在包中定义的游标类型
BEGIN
   emp_data_action.getempbydeptno (emp_cursors, 20);   --调用在包中定义的过程
END;



--创建包规范
CREATE OR REPLACE PACKAGE emp_data_action_err AS
   TYPE emp_type IS REF CURSOR RETURN emp%ROWTYPE;         --定义强类型游标类型
   emp_cur emp_type;
   --定义使游标变量的子程序  
   PROCEDURE getempbydeptno(emp_cur IN OUT emp_type,p_deptno NUMBER);   
END emp_data_action_err;



DECLARE
   TYPE emp_curtype IS REF CURSOR;                       --定义游标类型
   emp_cur emp_curtype;                                  --声明游标类型的变量
BEGIN   
   FOR emp_row IN emp_cur LOOP
      DBMS_OUTPUT.PUT_LINE(emp_row.ename);
   END LOOP;
END;

预见未来to50
关注
  • 1
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
pl/sql---游标
weixin_43363860的博客
06-09 2011
游标 DECLARE CURSOR A IS SELECT EMPNO,ENAME FROM EMP; B A%ROWTYPE; BEGIN OPEN A; LOOP FETCH A INTO B; EXIT WHEN A%NOTFOUND; DBMS_OUTPUT.PUT_LINE(B.EMPNO||' '||B.ENAME); END LOOP; CLOSE A; END; -----LOOP / DECLARE CURSOR
六、PL/SQL 游标
最新发布
weixin_42710036的博客
09-28 1050
PL/SQL 游标
10.2.4修改游标数据
tyohaihai的专栏
09-16 603
修改游标数据：一在游标的声明部分添加FOR  UPDATE子句；一种是在UPDATE或DELETE语句中添加WHERE CURRENT OF 子句。 1.FOR UPDATE 子句 FOR UPDATE子句会对用SELECT语句提取出来的结果进行锁定，相当于给结果集加了一把互斥锁，实行行级锁定。 CURSOR dept_cursor IS SELECT * FROM dept FOR UPD
Oracle_PL/SQL(3) 游标
weixin_30783913的博客
07-25 119
引言:PLSQL数据类型标量数据类型：数字类、字符类、日期类、布尔类(boolean)、复合数据类型：记录(%rowtype)、表、数组引用类型：REF CURSORLOB类型:BLOB、CLOB 1.系统定义的记录：%rowtype使用%rowtype属性定义记录变量:可以基于表或视图定义记录变量当使用%ROWTYPE属性定义记录变量时,记录成员个数,名称,类型与表或视图列的个数， 名称,类...
【Oracle数据库】实验-游标cursor
qq_45746744的博客
12-29 1124
1、游标的四个步骤： declare cursor c_1 is select xm from xs; v_1 xs.xm%type; begin open c_1; fetch c_1 into v_1; dbms_output.put_line(v_1); end; 2、游标+%rowtype declare cursor c_1 is select * from xs; v_1 xs%rowtype; begin open c_1;
PL/SQL游标使用
weixin_34177064的博客
04-09 117
游标只是一个指向查询语句返回的结果的指针，因此在游标定义时将包含一个查询定义。当游标打开后，数据被接收到一块内存区域存储，直到游标关闭。 游标实际上指向的是一块内存区域，这块内存区域位于进程全局区内部，称为上下文区域，在上下文区域中包含如下3类信息 1.查询返回的数据行 2.查询所处理的数据的行号 3.指向共享池中的已分析的SQL语句 游标实际上指向一块内存区域 游标定义时...
Oracle PL/SQL 基础语法、游标、例外
醉耕的博客
02-24 601
一、基础语法PL/SQL 是Oracle对SQL语言的扩展，可以对SQL进行编程。 基本框架set serveroutput on; -- 在SQL Developer中显示输出-- 基本框架 declare -- 必需 -- 声明变量、常量、游标、例外 begin -- 必需 -- do something exception -- 非必需 -- 例外
数据库应用+SQL优化+Git
weixin_55817753的博客
06-25 4760
数据库应用1.1 概念1.1.1 什么是数据库1.1.2 关系型和非关系型1.1.3 关系型数据库1.2 Mysql数据库1.2.1 MySQL数据存放在哪里？1.2.2 MySQL服务端1.2.3 MySQL客户端1：DOS窗口1.2.4 MySQL客户端2：可视化工具1.3 数据库的结构1.3.1 数据库结构1.4 SQL语句1.4.1 定义1.4.2 分类1.5
oracle函数大全
05-28
在Oracle中，函数被用于处理数据，执行计算，以及在SQL查询和PL/SQL程序块中进行各种操作。以下是对"Oracle函数大全"中可能包含的一些关键知识点的详细解释： 1. **字符串函数**： - `LENGTH(str)`：返回字符串`...
CSDN 数据技巧
hxhappy's eyes
04-09 6481
　 取 Access640-605 Remote Access 2.0 考试大纲Access Violations(访问冲突)ACCESS97关于数据库安全的几个问题AccesS密码的打击Access数据库操作中出现的怪现象Access数据库导入Mysql的方法之一ACCESS数据库防止下载大盘点ACCESS数据库向MySQL快速迁移小程序(二)ACCESS数据库向MySQL快速迁移小程序(一)A
收集的一些oracle使用，备份
xuliurong的专栏
04-30 334
收集的一些oracle使用，备份 1、建别名 create synonym tx_user_dbms for param.tx_user_dbms ;2、删除别名 drop synonym tx_group_dbms;3、赋权限 a.表  grant [select][,insert][,update] on TD_WEEK to public; b.存储过程  grant EXECUTE
通俗易懂，什么是.NET?什么是.NET Framework？什么是.NET Core? .Net Web开发技术栈...
07-02 2019
通俗易懂，什么是.NET?什么是.NET Framework？什么是.NET Core? 什么是.NET？什么是.NET Framework?本文将从上往下，循序渐进的介绍一系列相关.NET的概念，先从类型系统开始讲起，我将通过跨语言操作这个例子来逐渐引入一系列.NET的相关概念，这主要包括：CLS、CTS(CLI)、FCL、Windows下CLR的相关核心组成、Wind...
oracle--11游标
05-30 296
 游标-----内存中的一块区域,存放的是select 的结果          游标用来处理从数据库中检索的多行记录（使用SELECT语句）。利用游标，程序可以逐个地处理和遍历一次检索返回的整个记录集。      为了处理SQL语句，Oracle将在内存中分配一个区域，这就是上下文区。这个区包含了已经处理完的行数、指向被分析语句的指针，整个区是查询语句返回的数据行集。游标就是指向上下文...
Oracle数据库—— 游标的创建和应用
weixin_34099526的博客
05-22 380
一、涉及内容 　　游标的创建与应用 二、具体操作  （一）填空题 　　1.PL/SQL 程序块主要包含3个部分：声明部分、（执行部分 ）、异常处理部分。 　　2.自定义异常必须使用（RAISE ）语句引发。 （二）选择题 　　1.下列哪一个不是BOOLEAN变量可能的取值？（D ） 　　　　A.TRUE  B.FALSE  C.NULL D.BLANK 　　2.请查看以下IF语句...
oracle 笔记 游标
Ric
08-11 638
--游标：是Oracle系统在内存中开辟的一个工作区，可以存放select查询结果 --隐式的游标（SQL游标）：不需要open、fetch、close等操作， DECLARE v_deptno NUMBER:=30; BEGIN DELETE FROM emp WHERE deptno=v_deptno; dbms_output.put_line(SQL%ROWCOUNT
Oracle PL/SQL开发基础（第二十五弹：操纵游标数据）
艺术就是爆炸的专栏
08-01 486
LOOP循环如：DECLARE dept_row dept%ROWTYPE; --定义游标结果记录变量 CURSOR dept_cursor IS SELECT * FROM dept; --定义游标变量 BEGIN OPEN dept_cursor; --打开游标 LOOP
显示游标、隐式游标、高级游标
故园
05-25 3487
一。游标 1.定义： 游标是Oracle服务器为SQL语句建立的一个私有的SQL工作区。 2.种类： 显示游标：由编程者明确指定。 隐式游标：在缺省情况下，Oracle服务器以隐式游标来编译和执行SQL。 3.SQL游标属性： 使用SQL游标属性，可以测试SQL语句的输出。 游标属性 说明 SQL%ROWCOUNT 最后依次执行的SQL语句所影响到的数据行（一个整数值），几条数据受...
使用游标
hx05760576的专栏
04-15 484
使用游标(一)显式游标1、PL/SQL包含隐式游标、显式游标。隐式游标用于处理SELECT...INTO...和DML语句，显示游标专门用于处理SELECT语句返回的多行数据。2、使用显式游标包含定义游标、打开游标、提取数据、关闭游标等四个阶段。定义游标语法：CURSOR 游标名 IS select_statemant;打开游标语法：OPEN 游
oracle教程20 游标使用教程和举例（使用游标修改或删除数据for update\nowait子句\of子句）
热门推荐
.... 永远年轻，永远热泪盈眶
04-13 1万+
--按职工的职称涨工资，总裁涨1000元，经理涨500元，其他员工涨300元。 --1：用显示游标的常规方式实现业务需求 DECLARE --定义游标 CURSOR empnew_cursor IS SELECT empno,job FROM empnew; v_empno empnew.empno%TYPE; v_job empnew.job%TYPE; BEGIN --...
Oracle9i教程：第6章-PL/SQL基础解析
"Oracle 9i SQL基础教程，涵盖了PL/SQL的基本构成、结构控制语句、阶段训练和练习。此教程强调了PL/SQL作为SQL的扩展，具有数据封装、异常处理和面向对象编程特性，适合数据库事务处理。此外，还介绍了如何使用块...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值