shader学习摘要（四）——单张纹理

---

纹理有什么用

我们通常会使用一张纹理来代替物体的漫反射颜色。在本节中，我们将学习如何在unity shader中使用单张纹理来作为模拟的颜色

实现方法

单张纹理的使用方是在前面的光照模型的基础（这里使用的是Blinn-Phong光照模型）上，将模型原本的颜色乘以纹理的颜色的方法进行的纹理映射

---

单张纹理

代码

代码如下（示例）：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unity Shaders Book/Chapter 7/Single Texture" {
	Properties {
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex ("Main Tex", 2D) = "white" {}
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}
	SubShader {		
		Pass { 
			Tags { "LightMode"="ForwardBase" }
		
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag

			#include "Lighting.cginc"
			
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;//“纹理名_ST”是在unity中对纹理进行命名的格式ST.xy指的是缩放值，ST.zw存储的是偏移值
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;//模型的第一组纹理坐标会存储在texcoord中
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
			};
			//以下v2f结构体定义的函数为裁剪空间的函数vert及其结构体内包含的4个变量进行坐标变换与赋值
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
				// 也可以使用以下内置函数
//				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				
				return o;
			}
			//片元着色器，使用的光照模型是Blinn-Phong光照模型
			fixed4 frag(v2f i) : SV_Target {
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				
				// tex2D函数对纹理进行采样参数为（对象，对象坐标）取得RGB值，将其与color的乘积作为采样值albedo
				fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
				
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				
				return fixed4(ambient + diffuse + specular, 1.0);
			}
			
			ENDCG
		}
	} 
	FallBack "Specular"
}

使用效果

属性设置

如图所示，这里使用的texture type是默认（Default），这是因为经过版本的更新，将texture纹理命名为了Default，实际上，unity默认使用的纹理都是单张纹理
Wrap Mode属性中repeat模式是指当纹理坐标超过了1，那么将舍弃整数，使用小数部分进行采样，这样纹理会不断重复，当使用模式clamp模式时，超过范围的部分会截取到边界值，形成一个条形结构
Wrap Mode决定了超过[0,1]范围时如何进行平铺
Filter Mode
指的是滤波形式，不同的滤波形式会有不同的影像质量

---

总结

以上就是单张纹理的内容，单张纹理广泛应用于图像渲染，TA使用从美术制作的纹理图片，通过代码与数学公式进行纹理的大小比例的调整，实现预期效果。谢谢观看。