shader入门15 完整的光照处理

我们已经学习了所有相关的光照处理,尝试用前几篇的光照处理组合出一个标准的光照着色器.

代码

漫反射使用了兰伯特光照模型
高光反射使用Blinn-Phong模型
法线纹理是在切线空间计算的
添加了多光照处理,光照衰减,阴影

Shader "Unity/Custom/NewSurfaceShader" {
	Properties{
		_TexColor("TexColor", Color) = (1, 1, 1, 1)//贴图颜色
		_MainTex("MainTex", 2D) = "white" {}//贴图
		_BumpTex("NormalMap", 2D) = "white" {}//法线纹理
		_BumpScale("BumpScale",Range(0,200)) = 10//凹凸系数
		_Sepcular("_Sepcular",Color) = (1,1,1,1)//高光反射颜色
		_Gloss("_Gloss",Range(0,100)) = 1//光泽度
	}
	SubShader{
		Tags{ "Queue" = "Geometry" }//不透明物体渲染队列
		Pass{
			Tags{ "LightMode" = "ForwardBase" }
			CGPROGRAM
			#pragma multi_compile_fwdbase
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			fixed4 _TexColor;
			sampler2D _MainTex;
			float4 _MainTex_ST;//缩放与偏移
			sampler2D _BumpTex;
			float4 _BumpTex_ST;
			float _BumpScale;
			fixed4 _Sepcular;//高光反射颜色
			fixed _Gloss;//光泽度
			struct a2v {
				float4 vertex : POSITION;//模型空间位置
				float3 normal : NORMAL;//模型空间法线
				float4 tangent : TANGENT;//模型空间切线
				float4 texcoord : TEXCOORD0;//声明一个纹理用来储存MainTex
			};
			struct v2f {
				float4 pos : SV_POSITION;//剪裁空间位置
				float4 uv : TEXCOORD0;//我们用一个变量储存MainTex与BumpMap的uv,节省寄存器空间
				float3 lightDir: TEXCOORD1;//环境光方向 切线空间
				float3 viewDir : TEXCOORD2;//观察方向 切线空间
				float3 worldPos : TEXCOORD3;//世界坐标系位置
				SHADOW_COORDS(4)//声明一个变量储存阴影纹理
			};
			v2f vert(a2v v) {
				v2f f;
				f.pos = UnityObjectToClipPos(v.vertex);//剪裁空间的位置
				f.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;//获取两套uv 缩放+平移
				//f.uv.xy =   TRANSFORM_TEX(v.texcoord,_MainTex);  与上面等价,用于计算缩放+平移的uv Unity自带的宏
				f.uv.zw = v.texcoord.xy * _BumpTex_ST.xy + _BumpTex_ST.zw;//获取两套uv 缩放+平移
				TANGENT_SPACE_ROTATION;//利用unity自带的宏 来计算模型空间变换到切线空间的矩阵rotation
				f.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;//切线光方向
				f.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;//切线观察方向
				f.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;//模型空间到世界坐标系位置
				TRANSFER_SHADOW(f);//计算阴影纹理坐标
				return f;
			}
			fixed4 frag(v2f f) : SV_Target{
				fixed3 tangentLightDir = normalize(f.lightDir);//切线空间下的光方向
				fixed3 tangentViewDir = normalize(f.viewDir);//切线空间下的观察方向
				fixed3 tangentNormal = UnpackNormal(tex2D(_BumpTex,f.uv.zw));//默认法线贴图就是切线空间下的 映射回法线
				tangentNormal.xy *= _BumpScale;
				tangentNormal.z = sqrt(1 - saturate(dot(tangentNormal.xy,tangentNormal.xy)));//计算z轴分量
				fixed3 texColor = tex2D(_MainTex, f.uv.xy).rgb*_TexColor.rgb;//贴图颜色
				fixed3 halfDir = normalize(tangentViewDir + tangentLightDir);//h方向
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;//环境光
				fixed3 specular = _LightColor0.rgb * _Sepcular.rgb * pow(max(dot(halfDir, tangentNormal), 0), _Gloss);//h方向与法线的夹角决定高光补偿
				fixed3 diffuse = _LightColor0.rgb * texColor * max(0, dot(tangentLightDir, tangentNormal));//漫反射 兰伯特模型
				UNITY_LIGHT_ATTENUATION(atten, f, f.worldPos);//计算阴影和光照衰减
				return fixed4(ambient + (diffuse + specular) * atten, 1);//最终效果
			}
			ENDCG
		}
		Pass{
			Tags{ "LightMode" = "ForwardAdd" }
			Blend One One//希望多光源混合 而不是覆盖
			CGPROGRAM
			#pragma multi_compile_fwdadd
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			fixed4 _TexColor;
			sampler2D _MainTex;
			float4 _MainTex_ST;//缩放与偏移
			sampler2D _BumpTex;
			float4 _BumpTex_ST;
			float _BumpScale;
			fixed4 _Sepcular;//高光反射颜色
			fixed _Gloss;//光泽度
			struct a2v {
				float4 vertex : POSITION;//模型空间位置
				float3 normal : NORMAL;//模型空间法线
				float4 tangent : TANGENT;//模型空间切线
				float4 texcoord : TEXCOORD0;//声明一个纹理用来储存MainTex
			};
			struct v2f {
				float4 pos : SV_POSITION;//剪裁空间位置
				float4 uv : TEXCOORD0;//我们用一个变量储存MainTex与BumpMap的uv,节省寄存器空间
				float3 lightDir: TEXCOORD1;//环境光方向 切线空间
				float3 viewDir : TEXCOORD2;//观察方向 切线空间
				float3 worldPos : TEXCOORD3;//世界坐标系位置
				SHADOW_COORDS(4)//声明一个变量储存阴影纹理
			};
			v2f vert(a2v v) {
				v2f f;
				f.pos = UnityObjectToClipPos(v.vertex);//剪裁空间的位置
				f.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;//获取两套uv 缩放+平移
				f.uv.zw = v.texcoord.xy * _BumpTex_ST.xy + _BumpTex_ST.zw;//获取两套uv 缩放+平移
				TANGENT_SPACE_ROTATION;//利用unity自带的宏 来计算模型空间变换到切线空间的矩阵rotation
				f.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;//切线光方向
				f.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;//切线观察方向
				f.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;//模型空间到世界坐标系位置
				TRANSFER_SHADOW(f);//计算阴影纹理坐标
				return f;
			}
			fixed4 frag(v2f f) : SV_Target{
				fixed3 tangentLightDir = normalize(f.lightDir);//切线空间下的光方向
				fixed3 tangentViewDir = normalize(f.viewDir);//切线空间下的观察方向
				fixed3 tangentNormal = UnpackNormal(tex2D(_BumpTex,f.uv.zw));//默认法线贴图就是切线空间下的 映射回法线
				tangentNormal.xy *= _BumpScale;
				tangentNormal.z = sqrt(1 - saturate(dot(tangentNormal.xy,tangentNormal.xy)));//计算z轴分量
				fixed3 texColor = tex2D(_MainTex, f.uv.xy).rgb*_TexColor.rgb;//贴图颜色
				fixed3 halfDir = normalize(tangentViewDir + tangentLightDir);//h方向
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;//环境光
				fixed3 specular = _LightColor0.rgb * _Sepcular.rgb * pow(max(dot(halfDir, tangentNormal), 0), _Gloss);//h方向与法线的夹角决定高光补偿
				fixed3 diffuse = _LightColor0.rgb * texColor * max(0, dot(tangentLightDir, tangentNormal));//漫反射 兰伯特模型
				UNITY_LIGHT_ATTENUATION(atten, f, f.worldPos);//计算阴影和光照衰减
				return fixed4(ambient + (diffuse + specular) * atten, 1);//最终效果
			}
			ENDCG
		}
	}
	FallBack "Diffuse"
}

效果

为了测试其他的光照效果,关闭了平行光,仅使用点光源