# 简支梁的模态分析（附命令流）

maidoudexiaoxiao

已于 2023-05-20 22:29:52 修改

阅读量649

点赞数

文章标签：笔记

于 2023-05-20 22:29:23 首次发布

本文链接：https://blog.csdn.net/maidoudexiaoxiao/article/details/130786729

版权

文章介绍了对一简支梁进行模态分析的过程，包括使用BEAM3和BEAM189单元建立有限元模型，设定材料属性，应用约束条件，进行模态分析以求得自振频率。同时，文章提到了在使用BEAM189单元时需考虑的截面定义和模态拓展，并展示了如何通过命令流进行操作，包括绘制振型图和制作动画。

摘要由CSDN通过智能技术生成

简支梁的模态分析（附命令流）

设截面尺寸 $ b \times h =0.2 m \times 0.3m$，跨度 $L = 20 m$ ，质量密度 $\rho=8000 kg/m^3$ ，弹性模量 $E = 210 Gp a$ ，则其第 $i$ 阶自振频率为：
$f_i=\frac{\pi i^2}{2L^2}\sqrt{\frac{EI}{m}}=i^2 \frac{\pi h}{4L^2}\sqrt{\frac{E}{3 \rho}}\ \ \ \ (i=1,2,3,\dots) \tag1$
当采用最大元素归一法时，各阶振型（不考虑轴向振型）为：
$y_i(x)=\sin(\frac{i\pi x}{L})\ \ \ \ (i=1,2,3,\dots) \tag{2}$
本例是一个平面结构，用 BEAM3 单元进行模拟比较简单。也可采用 BEAM89 单元模拟，**但是为与式（1）的理论振型完全一致，需要添加一些约束，例如绕梁自身轴的转动、面外位移和转动、纵向位移自由度等，否则会出现其他形式的整形。**若采用 BEAM189 单元就需要定义梁截面，**在模态拓展时需要计算单元的计算结果，否则带单元形状绘制振型图时会出现异样的结果。**归一化选择振型最大元素法，可以看到大多如图所示的最大平动位移均为 1.0，但也有最大转动位移（ROTZ）为 1.0 振型，如第 8 阶振型。

命令流：

!=====================================
! 简支梁模态分析
FINISH$/CLEAR$/PREP7$B=0.2$H=0.3$L=20 					 !定义参数
ET,1,BEAM189$MP,EX,1,2.1E11$MP,PRXY,1,0.3$MP,DENS,1,8000 !定义单元和材料性质
SECTYPE,1,BEAM,RECT$SECDATA,B,H							 !定义梁截面:宽B高H的矩形梁单元
$K,1,0,0$K,2,L,0
K,3,L/2,L												 !定向关键点
L,1,2
LATT,1,,1,,,3,1 !LATT, MAT, REAL, TYPE, --, KB, KE, SECNUM
LESIZE,ALL,,,50
LMESH,ALL												 !创建几何和有限元模型
D,1,UX,,,,,UY	
D,2,UY
D,ALL,UZ,,,,,ROTX,ROTY,UX								 !增加的约束	!施加约束
/SOLU
ANTYPE,2 												 !模态分析
MODOPT,LANB,20,,,,ON 									 !模态提取方法,提取的模态数，
MXPAND,20,,,YES
SOLVE													 !模态分解
/POST1
SET,LIST
SET,1,1
PLDISP,1
PLNSOL,UY 												 !结果列表，绘制第1振型
SET,1,20
PLNSOL,UY
PLNSOL,ROTZ
ANMODE,10,0.2	!帧数（默认为5），延迟时间（默认为0.1s）    !绘制第8阶振型并制作动画
ETABLE,MI,SMISC,3
ETABLE,MJ,SMISC,16
PLLS,MI,MJ												 !绘制弯曲分布
/ESHAPE,1
PLNSOL,UY
PLNSOL,ROTZ 										     !带单元形状绘制振型