FORM里按钮调用请求并输出

DECLARE
  lb_add_layout  BOOLEAN;
  ln_request_id  NUMBER;
  lb_commit      BOOLEAN;
  lb_call_status BOOLEAN;
  lv_phase       VARCHAR2(200);
  lv_status      VARCHAR2(200);
  lv_dev_phase   VARCHAR2(200);
  lv_dev_status  VARCHAR2(200);
  lv_message     VARCHAR2(200);
  lv_retcode     VARCHAR2(200);

BEGIN
  --设置布局
  lb_add_layout := fnd_request.add_layout(template_appl_name => 'CUX',
                                          template_code      => 'CUX_GL_PAYMENT_PKG',
                                          template_language  => 'ZH',
                                          template_territory => 'CN',
                                          output_format      => 'PDF');
  --提交后台请求
  ln_request_id := fnd_request.submit_request('CUX',
                                              'CUX_GL_PAYMENT_PKG',
                                              NULL,
                                              NULL,
                                              FALSE,
                                              l_company_seg,
                                              l_company_seg,
                                              l_period_name,
                                              l_period_name,
                                              NULL,
                                              NULL,
                                              NULL,
                                              NULL,
                                              l_gl_doc_name,
                                              l_gl_doc_name,
                                              CHR(0));

  lb_commit := app_form.quietcommit;

  --等待请求结束
  lb_call_status := fnd_concurrent.wait_for_request(ln_request_id,
                                                    1,
                                                    0,
                                                    lv_phase,
                                                    lv_status,
                                                    lv_dev_phase,
                                                    lv_dev_status,
                                                    lv_message);

  IF (lv_dev_phase = 'COMPLETE') AND (lv_dev_status = 'NORMAL') THEN
    --正常完成
    --fnd_message.set_name('FND', 'CONC-SUBMITTED REQUEST');
    --fnd_message.set_token('REQUEST_ID', ln_request_id);
    --fnd_message.show;
    editor_pkg.report(ln_request_id, 'Y'); --报表结果输出，引用请求界面的“查看输出”按钮效应
  ELSE
    --非正常完成
    fnd_message.debug('出现异常结果，请查看请求号：' || ln_request_id);
    --调用系统标准功能，显示请求界面 
    fnd_function.execute(function_name => 'FND_FNDRSRUN',
                         open_flag     => 'Y',
                         session_flag  => 'Y',
                         other_params  => 'PROGRAM_APPL_SHORT_NAME="CUX" DODT_REQ_ID="' ||
                                          TO_CHAR(ln_request_id) || '"');
  END IF;

END;

FORM 中要加载FNDCONC.PLL文件