目录：
一、无源器件：电阻、电感、电容
1、电阻
2、电容
3、电感
二、有源器件：二极管、晶体管
1、Diode(二极管)
2、BJT(双极性晶体管)
3、JFET(结型场效应晶体管)
4、MOS(MOS场效应晶体管)
三、子电路
1、子电路定义开始语句
2、子电路终止语句
3、子电路调用语句★
四、激励源：独力源和受控源
1、直流源(DC Sources)
2、交流小信号源(AC Sources)
3、瞬态源(Transient Sources)
五、器件模型
1、二极管模型
2、BJT管模型
3、MOS管模型
六、分析类型描述语句
1、OP：直流工作点分析
2、DC：直流分析
3、TRAN：瞬态分析
4、NOISE：噪声分析
七、控制语句
1、INCLUDE语句
2、LIB语句
3、PARAM语句
4、DATA语句
5、ALTER语句
6、GLOBAL语句
7、Options语句
八、输出语句
九、示例代码
1、光耦HCPL-3140
2、隔离运放AMC1311
一、无源器件 ：电阻、电感、电容
1、电阻
RXXX n1 n2 <mname> <R=>resistance <AC=val> 电阻值可以是表达式。
R1 1 2 10K
Rac 9 8 1 AC=1e10
Rterm input gnd R='sqrt(HERTZ)'2、电容
CXXX n1 n2 <mname> <C=>capacitance
C1 1 2 1pF3、电感
LXXX n1 n2 <L=>inductance
L1 1 2 1nH二、有源器件：二极管、晶体管
1、Diode(二极管)
DXXX N+ N- MNAME<AREA> <OFF> <IC=VD>
可选项：AREA是面积因子，OFF是直流分析所加的初始条件，IC=VD是瞬态初始条件
注：模型中的寄生电阻串联在正极端
2、BJT(双极性晶体管)
QXXX NC NB NE <NS> MNAME<AREA> <OFF> <IC=VBE,VCE>
NC、NB、NE、NS分别是集电极、基极、发射极和衬底节点，缺省时NS接地。后面与二极管相同。
3、JFET(结型场效应晶体管)
JXXX ND NG NS MNAME<AREA> <OFF> <IC=VDS,VGS>
4、MOS(MOS场效应晶体管)
MXXX ND NG NS NB MNAME <L=VAL> <W=VAL> <Other options>
M为元件名称，ND、NG、NS、NB分别是漏、栅、源和衬底节点。MNAME是模型名，L沟道长，W为沟道宽。
三、子电路
1、子电路定义开始语句
.SUBCKT SUBNAM <node1 node2…>
其中，SUBNAM为子电路名，node1…为子电路外部节点号，不能为零。子电路中的节点号(除接地点)，器件名，模型的说明均是局部量，可以和外部的相同。
.SUBCKT OPAMP 1 2 3 42、子电路终止语句
.ENDS <SUBNAM>
若后有子电路名，表示该子电路定义结束；若没有，表示所有子电路定义结束。
.ENDS OPAMP
.ENDS3、子电路调用语句★
X***** <node1 node2 …> SUBNAM
在Spice中，调用子电路的方法是设定以字母X开头的伪元件名，其后是用来连接到子电路上的节点号，再后面是子电路名。
.SUBCKT INV IN OUT wn=1.2u wp=1.2u
Mn out in 0 0 NMOS W=wn L=1.2u
Mp out in vdd vdd PMOS W=wp L=1.2u
.ENDS
X1 IN 1 INV WN=1.2U WP=3U
X2 1 2 INV WN=1.2U WP=3U
X3 2 OUT INV WN=1.2U WP=3U四、激励源：独立源和受控源
独立源 ：直流源(DC Sources)、交流小信号源(AC Sources)、瞬态源(Transient Sources)、脉冲源、 指数源、正弦源、分段线性源。
1、直流源(DC Sources)
VXXX N+ N- DC VALUE
IXXX N+ N- DC VALUE
V1 1 0 DC=5V
I1 1 0 DC=5mA2、交流小信号源(AC Sources)
VXXX N+ N- AC<ACMAG<ACPHASE>>
IXXX N+ N- AC<ACMAG<ACPHASE>>
其中，ACMAG和ACPHASE分别表示交流小信号源的幅度和相位。
V1 1 0 DC=5V AC 1V3、瞬态源(Transient Sources)
1）脉冲源(又称周期源，PULSE Sources)
VXXX N+ N- PULSE (V1 V2 TD TR TF PW PER)
其中，V1初始值，V2脉动值，TD延时，TR上升时间，TF下降时间，PW脉冲宽度，PER脉冲周期。
Vin 1 0 PULSE (0V 5V 10ns 10ns 10ns 40ns 100ns)2）分段线性源(PWL Sources)
VXXX N+ N- PWL (T1 V1 <T2 V2 T3 V3 „>) <R<=repeat>> <TD=delay>
R=repeat_from_what_time TD=time_delay_before_PWL_start
其中,Vi是Ti时刻的值，repeat是开始重复的起始点，delay是延迟时间
V1 1 0 PWL 60n 0V,120n 0V,130n 5V,170n 5V,180ns 0V,R 0
V2 2 0 PWL 60n 0V,120n 0V,130n 5V,170n 5V,180ns 0V,R 60n3）VXXX N+ N- SIN(V0 VA FREQ TD THETA PHASE)
其中，VO偏置，VA幅度，TD延时，THETA阻尼因子，PHASE相位。
VIN 3 0 SIN (0V 1V 100MEG 2NS 5e7)4）指数源(EXP Sources)
VXXX N+ N- EXP(V1 V2 TD1 TAU1 TD2 TAU2)
V1是初始值，V2是峰值，TD1是上升延迟时间，TAU1是上升时间常数， TD2是下降延迟时间，TAU2是下降时间常数。
VIN 3 0 EXP (-4 -1 5N 30N 40N 80N)五、器件模型
元器件需要模型语句来定义其参数值。模型语句不同于元器件定义描述语句，它是以“.”开头的语句，由关键字.MODEL，模型名称，模型类型和一组参数组成。无源器件定义模型参数即可。
电阻模型：.MODEL 模型名 R keyword=value
NOISE，RX: 热噪声参数，inr＝SQRT(NOISE·4KT/R)
电容模型：.MODEL 模型名 C parameter=value
电感模型：.MODEL 模型名 L parameter=value
1、二极管模型
.MODEL模型名D <LEVEL = val> <keyword = val> ...
电阻、电容、电流参数
.MODEL D D (CO=2PF, RS=1, IS=1P)
.MODEL DFOWLER D (LEVEL=2, TOX=100, JF=1E-10, EF=1E8)
.MODEL DGEO D (LEVEL=3, JS=1E-4, JSW=1E-8)2、BJT管模型
.MODEL mname NPN <(> <pname1 = val1> ... <)>
.MODEL mname PNP <pname1 = val1> ...
模型参数中一般包括LEVEL，说明哪种模型，不同级的模型有不同的模型参数集。
3、MOS管模型
.MODEL模型名PMOS <LEVEL=val> <parameters>
.MODEL模型名NMOS <LEVEL=val> <parameters>
LEVEL=1常用于数字电路，精度低、速度快
LEVEL=2考虑了衬底电荷对电流的影响
LEVEL=13,39,49模拟电路，精度高、速度慢
六、分析类型描述语言
1、OP：直流工作点分析
•严格来说，这不算一种仿真类型。计算直流工作点指令，对于分析电路很有用（要会看.lis文件），会在输出文件中列出一些直流参数和各结点的工作点电压与支路电流、静态功耗。
•一般在任何其它仿真之前都需要计算直流工作点。
•.op time看某一时刻的各个器件和电源的状态。
•.op vol time某一时刻所有节点电压。
•.op cur time某一时刻所有器件和电源的电流。
•默认状态：.ac和.dc分析是初始工作点，.tran默认时间是0。
2、DC：直流分析
•可以对参数和独立电源扫描
•.DC var1 START STOP STEP/<SWEEP var2 type np start2 stop2>
其中，type有DEC(十进位）/OCT（倍频）/LIN（线性）/DATA＝datanm/POI(列表），Np是单位范围内的点数（依type而定）
•注意：
1）对独立源扫描时，var为电源名，而非节点名
2）仿真迟滞特性要正、负双向扫描，
如：.DC Vin 0 5 0.1.DC Vin 5 0 -0.1
3）注意对两个量的扫描，后面的是外循环
4）SWEEP后的变量可是电压、电流或温度等变量
3、TRAN：瞬态分析
.TRAN var1 START=start1 STOP=stop1 STEP=incr1
.TRAN 1NS 100NS *以1ns的步长输出到100ns.AC：交流分析
.AC type np fstart fstop <SWEEP var start stop incr>
or
.AC type np fstart fstop <SWEEP var type np start stop>
or
.AC var1 START = start1 STOP = stop1 STEP = incr1
例：.AC DEC 10 1K 100MEG
•注：一共有4种
DEC –十进制的(decade variation)OCT –八进制的(octave variation)
LIN –线形的(linear variation)POI –列举的(list of points)
4、NOISE：噪声分析
用来计算各个器件的噪声对输出节点的影响并给出其均方根并输出，可完成.AC语句规定的各频率的计算，应在.AC分析之后。
.NOISE ovv srcnam inter
Ovv－输出变量，srcnam－输入源，inter－频率间隔
七、控制语句
1、INCLUDE语句
.INCUDE语句：引用一个文件，被引用的文件置于引用文件前。
例：LNA
.include “me98xxxx/model.sp“
2、LIB语句
.lib ‘<filepath>filename’ entryname
该语句根据文件路径和文件名来调用一个库文件，一般该文件包含器件模型。
例：.lib ‘MODELS’ cmos1
MODELS文件：.MODEL CMOS1 nmos ···
我们仿真中加库的语句应该是
.LIB 'D:\TEST\PROCESS\0.6U BCD V0.1PHASE1.LIB' TT
3、PARAM语句
.PARAM语句：定义一个变量。
.PARAM <parametername> = ‘<Expression> ‘
例子: .PARAM width = 20u .PARAM length = 'sqrt(width)*1.65'
M1 3 2 0 0 NMOS width length
4、DATA语句
.DATA语句：给一个数组赋值。
例子：.DATA D1 width length RL + 50u 20u 1K + 60u 10u 10K + 100u 25u 1K .ENDDATA
5、ALTER语句
.ALTER语句：使用不同的参数和数据以返回一个仿真结果。
语法：.ALTER <title_string>
title_string是任何最长至72个字母的字符串。.alter运行所需的合适的字符串在每个输出列表文件和图形数据文件（.tr#）的标题部分打印出来。
6、GLOBAL语句
.GLOBAL语句：定义全局变量。
.GLOBAL parametername（XX）
例子: .GLOBAL VDD
.GLOBAL VSS
注：上述语句会把所有命名为XX的节点连接起来，包括子电路里面的节点。Global的使用需格外小心，一般仅把电源定义成Global。
7、Options语句
.Options语句：可选设置语句，该语句允许用户重新设置程序的参数或控制程序的功能。
.OPTIONS opt1 <opt2> … <opt=x>
常用的一些如下：
node:列出个节点的元件端点，便于查错；
post:使输出数据使用AvantWaves浏览(即将数据输出到post processor)
list:列出输入元件列表；
八、输出语句
–.PRINT:在输出的list文件中打印数字的分析结果，如果.OPTIONS中有POST则同时输出到post-processor中。
–.PLOT:在输出的list文件中打印低分辨率的曲线（由ASCII字符组成）,如果.OPTIONS中有POST则同时输出到post-processor中。
–.GRAPH：生成用于打印机或PostScript格式的高分辨率曲线。
–.PROBE:把数据输出到post-processor，而不输出到list文件。
–.MEASURE:输出用户定义的分析结果到mt0文件，如果.OPTIONS中有POST则同时输出到post-processor中。
–.OP, .TF, .NOISE, .SENS和.FOUR都提供直接输出功能。
.PRINT antype ov1 <ov2 … ov32>
Antype——AC/DC/TRAN；
Ovi——输出变量，可以有以下形式：
V(1)：节点1的电平；V(1，2)：1、2间的电压；V(R1)：电阻R1的电压；VM(1)：v1的幅值；VR(1)：v1的实部；VI(1)：v1的虚部；VP(1)：v1的相位；VDB(1)：v1的分贝值；（电流与以上类似）
.PLOT
.PLOT：.PLOT antype ov1 <(plo1,phi1)> … <ov32>
+<(plo32,phi32)>(plo1,phi1)－ov1绘图的上下限。
.PROBE
.PROBE：.PROBE antype ov1 … <ov32>
*元件电流引用：BJT: I1(Qx)-Ic，I2(Qx)-Ib, I3(Qx)-Ie, I4(Qx)-衬底电流；MOS:I(Mx)-Ids。
①.PRINT ac V(1) S11(DB) S21(m) S22(DB)；
②.TRAN 1N 200N
③.PROBE V(OUT)
.NOISE v(out) vin 10；
.PRINT noise onoise inoise
.PRINT im(rd)
九、示例代码
1、光耦HCPL-3140
本示例代码按Multism14.2导入第三方SPICE模型(HCPL3140)的方法导入Multisim即可使用。
* HCPL-3140/HCPL-0314 SPICE Macromodel
* Rev. B
* 07/07
* ZFC
*
* This is the behavioural model for the above-mentioned part number.
* It is valid for functional simulation over the range specified below.
* Supply range: 10 to 30V
*
* Macromodels provided by Avago Technologies are not warranted
* as fully representing all of the specifications and operating
* characteristics of the product.
*
* Macromodels are useful for evaluating product performance but they
* cannot model exact device performance under all conditions, nor are
* they intended to replace breadboarding for final verification.
*
* Copyright 2007 Avago Technologies Limited. All Rights Reserved
********************************************************************************
* Anode(pin2)
* | Cathode(pin3)
* | | Common(pin5)
* | | | Output(pin6)
* | | | | Vcc(pin8)
* | | | | |
.SUBCKT HCPL3140 102 103 105 106 108
land 20 102 20n
lcth 23 103 20n
lgnd 10 105 20n
lout 3 106 20n
lvcc 2 108 20n
xled 20 23 22 23 led
rled 22 23 1meg
*This is Ith, bandwidth and amplitude limitation
gpd 10 1 22 23 1
ith 1 10 dc 4.3m
cb 1 10 0.16n
rb 1 10 1500 tc1=0.004
vlimitp 13 10 dc 1
vlimitn 14 10 dc -1
dlimitp 11 13 dmod3 1.430
dlimitn 14 11 dmod3 1.430
rlimit 12 11 1000
elimit 12 10 1 10 1
mshut 11 16 10 10 nmosmod l=10u w=1000000u
.MODEL nmosmod nmos (vto=+0.7)
vshut 15 10 dc 5
rshut1 15 16 1000
rshut2 16 17 1000
eshut 17 10 2 10 -1
*This is output stage and gate drive 输出范围与门驱动
vinside 28 10 dc 30
ql1 3 6 10 npnmodL
ql2 28 7 6 npnmodL
dl1 10 3 dmod3 1.430
dl2 10 6 dmod3 1.430
dl3 6 7 dmod3 1.430
qh1 2 4 3 npnmodH
qh2 2 5 4 npnmodH
dh1 3 2 dmod3 1.430
dh2 3 4 dmod3 1.430
dh3 4 5 dmod3 1.430
gidh 3 5 11 10 0.0005
gidl 10 7 10 11 0.0005
*This is iccl 1.2mA current source cricuit 1.2mA电流源电路
q3 51 50 2 pnpmod
q4 50 50 2 pnpmod
q2 50 52 53 npnmod
q1 52 53 58 npnmod
rst2 51 52 1000
riccl 53 58 1240 tc1=-0.003
qcl 58 59 60 npnmod
gcl 60 59 10 11 0.0001
qdl 60 61 10 npnmod
gdl 10 61 2 10 0.000003
d50 60 59 dmod3 1.430
d51 10 61 dmod3 1.430
rl 58 10 1000000
.MODEL pnpmod pnp (bf=100)
.MODEL npnmod npn (bf=100)
*This is icch 0.7mA current source cricuit 0.7mA电流源电路
q13 151 150 2 pnpmod
q14 150 150 2 pnpmod
q12 150 152 153 npnmod
q11 152 153 158 npnmod
rst12 151 152 1000
ricch 153 158 2000 tc1=-0.0032
qch 158 159 160 npnmod
gch 160 159 11 10 0.0001
qdh 160 161 10 npnmod
gdh 10 161 2 10 0.000002
d150 160 159 dmod3 1.430
d151 10 161 dmod3 1.430
rh 158 10 1000000
.MODEL DMOD3 D IS=2.22P CJO=1P VJ=.376 M=.139 N=1.07 *器件模型
.MODEL NPNMODH
+ NPN
+ IS=1.27E-17 BF=550.35 NF=1.00 ISE=4.61E-17 NE=1.320
+ IKF=7.06E-3 BR=0.11
+ NR=1.00 IKR=10.4E-3 VAR=17.47 VAF=18 RE=4.26 RC=4.12 RB=6.85
+ RBM=68.65
+ CJC=84E-15 CJE=38E-15 CJS=520E-15 MJE=0.50 VJE=0.69 MJC=0.40 VJC=0.60
+ MJS=0.344 VJS=0.60 TF=305P XTF=0.43 ITF=12M
+ IRB=95U PTF=17 XTB=0.202 XTI=3.058 TR=85E-9 EG=1.167
.MODEL NPNMODL
+ NPN
+ IS=1.27E-17 BF=600.35 NF=1.00 ISE=4.61E-17 NE=1.320
+ IKF=7.06E-3 BR=0.11
+ NR=1.00 IKR=10.4E-3 VAR=17.47 VAF=32 RE=.136 RC=2.5 RB=6.85
+ RBM=68.65
+ CJC=84E-15 CJE=38E-15 CJS=520E-15 MJE=0.50 VJE=0.69 MJC=0.40 VJC=0.60
+ MJS=0.344 VJS=0.60 TF=305P XTF=0.43 ITF=12M
+ IRB=95U PTF=17 XTB=0.202 XTI=3.058 TR=85E-9 EG=1.167
*.ENDS HCPL3140 注释掉此句，放在文件的后面
.SUBCKT LED 1 2 7 4 *LED子电路定义开始语句
RSERIES 1 5 2
DELECT 5 2 LEDNOR
ELED 6 4 5 2 1
DOPTIC 6 8 LEDNORC
VSENSE 8 4 DC 0
FPHOTO 4 3 VSENSE 1
RL 3 4 1 tc1=-0.00015
EOUT 7 4 3 4 1
.MODEL LEDNOR D IS=5E-16 N=2 XTI=3 EG=2.1 BV=5 IBV=10u *器件模型
+ CJO=60p VJ=.75 M=.3333 FC=.5 TT=20n
.MODEL LEDNORC D IS=5E-16 N=2 XTI=3 EG=2.1 BV=5 IBV=10u
+ VJ=.75 M=.3333 FC=.5
.ENDS LED *LED子电路终止语句
.ENDS HCPL3140 此处添加2、隔离运放AMC1311
*****************************************************************************
* (C) Copyright 2017 Texas Instruments Incorporated. All rights reserved.
*****************************************************************************
** This model is designed as an aid for customers of Texas Instruments. 该型号是为德州仪器的客户设计的辅助工具
** TI and its licensors and suppliers make no warranties, either expressed TI及其许可人和供应商不作任何明示或暗示的保证
** or implied, with respect to this model, including the warranties of
** merchantability or fitness for a particular purpose. The model is
** provided solely on an "as is" basis. The entire risk as to its quality
** and performance is with the customer
*****************************************************************************
* Released by: Analog eLab Design Center, Texas Instruments Inc.
* Part: AMC1311
* High Impedance, 2-V Input, Reinforced Isolated Amplifier
* Date: 04/02/2019
* Model Type: TINA
* Simulator: TINA-TI
* Simulator Version: 7.0.30.267 SF-TI
* Datasheet: SBAS786 - 23.NOV 2017
*
*****************************************************************************
* version 1.2:
*
*****************************************************************************
* AMC1311 SUBCIRCUIT
* High Impedance, 2-V Input, Reinforced Isolated Amplifier 高阻抗，2V输入，加强型隔离运放
.SUBCKT AMC1311 VDD1 VIN SHTDN GND1 GND2 VOUTN VOUTP VDD2 *AMC1311主要功能：两级滤波放大与可调增益,同时具有防静电保护、供电去耦和信号限幅等保护机制
XDFilter POut1_11 VOCM NOut1 INP GND2 DFilter *调用前级滤波
XFilter POut1_11 NOut1 GND2 VDD2 VOUTN VOCM VOUTP Filter_Block *调用主滤波与放大
XD4 GND2 VOUTN D_D2 *XD1-XD4组成防静电保护电路,防止高压损坏芯片
XD3 VOUTN VDD2 D_D2
XD2 GND2 VOUTP D_D2
XD1 VOUTP VDD2 D_D2
XGain POut1_13 GND1 VDD1 GND1 VDD2 GND2 INP GND2 FSO VGAIN *调用增益控制VGAIN,适应不同信号幅度
R3 GND2 GND1 100G *R3、C1组成供电去耦滤波,减少噪声
C1 GND2 GND1 1.2P
RIO VDD2 VDD1 100G *RIO、CIO组成信号去耦滤波,提高抗干扰能力
CIO VDD2 VDD1 1.2P
XInput VIN SHTDN GND2 POut1_13 FSO VDD1 GND1 Input_circuit *调用输入信号的缓冲限幅
.ENDS
.SUBCKT DFilter POut1 VOCM NOut1 INP GND2 *由运算放大器和滤波电容组成,实现前级滤波,提高信噪比
R25 15 GND2 1
GVCCS3 15 GND2 16 GND2 -1
GVCCS2 NOut1 VOCM VALUE = {0.5*V(15,GND2)}
GVCCS1 VOCM POut1 VALUE = {0.5*V(15,GND2)}
R22 VOCM NOut1 1
R21 POut1 VOCM 1
R6 17 INP 200K
C6 16 GND2 428.833333F
C4 15 17 885.333333F
R5 16 17 200K
.ENDS
.SUBCKT Filter_Block INP INN GND2 VDD2 VOUTN VOCM VOUTP *实现主滤波与放大功能
VPSref 29 GND2 3.3
R21ops 25 0 59
L2ops 25 0 15.650236U
R1 26 25 1
R11ops 27 0 59
L1ops 27 0 62.600944U
R1ops 28 27 1
G2ops 0 26 28 0 1
G1ops 0 28 29 VDD2 14.058532U
XOutputp VM_19 Neg_30 IGND_23 Bias IAVDD_24 VOUTP VDD2 Plus_31 GND2 Vt0p Vt0
+ Output
C7 32 33 3.64P
EVCVS2 32 GND2 35 GND2 1
EVCVS1 34 GND2 36 GND2 1
R16 37 INP 200K
C8 36 35 1.493333P
R15 33 INN 200K
R14 35 33 200K
C5 34 37 3.64P
R11 36 37 200K
XOutputn VM_19 Neg_38 IGND_23 Bias IAVDD_24 VOUTN VDD2 Plus_39 GND2 Vt0p Vt0
+ Output_1
R8 40 34 200K
R22ops 41 0 10
C2ops Veps_18 41 1.607626N
Epsp VOCM Plus_31 Veps_18 0 -1
Epsn Plus_39 VOCM Veps_18 0 -1
R3ops Veps_18 0 990
G3ops 0 Veps_18 26 0 1.010101M
C3 40 42 4.76P
R7 42 32 200K
C4 VOUTP Neg_30 1.026667P
R6 Neg_30 42 100K
R5 VOUTP 42 200K
C2 VOUTN Neg_38 1.026667P
R3 Neg_38 40 100K
R2 VOUTN 40 200K
XBias IAVDD_24 VDD2 IGND_23 GND2 Bias VM_19 Vt0p Vt0 VOCM Bias
.ENDS
*****************************************************************************
.SUBCKT Output VM Neg IGND Bias IAVDD OUT VDD2 Plus GND2 Vt0p Vt0 *Output和Output_1模块使用运算放大器、MOS管放大电路实现滤波放大驱动功能
VAM2 47 VGN_45 ; Current Arrow
VAM1 50 OUT ; Current Arrow
Vo21 IAVDD 53 695.218247M
Vo22 48 IGND 695.218247M
XD5 VGP_44 VDD2 D_LIM1005
XD3 GND2 VGN_45 D_LIM1005
XD6 46 VGP_44 D_LIM1005
XD1 48 VV_43 D_LIM1
XD4 VGN_45 49 D_LIM1005
RO2 VDD2 51 10
RO1 52 GND2 10
XD2 VV_43 53 D_LIM1
C33 VV_43 VM 15.915494F
XT7 50 VGP_44 51 VDD2 Q_PMOS_OUT_L1
+ PARAMS: M=25 W=20U L=0.8U
XT2 OUT VGN_45 52 GND2 Q_NMOS_OUT_L1
+ PARAMS: M=25 W=20U L=0.8U
EVMP2 VDD2 46 VALUE = {LIMIT(1.02*V(VDD2,Vt0p),0,V(VDD2,GND2))}
EVMN2 49 GND2 VALUE = {LIMIT(1.02*V(Vt0,GND2),0,V(VDD2,GND2))}
Ro23 VM Neg 100G
Ro22 Plus VM 100G
Ro21 Neg Plus 1G
Co21 Neg Plus 10F
Rdn2 VGP_44 Vt0p 2.041402MEG
Gdn2 Vt0p VGP_44 VM VV_43 146.95U
Rdn1 47 Vt0 2.041402MEG
Gdn1 Vt0 47 VM VV_43 146.95U
Cf5 OUT 47 1P
Cf4 VGP_44 OUT 1P
Co23 VM Neg 10F
RCo23_RPAR VM Neg 1T
Co22 Plus VM 10F
RCo22_RPAR Plus VM 1T
R83 VV_43 VM 100K
G23 VM VV_43 Plus Neg 10U
.ENDS
.SUBCKT Output_1 VM Neg IGND Bias IAVDD OUT VDD2 Plus GND2 Vt0p Vt0
VAM2 58 VGN_56 ; Current Arrow
VAM1 61 OUT ; Current Arrow
Vo21 IAVDD 64 695.218247M
Vo22 59 IGND 695.218247M
XD5 VGP_55 VDD2 D_LIM1005
XD3 GND2 VGN_56 D_LIM1005
XD6 57 VGP_55 D_LIM1005
XD1 59 VV_54 D_LIM1
XD4 VGN_56 60 D_LIM1005
RO2 VDD2 62 10
RO1 63 GND2 10
XD2 VV_54 64 D_LIM1
C33 VV_54 VM 15.915494F
XT7 61 VGP_55 62 VDD2 Q_PMOS_OUT_L1
+ PARAMS: M=25 W=20U L=0.8U
XT2 OUT VGN_56 63 GND2 Q_NMOS_OUT_L1
+ PARAMS: M=25 W=20U L=0.8U
EVMP2 VDD2 57 VALUE = {LIMIT(1.02*V(VDD2,Vt0p),0,V(VDD2,GND2))}
EVMN2 60 GND2 VALUE = {LIMIT(1.02*V(Vt0,GND2),0,V(VDD2,GND2))}
Ro23 VM Neg 100G
Ro22 Plus VM 100G
Ro21 Neg Plus 1G
Co21 Neg Plus 10F
Rdn2 VGP_55 Vt0p 2.041402MEG
Gdn2 Vt0p VGP_55 VM VV_54 146.95U
Rdn1 58 Vt0 2.041402MEG
Gdn1 Vt0 58 VM VV_54 146.95U
Cf5 OUT 58 1P
Cf4 VGP_55 OUT 1P
Co23 VM Neg 10F
RCo23_RPAR VM Neg 1T
Co22 Plus VM 10F
RCo22_RPAR Plus VM 1T
R83 VV_54 VM 100K
G23 VM VV_54 Plus Neg 10U
.ENDS
*****************************************************************************
.SUBCKT Bias IAVDD VDD2 IGND GND2 Bias VM Vt0p Vt0 VOCM *提供所需的偏置电压,保证放大器工作在线性区。通过调节偏置电压VOCM,可以优化放大器的动态范围
VS2 67 68 1.2
XU5 0 Vocmtemp VOCMTEMP
EVSOCM VOCM GND2 VALUE = {LIMIT(V(Vt0,GND2)*2,0,(1.4461-1.8182M*V(VDD2,GND2))*V(Vocmtemp,0))}
GIb2 IGND Bias VALUE = {48.98M*V(VDD2,GND2)+730.612M}
Rb3 Bias IGND 1 TC=970U,-77N
R3 68 GND2 10MEG
R2 VDD2 69 10MEG
EVCVS1 VM IGND VALUE = {0.5*V(IAVDD,IGND)}
EAVDD IAVDD IGND VALUE = {5*V(Bias,IGND)}
EGND IGND 0 GND2 0 1
EBMG 70 GND2 Vt0 GND2 1
XT4 69 69 VDD2 VDD2 Q_PMOS_OUT_L1_1
+ PARAMS: M=1 W=10U L=4U
XT1 VT1 70 GND2 GND2 Q_NMOS_OUT_L1_1
+ PARAMS: M=9 W=21U L=0.8U
XT3 68 68 GND2 GND2 Q_NMOS_OUT_L1_2
+ PARAMS: M=1 W=10U L=4U
XD2 67 69 D_LIM1_1
Rsp1 VDD2 VT1 2.111111K
GIb1 69 68 Bias IGND 10U
Rpsrr1 69 68 10MEG
EVMP1 Vt0p VDD2 69 VDD2 1
EVMN1 Vt0 GND2 68 GND2 1
.ENDS
.SUBCKT Input_circuit VIN SHTDN GND2 POut1 FSO VDD1 GND1 *构建输入缓冲、限幅保护电路,提高抗干扰能力
VPSref 89 GND1 5
L4 77 0 1.6242U
R12 77 0 999
R4 Venoise 77 1
GVCCS2 0 Venoise 0 78 1
R3 SHTDN GND1 1G
XU3 SHTDN GND1 80 GND1 VDD1 HYSTCOMPGD_VDD
+ PARAMS: VOUTH=1 VOUTL=0 ROUT=100 DELAY=100N
XU1 81 IGND_72 FSO IGND_72 HYSTCOMPG_THLRF
+ PARAMS: VOUTH=1 VOUTL=0 ROUT=100 TDLH=48U TDHL=1U TRISE=1N TFALL=1N VTHRES=0.5
+ VHYST=100m
C3 VIN GND1 2P
C1 VLCM GND1 5P
XU_1 VLCM GND1 VDD1 GND1 IIB
R2 VLCM GND1 1G
R1 VIN VLCM 5K
XD2 GND1 VLCM D_LIMINH ; 04/02/2019
XD1 VLCM VDD1 D_LIMINH
XD9 82 GND1 D_ZR_5V3
XD8 GND1 SHTDN D_D2
XD7 SHTDN VDD1 D_D2
XD6 82 VIN D_D2
XD5 VIN VDD1 D_D2
GVCCS1 IGND_72 81 VALUE = {IF(V(80,GND1)>0.5|V(83,IGND_72)<0.5,1,0)}
R11 81 IGND_72 1
XU2 VDD1 GND1 83 IGND_72 HYSTCOMPGD
+ PARAMS: VTHRES=2.73 VHYST=200M VOUTH=1 VOUTL=0 ROUT=100 DELAY=100N
Eios VLCM POut1 VALUE = {V(Venoise,0)+50.1187N*V(GND1,GND2)+V(VOS,0)+V(Veps_73,0)+V(Venoise,0)}
L3 84 0 1.6242U
R10 84 0 999
R9 78 84 1
Gnoise 0 78 0 85 1.225295
L2 86 0 716.197244N
R8 86 0 9
R7 Veps_73 86 1
G88ps 0 Veps_73 87 0 1
R6 88 0 9
L1 88 0 7.161972U
R5 87 88 1
G8ps 0 87 89 VDD1 446.683592U
XU5 0 VOS VOST
Rnoise2 85 0 4.8263MEG
Rnoise1 85 0 4.8263MEG
XBias GND1 IGND_72 IAVDD_76 VM_75 VDD1 FSO Bias_1
C37 SHTDN GND1 5P
.ENDS
.SUBCKT Bias_1 GND1 IGND IAVDD VM VDD1 SHTDN *提供偏置电压,偏置放大器工作点
Rp1 VDD1 GND1 3.846154MEG TC=-6M,22U
GIS1 91 GND1 VALUE = {(5.4896M*(973.4933M+TEMP*1060.3U)+V(91,GND1)/1.5625K)*(1-V(SHTDN,GND1))}
EVSVM VM IGND IAVDD IGND 400M
EAVDD IAVDD IGND VALUE = {LIMIT(5*(V(VDD1,GND1)-1.4),5,0)}
Rs4 91 GND1 1.5625G TC=-6M,22U
XD1 GND1 91 D_D4
XDZb1 91 VDD1 D_ZB1
EGND IGND 0 GND1 0 1
.ENDS
.SUBCKT D_D2 1 2 *防静电保护二极管,防止高压破坏芯片
D1 1 2 D2
.ENDS
.SUBCKT VGAIN INP INN VDD1 GND1 VDD2 GND2 OUTP OUTN FSO *实现可变增益放大,通过表格查找方式映射控制码和增益系数,调整放大倍数
*EG Gain error
.PARAM TCGERR0= {-30E-6}
.PARAM TCGERRB= {-5E-6}
.PARAM TCGERR= {TCGERR0}
.PARAM EG0= {0.400/100} ;AMC1311
.PARAM EGB= {0.0629519/100} ;AMC1311B
.PARAM EG= { EG0 }
.PARAM Gin={8.2}
.PARAM Gout={1.0}
.PARAM G={8.2} ;AMC1301
.PARAM RG1= {0.01}
.PARAM RG2= {1/Gin}
.PARAM I0 = 1
.PARAM R0 = {1/(I0*Gout)}
.PARAM Rout = {R0*(1 + 2*TCGERR + EG - 96.4519m/100)}
.PARAM TC1= {TCGERR/R0/I0}
.PARAM K=1.2
.PARAM C25={56.0014427*K}
.PARAM B25={0.146489/K}
.PARAM C125={47.45704}
.PARAM B125={0.17289}
.PARAM MC={0}
.PARAM C0={C25 - MC}
.PARAM MB={0}
.PARAM B0={B25 - MB}
.PARAM A0={-0.010854}
.PARAM D0={0.088938}
.PARAM Vclip={2.516}
.PARAM VL={Vclip}
.PARAM VLFSO={-2.6/Rout}
GVDD1 0 G1 TABLE {V(VDD1,GND1)} = (3,0.0617284, 3.50217,0.0345679, 4.00435,0.0296296, 4.50000,0.0320988,
+4.99783,0.0518519, 5.49783,0.0592593)
RG1 G1 0 {RG1}
GVDD2 0 G12 TABLE {V(VDD2,GND1)} = (3,0.0637284, 3.25217,0.0629519, 3.50652,0.0637284, 3.75000,0.0641975,
+4.24783,0.0641975, 4.75217,0.0641975, 5.25217,0.0641975, 5.49783,0.0641975)
RG12 G12 0 {RG1}
G2 0 G2 VALUE = {Limit(V(INP,INN), -VL, VL)}
RG2 G2 0 {RG2}
G1 OUTN OUTP VALUE = {IF(V(FSO,GND1) < 0.5, (C0*(1 + V(G1))*(1 + (V(G12)-EGB))*TANH( B0*(V(G2) + A0) ) + D0), VLFSO)}
ROUT OUTP OUTN RMOD2 {Rout}
.MODEL RMOD2 RES (TC1={TC1} TC2=0 TCE=0)
.ENDS
.SUBCKT D_LIM1005 1 2 *过压保护二极管,防止超过5.3V电压损坏芯片
D1 1 2 D_Lim1005
.ENDS
.SUBCKT D_LIM1 1 2 *保护二极管,防止反向电压损坏
D1 1 2 D_Lim1
.ENDS
.SUBCKT Q_PMOS_OUT_L1 D G S B PARAMS: M = 1 W = 100U L = 10U *P沟道MOS管,实现PMOS管驱动
M1 D G S B Q_PMOS_Out_L1 W = {W} L = {L} M = {M}
.ENDS
.SUBCKT Q_NMOS_OUT_L1 D G S B PARAMS: M = 1 W = 100U L = 10U *N沟道MOS管,实现NMOS管驱动
M1 D G S B Q_NMOS_Out_L1 W = {W} L = {L} M = {M}
.ENDS
.SUBCKT VOCMTEMP 1 2 *温度补偿电路,通过表格映射自动调整偏置
.PARAM R0 = {1/1.44}
GVocmtemp 1 2 table {TEMP} = (-55,1.43532, -39.6341,1.43680, -24.8955,1.43778, -9.84321,1.43901, 4.89547,1.43975, 19.9477,1.44000,
+ 35,1.44025, 49.8955,1.44037, 65.1045,1.44049, 80.1568,1.44025, 94.8955,1.43988, 109.948,1.43926, 124.686,1.43852)
Rout 1 2 {R0}
.ENDS
.SUBCKT Q_PMOS_OUT_L1_1 D G S B PARAMS: M = 1 W = 100U L = 10U *P沟道MOS管,实现PMOS管驱动
M1 D G S B Q_PMOS_Out_L1 W = {W} L = {L} M = {M} AD={W*LS} AS={W*LS} PD={W + 2*LS} PS={W + 2*LS}
+ NRD={LS/W} NRS={LS/W}
.ENDS
.SUBCKT Q_NMOS_OUT_L1_1 D G S B PARAMS: M = 1 W = 100U L = 10U *N沟道MOS管,实现NMOS管驱动
M1 D G S B Q_NMOS_Out_L1 W = {W} L = {L} M = {M} AD={W*LS} AS={W*LS} PD={W + 2*LS} PS={W + 2*LS}
+ NRD={LS/W} NRS={LS/W}
.ENDS
.SUBCKT Q_NMOS_OUT_L1_2 D G S B PARAMS: M = 1 W = 100U L = 10U *N沟道MOS管,实现NMOS管驱动
M1 D G S B Q_NMOS_Out_L1 W = {W} L = {L} M = {M} AD={W*LS} AS={W*LS} PD={W + 2*LS} PS={W + 2*LS}
+ NRD={LS/W} NRS={LS/W}
.ENDS
.SUBCKT D_LIM1_1 1 2
D1 1 2 D_Lim1
.ENDS
.SUBCKT D_ZR_5V3 1 2 *定义5.3V稳压二极管模型参数
D1 1 2 D_Z5V3
.MODEL D_Z5V3 D(IS=1P N=1.0 BV=5.3 IBV=1.0M RS=10 XTI=0 EG=0.48)
.ENDS
.SUBCKT HYSTCOMPGD_VDD inp inm out gnd vdd
+ Params: VoutH=5 VoutL=0 Rout=1 Delay=1N
.PARAM Tdel = {MAX(Delay,MinADel)}
.Param Rdel = {IF((Tdel > 1E-15) & (Rout < 1), 1, Rout)}
.Param VoutM={(VoutH+VoutL)/2}
.Param Cout={Tdel/(0.693*(Rdel+1u))}
.Param Gdlh={1/Rdel}
.Param Gdhl={1*Gdlh}
EVthrH VthrH 0 value = {0.7*V(vdd,gnd)}
EVthrL VthrL 0 value = {0.3*V(vdd,gnd)}
Gthr gnd thr Value= {IF(V(out,gnd) < VoutM, V(VthrH), V(VthrL))}
Rthr gnd thr 1
Gout gnd out Value= {IF((V(inp,inm) > V(thr,gnd)), (VoutH - V(out,gnd))*Gdlh, (VoutL - V(out,gnd))*Gdhl)}
Cout out gnd {Cout}
Rout out gnd {1e5*Rdel}
.ENDS
.SUBCKT HYSTCOMPG_THLRF inp inm out gnd
+ Params: Vthres=0 Vhyst=1 VoutH=5 VoutL=0 Rout=1 Tdlh=1N Tdhl=1N Trise=1N Tfall=1N
.PARAM Tdellh = {MAX(Tdlh,MinADel)}
.PARAM Tdelhl = {MAX(Tdhl,MinADel)}
.Param Rdel = {IF(((Tdellh > 1E-15)|(Tdelhl > 1E-15)) & (Rout < 1), 1, Rout)}
.Param Ro = {IF(((Trise > 1E-15)|(Tfall > 1E-15)) & (Rout < 1), 1, Rout)}
.Param VoutM={(VoutH+VoutL)/2}
.Param Tdmin= 1p
.Param Cdel={Sqrt((Tdelhl+Tdmin)*(Tdellh+Tdmin))/(4.6*(Rdel+1u))}
.Param Gdlh={Sqrt((Tdelhl+Tdmin)/(Tdellh+Tdmin))/Rdel}
.Param Gdhl={(Tdellh+Tdmin)/(Tdelhl+Tdmin)*Gdlh}
.Param Cout={Sqrt(Tfall*Trise)/(2.287*(Ro+1u))}
.Param Gr={Sqrt(Tfall/(Trise+Tdmin))/Ro}
.Param Gf={(Trise+Tdmin)/Tfall*Gr}
.Param VthH={Vthres+Vhyst}
.Param VthL={Vthres-Vhyst}
Rinp inp gnd 1G
Rinm inm gnd 1G
Gthr gnd thr Value= {IF(V(out,gnd) < {VoutM}, {VthH}, {VthL})}
Rthr gnd thr 1
Gouti gnd outi Value= {IF ( (V(inp,inm) > V(thr,gnd)), (VoutH - V(outi,gnd))*Gdlh, (VoutL - V(outi,gnd))*Gdhl)}
Couti outi gnd {Cdel}
Routi outi gnd {1e5*Rdel} ; 05/14/2018
Gthro gnd thro Value= {IF(V(out,gnd) < VoutM, VoutH*0.99, VoutH*0.01)}
Rthro gnd thro 1
Gout gnd out Value= {IF((V(outi, gnd) > V(thro,gnd)), (VoutH - V(out,gnd))*Gr, (VoutL - V(out,gnd))*Gf)}
Cout out gnd {Cout}
Rout out gnd {1e5*Ro} ; 05/14/2018
.ENDS
.SUBCKT IIB 1 2 Vdd Gnd *用于电流镜电路，其中电流镜是一种电路结构，用于生成一个输出电流的副本，通常用于放大器和其他电路中
.PARAM Rtemp = {1/3.50985}
.PARAM RVdd = {1/1.0}
GVocmtemp 0 10 table {TEMP} = (-55,3.84236, -25.2609,3.76847, 4.79130,3.62069, 24.5130,3.50985, 34.9478,3.49754,
+ 49.7130,3.47291, 64.7391,3.47291, 79.7130,3.49754, 94.6348,3.69458, 109.661,3.95320, 124.374,4.35961)
R1 10 0 { Rtemp}
GIibvdd 0 20 table {V(Vdd,Gnd)} = (0,0, 3,1.73219, 3.49652,2.24816, 3.99739,2.61671,
+ 4.50261,3.13268, 5.00348,3.50123, 5.50000,3.86978)
R2 20 0 {RVdd}
GIib 1 2 Value = {V(20)*V(10)*1n}
.ENDS
.SUBCKT D_LIMINH 1 2 *限流二极管模型
D1 1 2 D_Liminh
.MODEL D_Liminh D( IS=3.5p N=1.0 RS=0 XTI=0 AF=0 KF=0 EG=0.55) ; 04/02/2019
.ENDS
.PARAM MinADel = {1n}
.SUBCKT HYSTCOMPGD inp inm out gnd *迟滞比较器
+ Params: Vthres=0 Vhyst=1 VoutH=5 VoutL=0 Rout=1 Delay=1N
.PARAM Tdel = {MAX(Delay,MinADel)}
.Param Rdel = {IF((Tdel > 1E-15) & (Rout < 1), 1, Rout)}
.Param VoutM={(VoutH+VoutL)/2}
.Param VthH={Vthres+Vhyst}
.Param VthL={Vthres-Vhyst}
.Param Cout={Tdel/(0.693*(Rdel+1u))}
.Param Gdlh={1/Rdel}
.Param Gdhl={1*Gdlh}
Gthr gnd thr Value= {IF(V(out,gnd) < {VoutM}, {VthH}, {VthL}) }
Rthr gnd thr 1
Gout gnd out Value= {IF((V(inp,inm) > V(thr,gnd)), (VoutH - V(out,gnd))*Gdlh, (VoutL - V(out,gnd))*Gdhl)}
Cout out gnd {Cout}
Rout out gnd {1e5*Rdel}
.ENDS
.SUBCKT VOST 1 2 *输入失调电压模型
.PARAM R0 = 1k
.PARAM DVOS_DT= {-20.0U}
.PARAM VOFFS = {-119.0U + 2*DVOS_DT}
.PARAM I0 = {VOFFS/R0}
.PARAM TC1= {DVOS_DT/R0/I0}
R2 40 0 RMOD2 {R0}
I2 40 0 {I0}
E3 1 2 40 0 1
.MODEL RMOD2 RES (TC1={TC1} TC2=0 TCE=0)
.ENDS
.SUBCKT D_D4 1 2 *简单的二极管模型
D1 1 2 DD
.MODEL DD D( IS=10n N=0.50 RS=1 XTI=0 Eg=0.35)
.ENDS
.SUBCKT D_ZB1 1 2 *锗二极管模型
D1 1 2 D_4_9V
CD 1 2 10P
.MODEL D_4_9V D(IS=1n N=1.0 BV=2.4 IBV=1.0m RS=0 XTI=0 EG=0.55)
.ENDS
.SUBCKT D_LIMCM 1 2 *限流二极管模型
D1 1 2 D_Limcm
.MODEL D_LIMcm D(IS=1p N=1.0 RS=100 XTI=0 AF=0 KF=0 EG=1.1)
.ENDS
.SUBCKT D_LIM1T 1 2 *限流二极管模型
D1 1 2 D_Lim1T
.ENDS
.MODEL D_LIM1T D(IS=10F N=1.0 RS=10 XTI=0 AF=0 KF=0 EG=0.555) *描述了一系列不同类型的二极管和场效应管模型，用于在电路设计中模拟和分析不同的元器件行为
*Parameters: 0.4um CMOS
.PARAM LS = 1.0U
.PARAM VTOHP = 0.75
.PARAM VTOHN = 0.75
.PARAM LAMBDA = 10M
.PARAM GAMMA = 0.00
.PARAM KAPPA = 1.0
.PARAM THETA = 0.23
.PARAM ETA = 3
.PARAM KPN = {UON*COX * 1e-4}
.PARAM KPP = {UOP*COX * 1e-4}
.PARAM LDN = 0.09U
.PARAM LDP = 0.09U
.PARAM RSW = 1810
.PARAM RSN = 1.41
.PARAM RDS = 10MEG
.PARAM VBMUL = 1E6
.PARAM RPAR = 1T
.PARAM CBDJ = 1.0
.PARAM CBDS = 1.0
.PARAM CGBF = 1.0
.PARAM PBP = 0.7
.PARAM PBN = 0.7
.PARAM UON = 450
.PARAM UOP = 450
.PARAM CJN = {200U}
.PARAM CJP = {400U}
.PARAM CJSWN = {1.2N}
.PARAM CJSWP = {2.4N}
.PARAM XJN = 0.15U
.PARAM CGSON = {0.6*XJN*COX}
.PARAM CGDON = {CGSON}
.PARAM CGBON = {CGBF*CGDON}
.PARAM XJP = 0.18U
.PARAM CGSOP = {0.6*XJP*COX}
.PARAM CGDOP = {CGSOP}
.PARAM CGBOP = {CGBF*CGDOP}
.PARAM EPSSIO2 = {3.9*8.854214871E-12}
.PARAM TOX = 80E-10
.PARAM COX = {EPSSIO2/TOX}
.MODEL Q_NMOS NMOS Level=1 L=2U W=10U KP={KPN} VTO={VTOHN} AF=0 KF=0
.MODEL Q_PMOS PMOS Level=1 L=2U W=10U KP={KPP} VTO={-VTOHP} AF=0 KF=0
.MODEL Q_NMOS_Out_L1 NMOS LEVEL=1 L=10U W=100U KP={KPN} VTO={VTOHN} LAMBDA={LAMBDA}
+ CJ={CJN} CJSW={CJSWN} CGSO={CGSON} CGDO={CGDON} RSH= 4 PB={PBN} LD= {LDN} RDS={RDS}
.MODEL Q_NMOS_Out NMOS LEVEL=3 L=10U W=100U KP={KPN} VTO={VTOHN} THETA={THETA}
+ CJ={CJN} CJSW={CJSWN} CGSO={CGSON} CGDO={CGDON} RSH= 4 PB={PBN} LD= {LDN} RDS={RDS} TOX={TOX} XJ={XJN}
+ GAMMA={GAMMA} KAPPA={KAPPA} ETA={ETA}
.MODEL Q_PMOS_Out_L1 PMOS LEVEL=1 L=10U W=100U KP={KPP} VTO={-VTOHP} LAMBDA={LAMBDA}
+ CJ={CJP} CJSW={CJSWP} CGSO={CGSOP} CGDO={CGDOP} RSH=4 PB={PBP} LD= {LDP} RDS={RDS}
.MODEL Q_PMOS_Out PMOS LEVEL=3 L=10U W=100U KP={KPP} VTO={-VTOHP} THETA={THETA}
+ CJ={CJP} CJSW={CJSWP} CGSO={CGSOP} CGDO={CGDOP} RSH=4 PB={PBP} LD= {LDP} RDS={RDS} TOX={TOX} XJ={XJP}
+ GAMMA={GAMMA} KAPPA={KAPPA} ETA={ETA}
.MODEL D_Lim1 D( IS=10F N=1.0 RS=1000 XTI=0 AF=0 KF=0 EG=1.11)
.MODEL D_Lim100 D( IS=10F N=1.0 RS=100 XTI=0 AF=0 KF=0 EG=1.11)
.MODEL D_Lim1005 D( IS=10F N=0.5 RS=100 XTI=0 AF=0 KF=0 EG=0.555)
.MODEL D_Lim100_05 D( IS=10F N=0.5 RS=100 XTI=0 AF=0 KF=0 EG=0.555)
.MODEL D_Lim10 D( IS=10F N=1.0 RS=10 XTI=0 AF=0 KF=0 EG=1.11)
.MODEL D_Lim2 D( IS=10f N=0.5 RS=1 XTI=0 AF=0 KF=0 EG=0.555 )
.MODEL D_Lim3 D( IS=1E-18 N=1.0 RS=1 XTI=0 AF=0 KF=0)
.MODEL D_Lim4 D( IS=10F N=1.0 RS=1m XTI=0 AF=0 KF=0)
.MODEL D1 D( IS=1p N=1.0 RS=0 XTI=3 AF=0 KF=0 )
.MODEL DZ_14V D( IS=1p N=1.0 BV=14.0 IBV=5.0M XTI=0 RS=10)
.MODEL DZ_80V D( IS=1p N=1.0 BV=80.0 IBV=5.0M XTI=0 RS=10)
.MODEL D2 D( IS=1p N=1.0 XTI=0 RS=10)
我与春风皆过客，你携秋水揽星河。觉得不错，动动发财的小手点个赞哦！
扫一扫
763
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
