Cg Programming In Unity Cutaways (Wiki翻译自用)

本教程介绍了如何丢弃片元以及正面剔除和反面剔除。
本教程的主题时切除三角形或片元，即使他们是正在渲染的网格。主要是有两个原因：我们想看一个三角形或者一个片元，也就是我们知道的不可见的三角形。因此，我们可以通过不处理它来节省性能。GPU有很多方式支持这种情况。我们将讨论其中的两个。

非常简单的切除方法

下面的shader是切除网格一部分的一种非常简单的方法：切掉所有片元在模型坐标下的正y坐标。

Shader "Cg shader using discard" {
   SubShader {
      Pass {
         Cull Off // 关闭三角剔除，其他方法：
         // Cull Back (默认): 仅剔除背面 
         // Cull Front : 只剔除正面 
         
         CGPROGRAM 
 
         #pragma vertex vert  
         #pragma fragment frag 
 
         struct vertexInput {
            float4 vertex : POSITION;
         };
         struct vertexOutput {
            float4 pos : SV_POSITION;
            float4 posInObjectCoords : TEXCOORD0;
         };
 
         vertexOutput vert(vertexInput input) 
         {
            vertexOutput output;
 
            output.pos = UnityObjectToClipPos(input.vertex);
            output.posInObjectCoords = input.vertex; 
 
            return output;
         }
 
         float4 frag(vertexOutput input) : COLOR 
         {
            if (input.posInObjectCoords.y > 0.0) 
            {
               discard; // drop the fragment if y coordinate > 0
            }
            return float4(0.0, 1.0, 0.0, 1.0); // green
         }
 
         ENDCG  
      }
   }
}

当您将此着色器应用于任何默认对象时，该着色器将切掉其中一半。 这是产生半球或敞开圆柱体的非常简单的方法。

丢弃片元

让我们首先关注片段着色器中的废弃指令。该指令基本上只是丢弃已处理的片段。 （这在较早的着色语言中被称为片段“ kill”）。根据硬件的不同，这可能是一种非常昂贵的技术，因为一旦存在一个shader包含了丢弃指令，渲染可能会表现的相当差。（无论实际上丢弃了多少片元，只是该指令的存在可能 导致一些重要的优化被停用）。因此，应尽可能避免使用此说明，尤其是在遇到性能问题时。
还有一点需要注意：片元丢弃的条件仅包含一个对象的坐标。这导致的结果是您可以以任何方式旋转和移动对象，并且切除部分将始终随对象一起旋转和移动。 您可能想要检查世界空间中的切割效果，以使世界坐标y用于片段丢弃的条件

更好的切面

如果你不熟悉Unity中的脚本，你可以尝试以下方式来改进着色器：如果片元的y坐标大于某个阈值变量就丢弃它。然后引入一个着色器属性，以允许用户控制此阈值。
如果你熟悉Unity的脚本编写，可以尝试这种方式：为一个对象编写脚本，该脚本引用另一个sphere对象并将该球体对象的模型矩阵的逆矩阵（GetComponent(Renderer).worldToLocalMatrix）分配给着色器的float4x4统一参数（GetComponent（Renderer）.sharedMaterial.SetMatrix（））。在这个着色器中，计算片元在世界坐标中的位置，并讲另一个球体对象的模型矩阵的逆应用在片元上。现在，您拥有一个在另一个球体对象坐标系的片元的位置。在这里，很容易检测片元是否在球体内部，因为在这个坐标系下，Unity默认的球是以原点为中心0.5为半径。如果片元在球体内部，则将其丢弃。

正面或背面剔除

最后，示例中的shader（确切的说是这个shader的Pass）包含Cull Off这一行。该行必须写在CGPROGRAM之前，因为它不在Cg中。事实上，它是”Unity’s ShaderLab“关闭任何三角形剔除的一个命令。这是必要的，因为默认情况下会剔除背面，就像指定了Cull Back命令一样。您也可以使用Cull Front指定正面剔除。默认使用背面剔除的原因是对象的内部通常是不可见的。因此，背面剔除可以避免栅格化这些三角形从而节省了一些性能。当然，我们可以使用shader来看到对象的内部因为我们已经丢弃了一些片元，因此我们应该禁用背面剔除。剔除是怎么工作的呢？三角形和顶点照常处理。但是在将顶点从视图空间（View）变换为屏幕坐标系下，图像处理器将判断三角形的顶点是按逆时针方向还是按顺时针顺序出现在屏幕上，根据这个处理，每个三角形都被视为一个正向三角形或者背向三角形。如果它是正向的并且剔除是正向剔除，那么它将被丢弃，即停止对该三角形的处理并不对它进行栅格化。类似的，如果三角形是背向的并且剔除是背向剔除的也将被丢弃。否则将照常处理三角形。
我们可以用剔除来做些什么呢？一种应用是使用不同的shader处理正面和背面，即对象的内部和外部。下面的shader‘使用了两个Pass。在一个Pass中，仅剔除正面，剩下的面渲染为红色（如果片元未被丢弃）。第二个Pass剔除背面，将剩下的面渲染为绿色。

Shader "Cg shader with two passes using discard" {
   SubShader {

      // first pass (is executed before the second pass)
      Pass {
         Cull Front // cull only front faces
 
         CGPROGRAM 
 
         #pragma vertex vert  
         #pragma fragment frag 
 
         struct vertexInput {
            float4 vertex : POSITION;
         };
         struct vertexOutput {
            float4 pos : SV_POSITION;
            float4 posInObjectCoords : TEXCOORD0;
         };
 
         vertexOutput vert(vertexInput input) 
         {
            vertexOutput output;
 
            output.pos = UnityObjectToClipPos(input.vertex);
            output.posInObjectCoords = input.vertex; 
 
            return output;
         }
 
         float4 frag(vertexOutput input) : COLOR 
         {
            if (input.posInObjectCoords.y > 0.0) 
            {
               discard; // drop the fragment if y coordinate > 0
            }
            return float4(1.0, 0.0, 0.0, 1.0); // red
         }
 
         ENDCG  
      }

      // second pass (is executed after the first pass)
      Pass {
         Cull Back // cull only back faces

         CGPROGRAM 
 
         #pragma vertex vert  
         #pragma fragment frag 
 
         struct vertexInput {
            float4 vertex : POSITION;
         };
         struct vertexOutput {
            float4 pos : SV_POSITION;
            float4 posInObjectCoords : TEXCOORD0;
         };
 
         vertexOutput vert(vertexInput input) 
         {
            vertexOutput output;
 
            output.pos = UnityObjectToClipPos(input.vertex);
            output.posInObjectCoords = input.vertex; 
 
            return output;
         }
 
         float4 frag(vertexOutput input) : COLOR 
         {
            if (input.posInObjectCoords.y > 0.0) 
            {
               discard; // drop the fragment if y coordinate > 0
            }
            return float4(0.0, 1.0, 0.0, 1.0); // green
         }
 
         ENDCG  
      }
   }
}

请记住，Unity的shader只执行一个subshader，但是该subshader的所有pass都被执行。
在许多GPU上，有一种更高效的方法来区分Cg中的正面和反面，那就是使用带有语义VFACE的参数作为片元的输入。你可以查阅Unity的shader语义文档。但是并不是所有GPU都支持这。

总结

本教程你学会：

• 如何丢弃片元
• 如何指定正面剔除和背面剔除
• 如何使用两次pass来剔除以使得对网格的内部和外部使用不同的shader