UnityShader案例（四）——单张纹理

一、单张纹理映射实现的shader

Shader "Custom/Texture/SingleTexture"
{
    Properties
    {
        _Color("Color",Color)=(1,1,1,1)
        _MainTex ("Texture", 2D) = "white" {}
        _Specular("Specular",Color)=(1,1,1,1)
        _Gloss("Gloss",Range(8.0,256))=20
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float4 normal:NORMAL;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD2;
                float4 vertex : SV_POSITION;
                float3 worldNormal:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
            };

            fixed4 _Color;
            fixed4 _Specular;
            float _Gloss;
            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                //o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.uv=v.uv.xy*_MainTex_ST.xy+_MainTex_ST.zw;
                o.worldNormal=UnityObjectToWorldNormal(v.normal);
                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed3 worldNormal=normalize(i.worldNormal);
                fixed3 worldLightDir=normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed3 albedo=tex2D(_MainTex, i.uv).rgb * _Color.rgb;

                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;

                fixed3 diffuse = _LightColor0.rgb * albedo *max(0,dot(worldNormal,worldLightDir));

                fixed3 viewDir =normalize(UnityWorldSpaceViewDir(i.worldPos));

                fixed3 halfDir=normalize(worldNormal+viewDir);

                fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(worldNormal,halfDir)),_Gloss);

                return  fixed4(ambient+diffuse+specular,1.0);
            }
            ENDCG
        }
    }
}

二、实现细节详解

1、纹理类型的属性声明了float4 类型的变量_MainTex_ST,其中_MainTex_ST的名字不是随便起的。在Unity中，我们需要使用纹理名_ST的方式来声明摸个纹理的属性。ST是缩放（Scale）和平移（Transform）的缩写。_MainTex_ST.zw存储的是偏移值，_MianTex_ST.xy存储的是缩放值，而面板的纹理属性中可以调节。

2、在顶点着色器中，我们使用的属性值_MainTex_ST来对顶点纹理坐标进行变换，得到最终的纹理坐标。
计算过程是：首先使用缩放属性_MainTex_ST.xy对顶点纹理坐标进行缩放，然后在使用偏移属性_MainTex_ST.zw对结果进行偏移。Unity中提供一个内置宏TRANSFORM_TEX来帮我们计算上述过程。
3、在片段主色器中，首先计算了世界空间下的法线方向和光照方向，然后使用tex2D函数对纹理进行采样。它的第一个参数是需要被采样的纹理，第二个参数是一个float2类型的纹理坐标，它将返回计算得到纹素值。我们使用采样结果和属性颜色_Color的乘积来作为材质的反射率albedo，并将它和环境光照相乘得到环境光部分。随后，我们使用albedo来计算漫反射光照的结果，并与环境光照、高光反射光照相加后返回最终结构板。