AS3 VerticalScroller ---- 垂直滚动条，在水平滚动条的基础上，使用10分钟左右完成了

最新推荐文章于 2014-11-04 11:42:42 发布
最新推荐文章于 2014-11-04 11:42:42 发布
阅读量2.6k 收藏 1
点赞数
分类专栏： Jave's AS3-Control 文章标签： function class button radiobutton bt import
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/linjf520/article/details/7445036
版权

向上按钮：

//package
//{
//	public class VerticalUpButton extends Button
//	{
//		public function VerticalUpButton($text:String="button")
//		{
//			super($text);
//		}
//	}
//}

package
{
	public class VerticalUpButton extends Button
	{
		public function VerticalUpButton()
		{
			super();
			
			width=10;
			height=10;
		}
		
		protected override function refreshBackground():void
		{
			//super.refreshBackground();
			
			//背景也居中
			this.graphics.clear();
			this.graphics.beginFill(0x55aa00, 0.5);
			this.graphics.drawRect(0,0,10,10);
			this.graphics.endFill();
			
			//边框
			this.graphics.moveTo(0,0);
			this.graphics.lineStyle(1,0,.5);
			this.graphics.lineTo(10,0);
			this.graphics.lineTo(10,10);
			this.graphics.lineTo(0,10);
			this.graphics.lineTo(0,0);
			
			//三角形
			this.graphics.moveTo(5,2);
			this.graphics.lineStyle(1,0,.5);
			this.graphics.lineTo(8,8);
			this.graphics.lineTo(2,8);
			this.graphics.lineTo(5,2);
		}
	}
}

向下按钮类： 

//package
//{
//	public class VerticalDownButton
//	{
//		public function VerticalDownButton()
//		{
//		}
//	}
//}
package
{
	public class VerticalDownButton extends Button
	{
		public function VerticalDownButton()
		{
			super();
			
			width=10;
			height=10;
		}
		
		protected override function refreshBackground():void
		{
			//super.refreshBackground();
			
			//背景也居中
			this.graphics.clear();
			this.graphics.beginFill(0x55aa00, 0.5);
			this.graphics.drawRect(0,0,10,10);
			this.graphics.endFill();
			
			//边框
			this.graphics.moveTo(0,0);
			this.graphics.lineStyle(1,0,.5);
			this.graphics.lineTo(10,0);
			this.graphics.lineTo(10,10);
			this.graphics.lineTo(0,10);
			this.graphics.lineTo(0,0);
			
			//三角形
			this.graphics.moveTo(5,8);
			this.graphics.lineStyle(1,0,.5);
			this.graphics.lineTo(8,2);
			this.graphics.lineTo(2,2);
			this.graphics.lineTo(5,8);
		}
	}
}

整个垂直滚动条组件： 

//package
//{
//	public class VerticalScroller extends Control
//	{
//		public function VerticalScroller()
//		{
//			super();
//		}
//	}
//}

