ShadowGun Shader学习

读了《Unity Shader入门精要》后，下了ShadowGun 的demo来学习下。

说明

标记为转载的原因是因为不知道如何去找准确的顺序去看Shadow Gun，所以学习的顺序是按照Candy Cat的学习顺序看的。https://blog.csdn.net/candycat1992

冒烟效果

之前冒烟的效果都是用粒子做的，但是消耗很大，而Shadow Gun里的冒烟使用了扭曲的mesh加shader做的，性能会好很多。

源码

Shader "CrazyShader/Fire"
{
	Properties
	{
		_MainTex ("Base layer (RGB)", 2D) = "white" {}
		_DetailTex ("2nd layer (RGB)", 2D) = "white" {}
		_ScrollX ("Base layer Scroll speed X", Float) = -2
		_ScrollY ("Base layer Scroll speed Y", Float) = -0.5
		_Scroll2X ("2nd layer Scroll speed X", Float) = 0.0
		_Scroll2Y ("2nd layer Scroll speed Y", Float) = -0.3
		_SineAmplX ("Base layer sine amplitude X",Float) = 0.005 
		_SineAmplY ("Base layer sine amplitude Y",Float) = 0.005
		_SineFreqX ("Base layer sine freq X",Float) = 250 
		_SineFreqY ("Base layer sine freq Y",Float) = 250
		_SineAmplX2 ("2nd layer sine amplitude X",Float) = 0.005 
		_SineAmplY2 ("2nd layer sine amplitude Y",Float) = 0.0
		_SineFreqX2 ("2nd layer sine freq X",Float) = 200 
		_SineFreqY2 ("2nd layer sine freq Y",Float) = 10
		_Color("Color", Color) = (1,1,1,1)
		
		_MMultiplier ("Layer Multiplier", Float) = 2.0
	}
	SubShader
	{
		Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" }

		Blend SrcAlpha OneMinusSrcAlpha
		Cull Off
		Lighting Off
		ZWrite Off

		LOD 100

		CGINCLUDE

		#include "UnityCG.cginc"

		sampler2D _MainTex;
		sampler2D _DetailTex;
		float4 _MainTex_ST;
		float4 _DetailTex_ST;

		float4 _Color;

		float _ScrollX;
		float _ScrollY;
		float _Scroll2X;
		float _Scroll2Y;

		float _SineAmplX;
		float _SineAmplY;
		float _SineFreqX;
		float _SineFreqY;

		float _SineAmplX2;
		float _SineAmplY2;
		float _SineFreqX2;
		float _SineFreqY2;

		float _MMultiplier;

		struct v2f
		{
			float4 pos : SV_POSITION;
			float4 uv : TEXCOORD0;
			fixed4 color : TEXCOORD1; 
		};

		v2f vert(appdata_full v)
		{
			v2f o;

			o.pos = UnityObjectToClipPos(v.vertex);

			o.uv.xy = TRANSFORM_TEX(v.texcoord.xy, _MainTex) + frac(float2(_ScrollX, _ScrollY) * _Time);
			o.uv.zw = TRANSFORM_TEX(v.texcoord.xy, _DetailTex) + frac(float2(_Scroll2X, _Scroll2Y) * _Time);

			o.uv.x += sin(_Time * _SineFreqX) * _SineAmplX;
			o.uv.y += sin(_Time * _SineFreqY) * _SineAmplY;

			o.uv.z += sin(_Time * _SineFreqX2) * _SineAmplX2;
			o.uv.w += sin(_Time * _SineFreqY2) * _SineAmplY2;

			o.color = _MMultiplier * _Color * v.color;
			return o;
		}

		ENDCG

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			fixed4 frag(v2f i) : COLOR
			{
				fixed4 o;
				fixed4 tex = tex2D(_MainTex, i.uv.xy);
				fixed4 tex2 = tex2D(_DetailTex, i.uv.zw);

				o = tex * tex2 * i.color;

				return o;
			}

			ENDCG
		}
	}
}

备注

1.如果不使用两张图片叠加的话，就会显得太亮，没有浓烟的感觉

2.SG里面的参数，不知道是怎么调出来的，按照原始Shader里的参数，图像会因为正弦函数导致画面呈现往复效果

3.关于Tag，一般含有Alpha的Shader的Tag大多都是这样的

Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" }

问题:

这里有些问题，烦请路过的大神们给个解答

1.原代码中用了CGINCLUDE，但是不知道这个宏的意思是什么，能说明下吗？

2.效果中的火焰除去贴图是有颜色的，应该是v.color自带的，那v.color是怎么设置的呢？