package
{
	import controlsEvents.ScrollerEvent;
	
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.filters.GlowFilter;
	import flash.geom.Point;
	import flash.utils.getTimer;
	
	/**
	 * 垂直滚动条
	 * (纯graphics控件，后期可能要考虑开放更多的一些重绘制接口：方便外部的写重绘制这部分)
	 * @author Jave.Lin
	 */
	public class VerticalScroller extends Control
	{
		private var _upBtn:VerticalUpButton;//向上的按钮--减量操作
		private var _downBtn:VerticalDownButton;//向右的按钮--增量操作
		private var _rollPacker:ScrollPacker;//滚动器
		private var _buttonInterval:Number=20;
		private var _curValue:int=0;//当前值
		private var _minValue:int=0;//最小值
		private var _maxValue:int=100;//最大值
		private var _increment:int=5;//每次操作的增/减量
		private var _isAdding:Boolean=false;
		//续持性快速操作的控件参数
		private var _quickCurTime:int=0;
		private var _quickOperateTime:int=0;
		private var _quickOperateTimeMax:int=500;
		private var _maxPos:Number;//滚动器最远的距离
		private var _curVisibleRate:Number=1;//当前可视范围比率，直接影响滚动器的宽度
		
		public function get curVisibleRate():Number
		{
			return _curVisibleRate;
		}
		
		public function set curVisibleRate(value:Number):void
		{
			if(_curVisibleRate!=value)
			{
				_curVisibleRate=value;
				if(_curVisibleRate<=0)_curVisibleRate=0;
				if(_curVisibleRate >=1)_curVisibleRate=1;
				onLayout();
			}
		}
		
		public function get maxValue():int
		{
			return _maxValue;
		}
		
		public function set maxValue(value:int):void
		{
			if(_maxValue!=value)
			{
				if(_minValue>value)throw new Error("HorizontalScroller maxValue less then minValue error! maxValue:"+value+" minValue:"+_minValue);
				_maxValue=value;
				if(curValue>_maxValue)curValue=_maxValue;
			}
		}
		
		public function get minValue():int
		{
			return _minValue;
		}
		
		public function set minValue(value:int):void
		{
			if(_minValue!=value)
			{
				if(value>_maxValue)throw new Error("HorizontalScroller minValue more then maxValue error! minValue:"+value+" maxValue:"+_maxValue);
				_minValue=value;
				if(curValue<_minValue)curValue=_minValue;
			}
		}
		
		public function get curValue():int
		{
			return _curValue;
		}
		
		public function set curValue(value:int):void
		{
			if(_curVisibleRate>=1)return;
			if(_curValue!=value)
			{
				var preValue:int=value;
				if(preValue<_minValue)preValue=_minValue;
				else if(preValue>_maxValue)preValue=_maxValue;
				if(preValue!=_curValue)
				{
					_curValue=preValue;
					if(_minValue==_maxValue)
					{
						_rollPacker.y=fixAndSetRollPackerY(_upBtn.height);
					}
					else
					{
						_rollPacker.y=fixAndSetRollPackerY(_upBtn.height+(_buttonInterval-_rollPacker.height)*((_curValue-_minValue)/(_maxValue-_minValue)));
					}
					
					dispatchEvent(new ScrollerEvent(ScrollerEvent.VALUE_CHANGED,_curValue));
				}
			}
		}
		
		public override function get width():Number
		{
			return super.width;
		}
		
		public override function get height():Number
		{
			if(isNaN(_h))
			{
				_h=super.height;
			}
			return _h;
		}
		
		public override function set height(value:Number):void
		{
			if(_h!=value)
			{
				var sourceBI:Number=_buttonInterval;
				var sumH:Number=_upBtn.height+_downBtn.height;
				_buttonInterval=value-sumH;
				if(_h<value)
				{
					_h=value;
					if(_buttonInterval<10)
					{
						_buttonInterval=10;
						_h=sumH+_buttonInterval;
					}
				}
				else
				{
					_h=value;
				}
				refreshBackground();
				onLayout();
			}
		}
		
		public function VerticalScroller()
		{
			super();
		}
		
		private function fixAndSetRollPackerY(prePos:Number):Number
		{
			if(prePos<_upBtn.height)prePos=_upBtn.height;
			else if(prePos>_maxPos)prePos=_maxPos;
			return prePos;
		}
		
		private function yTransformToValueAndSetIt(prePos:Number):void
		{
			if(_curVisibleRate>=1)return;
			if(_rollPacker.y==prePos)
			{
				return;
			}
			curValue=(prePos-_upBtn.height)/(_maxPos-_upBtn.height)*(_maxValue-_minValue)+_minValue;
		}
		
		protected override function initialize():void
		{
			_upBtn=new VerticalUpButton();
			addChild(_upBtn);
			
			_rollPacker=new ScrollPacker();
			addChild(_rollPacker);
			
			_downBtn=new VerticalDownButton();
			addChild(_downBtn);
			
			if(stage)
			{
				onAddedToStageHandler();
			}
			else
			{
				addEventListener(Event.ADDED_TO_STAGE,onAddedToStageHandler);
			}
			
			this.width=_upBtn.width;
			this.height=100;
			
			onLayout();
			
			refreshBackground();
		}
		
		private function onLayout():void
		{
			_upBtn.x=0;
			_upBtn.y=0;
			
			_rollPacker.x=0;
			_rollPacker.y=_upBtn.height;
			_rollPacker.height=(1-_curVisibleRate)*_buttonInterval;
			_rollPacker.width=_upBtn.width;
			
			_downBtn.x=0;
			_downBtn.y=_upBtn.y+_upBtn.height+_buttonInterval;
			
			_maxPos=_upBtn.height+_buttonInterval-_rollPacker.height;
		}
		
		private function onAddedToStageHandler(e:Event=null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE,onAddedToStageHandler);
			
			addEventListener(Event.REMOVED_FROM_STAGE,onRemovedFromStageHandler);
			_upBtn.addEventListener(MouseEvent.CLICK,onUpBtnMouseClickHandler);
			_upBtn.addEventListener(MouseEvent.MOUSE_OUT,onUpBtnMouseOutHandler);
			_upBtn.addEventListener(MouseEvent.MOUSE_DOWN,onUpBtnMouseDownHandler);
			_upBtn.addEventListener(MouseEvent.MOUSE_UP,onUpBtnMouseUpHandler);
			_downBtn.addEventListener(MouseEvent.CLICK,onDownBtnMouseClickHandler);
			_downBtn.addEventListener(MouseEvent.MOUSE_OUT,onDownBtnMouseOutHandler);
			_downBtn.addEventListener(MouseEvent.MOUSE_DOWN,onDownBtnMouseDownHandler);
			_downBtn.addEventListener(MouseEvent.MOUSE_UP,onDownBtnMouseUpHandler);
			_rollPacker.addEventListener(MouseEvent.MOUSE_DOWN,onRollPackerMouseDownHandler);
		}
		//鼠标点下滚动器时，滚动器的备份坐标
		private var _mouseDownRollPackerSourceY:Number=0;
		//鼠标点下滚动器时，相对舞台的鼠标x坐标
		private var _mouseDownStageMouseSourceY:Number=0;
		//鼠标点下滚动器时，相对舞台的上一次的鼠标x坐标
		private var _lastStageMouseY:Number=0;
		
		private function onStageEnterFrameHandler(e:Event):void
		{
			if(_lastStageMouseY!=stage.mouseY)
			{
				yTransformToValueAndSetIt(fixAndSetRollPackerY(_mouseDownRollPackerSourceY+(stage.mouseY-_mouseDownStageMouseSourceY)));
				_lastStageMouseY=stage.mouseY;
			}
		}
		
		private function onStageMouseUpHandler(e:MouseEvent):void
		{
			stage.removeEventListener(Event.ENTER_FRAME,onStageEnterFrameHandler);
			_rollPacker.addEventListener(MouseEvent.MOUSE_DOWN,onRollPackerMouseDownHandler);
		}
		
		private function onRollPackerMouseDownHandler(e:MouseEvent):void
		{
			_mouseDownRollPackerSourceY=_rollPacker.y;
			_mouseDownStageMouseSourceY=stage.mouseY;
			_rollPacker.removeEventListener(MouseEvent.MOUSE_DOWN,onRollPackerMouseDownHandler);
			stage.addEventListener(Event.ENTER_FRAME,onStageEnterFrameHandler);
			stage.addEventListener(MouseEvent.MOUSE_UP,onStageMouseUpHandler);
		}
		
		private function onDownBtnMouseClickHandler(e:MouseEvent):void
		{
			if(_curVisibleRate>=1)return;
			curValue+=_increment;
		}
		
		private function onDownBtnMouseUpHandler(e:MouseEvent):void
		{
			removeEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
			_quickOperateTime=0;
		}
		
		private function onDownBtnMouseDownHandler(e:MouseEvent):void
		{
			if(_curVisibleRate>=1)return;
			_quickCurTime=getTimer();
			_isAdding=true;
			addEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
		}
		
		private function onDownBtnMouseOutHandler(e:MouseEvent):void
		{
			removeEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
			_quickOperateTime=0;
		}
		
		private function onUpBtnMouseUpHandler(e:MouseEvent):void
		{
			removeEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
			_quickOperateTime=0;
		}
		
		private function onUpBtnMouseDownHandler(e:MouseEvent):void
		{
			if(_curVisibleRate>=1)return;
			_quickCurTime=getTimer();
			_isAdding=false;
			addEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
		}
		
		private function onUpBtnMouseOutHandler(e:MouseEvent):void
		{
			removeEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
			_quickOperateTime=0;
		}
		
		private function onUpBtnMouseClickHandler(e:MouseEvent):void
		{
			if(_curVisibleRate>=1)return;
			curValue-=_increment;
		}
		
		private function onEnterFrameHandler(e:Event):void
		{
			_quickOperateTime+=getTimer()-_quickCurTime;
			if(_quickOperateTime>_quickOperateTimeMax)
			{
				if(_isAdding)
				{
					curValue+=_increment;
				}
				else
				{
					curValue-=_increment;
				}
			}
		}
		
		private function onRemovedFromStageHandler(e:Event):void
		{
			removeEventListener(Event.REMOVED_FROM_STAGE,onRemovedFromStageHandler);
			_upBtn.removeEventListener(MouseEvent.CLICK,onUpBtnMouseClickHandler);
			_upBtn.removeEventListener(MouseEvent.MOUSE_OUT,onUpBtnMouseOutHandler);
			_upBtn.removeEventListener(MouseEvent.MOUSE_DOWN,onUpBtnMouseDownHandler);
			_upBtn.removeEventListener(MouseEvent.MOUSE_UP,onUpBtnMouseUpHandler);
			_downBtn.removeEventListener(MouseEvent.CLICK,onDownBtnMouseClickHandler);
			_downBtn.removeEventListener(MouseEvent.MOUSE_OUT,onDownBtnMouseOutHandler);
			_downBtn.removeEventListener(MouseEvent.MOUSE_DOWN,onDownBtnMouseDownHandler);
			_downBtn.removeEventListener(MouseEvent.MOUSE_UP,onDownBtnMouseUpHandler);
			_rollPacker.removeEventListener(MouseEvent.MOUSE_DOWN,onRollPackerMouseDownHandler);
			stage.removeEventListener(Event.ENTER_FRAME,onStageEnterFrameHandler);
			stage.removeEventListener(MouseEvent.MOUSE_UP,onStageMouseUpHandler);
		}
		
		protected override function refreshBackground():void
		{
			this.graphics.clear();
			//背景
			this.graphics.beginFill(0x008800,.5);
			this.graphics.drawRect(0,0,width,height);
			this.graphics.endFill();
		}
	}
}

测试代码： 

package
{
	import controlsEvents.RadioButtonEvent;
	import controlsEvents.ScrollerEvent;
	
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.MouseEvent;
	
	public class ControlsTest extends Sprite
	{
		private var rbt:RadioButton;
		private var bt:Button;
		private var hs:HorizontalScroller;
		private var vs:VerticalScroller;
		private var hsLb:Label;
		private var vsLb:Label;
		
		public function ControlsTest()
		{
			stage.color=0;
			stage.frameRate=60;
			stage.align=StageAlign.TOP_LEFT;
			stage.scaleMode=StageScaleMode.NO_SCALE;
			
			rbt=new RadioButton();
			rbt.text="test";
			rbt.x=50;
			rbt.y=50;
			rbt.checked=true;
			
			addChild(rbt);
			
			rbt.addEventListener(RadioButtonEvent.ON_CHECKED_CHANGED,onCheckedChangedHandler);
			
			bt=new Button("testButton");
			addChild(bt);
			
			bt.x=100;
			bt.y=100;
			bt.addEventListener(MouseEvent.CLICK,onBtClickHandler);
			
			//bt.width=50;
			
			hs=new HorizontalScroller();
			hs.curVisibleRate=.5;
			addChild(hs);
			
			hs.x=100;
			hs.y=200;
			hs.maxValue=1000;
			hs.minValue=500;
			
			hs.width=200;
			hs.addEventListener(ScrollerEvent.VALUE_CHANGED,onHsValueChangedHandler);
			
			hsLb=new Label();
			addChild(hsLb);
			hsLb.x=100;
			hsLb.y=200+10;
			hsLb.text="HorizontalScroller.value:"+hs.curValue;
			
			vs=new VerticalScroller();
			vs.curVisibleRate=.5;
			addChild(vs);
			
			vs.x=100;
			vs.y=250;
			vs.maxValue=1000;
			vs.minValue=500;
			
			vs.height=200;
			vs.addEventListener(ScrollerEvent.VALUE_CHANGED,onVsValueChangedHandler);
			
			vsLb=new Label();
			addChild(vsLb);
			vsLb.x=100;
			vsLb.y=200+60;
			vsLb.text="HorizontalScroller.value:"+vs.curValue;
		}
		
		private function onBtClickHandler(e:MouseEvent):void
		{
			hs.minValue+=100;
			if(hs.minValue>=hs.maxValue)
			{
				hs.minValue=0;
			}
			hs.curVisibleRate+=.1;
			if(hs.curVisibleRate>=1)
			{
				hs.curVisibleRate=.1;
			}
		}
		
		private function onVsValueChangedHandler(e:ScrollerEvent):void
		{
			vsLb.text="VerticalScroller.value:"+e.value;
		}
		
		private function onHsValueChangedHandler(e:ScrollerEvent):void
		{
			hsLb.text="HorizontalScroller.value:"+e.value;
		}
		
		private function onCheckedChangedHandler(e:RadioButtonEvent):void
		{
			trace(rbt.checked);
		}
	}
}

运行效果图：


Jave.Lin
关注
  • 0
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
as3滚动条设计
xianquan009的专栏
01-12 840
as3自定义滚动条制作方法： package { import flash.display.*; import flash.events.*; import flash.filters.*; import flash.geom.*; /** * ...滚动条组件 * @author qxq */ public class Scrollbar extends S
AS3 滚动条
07-02
AS3滚动条，可自定义横向还是竖向，带源码
as3的滚动条
10-13
用flash的as3写的横向和纵向的滚动条。有源码
as3 水平滚动条
xinhua0228的专栏
04-29 456
具体使用见附件水平滚动条.rar
AS3滚动条类
weixin_33704591的博客
05-30 389
"分享"一个比较好的AS3.0 滚动条（鼠标滚动+横竖都全），功能都备注，支持左右键：myScroll.direction="H"; //方向——左右滚动为"H"，上下滚动为"L"。[默认:"L"]myScroll.tween=5; //缓动——1为不缓动，数字越大缓动越明显。[默认:5]myScroll.elastic=false; ...
10-模拟滚动条.html
最新发布
02-15
10-模拟滚动条.html
vue使用keep-alive保持滚动条位置的实现方法
10-17
在开发使用Vue框架的应用时，我们常常需要在用户在页面间切换时保持滚动条的位置，以改善用户体验。然而，当我们使用Vue内置的<keep-alive>组件来缓存组件状态时，会发现滚动条位置并没有被自动保存。为了解决这个...
Element-ui之ElScrollBar组件滚动条的使用方法
10-18
例如，在原文中提到的使用火狐浏览器时，通过优化样式调整滚动条可能无法兼容，使用 Element-ui 的 ElScrollBar 组件则可以避免此类问题。 2. ElScrollBar 组件的属性和用法 ElScrollBar 组件提供了几个关键属性，...
详解使用vue-router进行页面切换时滚动条位置与滚动监听事件
12-12
在使用vue-router进行页面切换时，发现滚动条所处的位置被自动记录了下来，且在另一个组件内定义的滚动监听事件仍会运行，着实吃了一大惊。。。 说说我的破解方法： 1、在每个需要用vue-router切换的组件的mounted...
vue中使用vue-router切换页面时滚动条自动滚动到顶部的方法
01-19
有时候我们需要页面滚动条滚动到某一固定的位置，一般使用Window scrollTo() 方法。 语法就是：scrollTo(xpos,ypos) xpos：必需。要在窗口文档显示区左上角显示的文档的 x 坐标。 ypos：必需。要在窗口文档显示区...
as3 滚动条 AsScroolBar 水平垂直
12-31
给可视对象添加滚动条 new AsScroolBar()加入显示列表 AsScroolBar(_controlUI:DisplayObject,_scrollWidth:int,_scrollHeight:int,_stepNum:int=20)
AS3横竖滚动条
12-04
纯AS3滚动条，横竖两种单独方向滚动。ScrollBar，拖动滚动条，滚动显示整张图片。
flash元件滚动条(AS3.0)
04-21
这个元件滚动条我用了将近两年了，2011年初我还在天地会论坛里发布过我的最初版本。在这两年时间里很多项目里都应用过，可以说是我经过了两年左右的不停完善，为了最大化的重复利用性，做了很多次大小改动。从最初下载的火山动态文本滚动条V5到现在的版本，优化了很多，也改了些小bug，目前版本不能说非常完美但也自认为很棒了。 今天我就将多年的成果贡献出来，让大家借鉴或批评^_^，今天我还完善了一下，以后我还会继续完善的，毕竟这个是经常会用到的东东。 先介绍下我这个flash拖动条吧，AS3.0，拖动时有缓动效果，没有用到第三方动画类，内容高度可变化，支持随时改动拖动条的高度，以适应新区域，例如跟随窗口变化，支持鼠标滚轮操作。额外功能，可在外部监听滚动状态。
as3滚动条制作
03-18
实用as3滚动条,flash常用滚动条源码
as3 滚动条控制元件移动 带缓冲效果
06-24
由于带滚动条的动态文本框无法竖着显示文字，于是通过把文本框转换成元件，遮罩层盖在内容层上，实现拉滚动条，元件左右移动，在遮罩层的帮助下，实现竖排文字左右移动的效果，然后通过代码加入移动的缓冲效果，注意最后一帧的代码是跳转到前一帧，通过循环才能实现移动缓冲的效果，而不是在同一帧内实现。。。
AS3 HorizontalScroller---- 水平滚动条控件，细节是魔鬼
Jave.Lin 的学习笔记
04-10 2278
水平滚动条的，向右按钮： package { public class HorizontalScrollerLeftButton extends Button { public function HorizontalScrollerLeftButton() { super(); width=10; height=10; } protecte
用纯AS写滚动条
wangangie22
04-04 250
 前两个星期抽时间看了看一直很感兴趣却没时间研究的XML类和绘图API 觉得也没之前想象的那么神秘：） 用了三个晚自习的时间用AS1.0写了这个纯AS+XML的滚动条，算做练习吧。 请高手多多指教！ [1b]下面是所有的AS代码：[/1b] //%%%%%%%%%%%%MC类自定义方法%%%%%%%%%%%%// //——————绘图方法————// //三角型方法 Movi...
一个简单的文本滚动条类 as3
hereson
06-13 273
最近一直做会议与AS3有关项目今天花了点时间写了一个可以选择套皮肤，或无皮肤AS3.0文本滚动条不需要皮肤的话，代码会简单的话花一个皮肤初学，不完美的地方自己可以自己修改。这里说下套 皮肤方式。比如我们做一个styleTextScrollBar的皮肤，建一个styleTextScrollBar的影片剪辑然后捆绑上md.UI.styleTextScrollBar，这个类不用写，系统会帮你自动生成，我...
as3滚动条控制元件移动 带缓冲效果
斗战圣Q
11-04 2098
由于带滚动条的动态文本框无法竖着显示文字，于是通过把竖着显示得静态文本框转换成元件，遮罩层盖在内容层上，实现拉滚动条，元件左右移动，在遮罩层的帮助下，实现竖排文字左右移动的效果，然后通过代码加入移动的缓冲效果，注意最后一帧的代码是跳转到前一帧，通过循环才能实现移动缓冲的效果，而不是在同一帧内实现。。。 drag.addEventListener(MouseEvent.MOUSE_DOWN
Flex4教程：轻松掌握VScrollBar垂直滚动条应用
在Flex4中，开发人员经常会遇到需要在用户界面中添加滚动条的情况，特别是对于那些展示大量数据或者需要垂直浏览的列表。本教程主要针对初学者，深入浅出地讲解了如何在Flex4中应用垂直滚动条（VScrollBar）组件。 ...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值