Cg Programming In Unity Order-Independent Transparency(Wiki翻译自用)

本教程介绍了与顺序无关的混合

顺序无关的混合

如“Rransparency”部分所述，Blend的混合结果通常取决于渲染三角形的顺序（特别是对于标准的alpha blend）。因此如果未对三角形进行从前到后的排序，则会导致渲染失真。术语“order-independent transparency（顺序无关的透明度）”描述了避免此问题的各种技巧。技巧之一就是顺序无关的混合，即使用不依赖于三角形栅格化顺序的混合方程。这里有两种基本方程：加法混合（additive blending） 和乘法混合（multiplicative blending）

加法混合

加法混合的标准示例是两次曝光，添加颜色使得无法（或至少很难）说出照片的拍摄顺序。可以根据“透明度”部分中介绍的混合方程式来表示加法混合：

float4 result = SrcFactor * fragment_output + DstFactor * pixel_color;

其中fragment_output是片元着色器的输出，pixel_color是帧缓冲区中以及存在的颜色。SrcFactor和DstFactor由Unity的ShaderLab语法定义：

Blend {code for SrcFactor} {code for DstFactor}

对于加法混合，DstFactor必须为1，SrcFactor的代码必须不依赖于帧缓冲区中的像素颜色，即，它可以是One，SrcColor，SrcAlpha，OneMinusSrcColor或OneMinusSrcAlpha
示例：

Shader "Cg shader using additive blending" {
   SubShader {
      Tags { "Queue" = "Transparent" } 
         // draw after all opaque geometry has been drawn
      Pass { 
         Cull Off // draw front and back faces
         ZWrite Off // don't write to depth buffer 
            // in order not to occlude other objects
         Blend SrcAlpha One // additive blending

         CGPROGRAM 
 
         #pragma vertex vert 
         #pragma fragment frag
 
         float4 vert(float4 vertexPos : POSITION) : SV_POSITION 
         {
            return UnityObjectToClipPos(vertexPos);
         }
 
         float4 frag(void) : COLOR 
         {
            return float4(1.0, 0.0, 0.0, 0.2); 
         }
 
         ENDCG  
      }
   }
}

乘法混合

摄像中的乘法混合的一个示例是使用多个均匀的灰色滤镜：滤镜放置在相机上的顺序所产生的图像衰减不重要。就三角形栅格化而言，图像对应于三角形栅格化之前的帧缓冲区的内容，而滤镜对应于三角形。
使用下面一行在Unity中指定乘法混合

Blend {code for SrcFactor} {code for DstFactor}

SrcFactor代码必须为0，DstFactor代码必须取决于片元颜色，即它可以是SrcColor，SrcAlpha，OneMinusSrcColor或OneMinusSrcAlpha。用片元的alpha分量指定的不透明度来衰减背景的典型示例是使用OneMinusSrcAlpha作为DstFactor的代码：

Shader "Cg shader using multiplicative blending" {
   SubShader {
      Tags { "Queue" = "Transparent" } 
         // draw after all opaque geometry has been drawn
      Pass { 
         Cull Off // draw front and back faces
         ZWrite Off // don't write to depth buffer 
            // in order not to occlude other objects
         Blend Zero OneMinusSrcAlpha // multiplicative blending 
            // for attenuation by the fragment's alpha

         CGPROGRAM 
 
         #pragma vertex vert 
         #pragma fragment frag
 
         float4 vert(float4 vertexPos : POSITION) : SV_POSITION 
         {
            return UnityObjectToClipPos(vertexPos);
         }
 
         float4 frag(void) : COLOR 
         {
            return float4(1.0, 0.0, 0.0, 0.2); 
         }
 
         ENDCG  
      }
   }
}

完整的shader代码

最后，在一个shader中通过组合上面介绍的两个pass，将乘法混合作用于背景衰减，将加法混合作用于三角形颜色的增加是很有意义的。如果不考虑三角形网格本身的颜色衰减，则可以将其视为 alpha blending 的较小的不透明度的近似值，也就是较小的alpha值：

Shader "Cg shader using order-independent blending" {
   SubShader {
      Tags { "Queue" = "Transparent" } 
         // draw after all opaque geometry has been drawn
      Pass { 
         Cull Off // draw front and back faces
         ZWrite Off // don't write to depth buffer 
            // in order not to occlude other objects
         Blend Zero OneMinusSrcAlpha // multiplicative blending 
            // for attenuation by the fragment's alpha

         CGPROGRAM 
 
         #pragma vertex vert 
         #pragma fragment frag
 
         float4 vert(float4 vertexPos : POSITION) : SV_POSITION 
         {
            return UnityObjectToClipPos(vertexPos);
         }
 
         float4 frag(void) : COLOR 
         {
            return float4(1.0, 0.0, 0.0, 0.2); 
         }
 
         ENDCG  
      }

      Pass { 
         Cull Off // draw front and back faces
         ZWrite Off // don't write to depth buffer 
            // in order not to occlude other objects
         Blend SrcAlpha One // additive blending to add colors

         CGPROGRAM 
 
         #pragma vertex vert 
         #pragma fragment frag
 
         float4 vert(float4 vertexPos : POSITION) : SV_POSITION 
         {
            return UnityObjectToClipPos(vertexPos);
         }
 
         float4 frag(void) : COLOR 
         {
            return float4(1.0, 0.0, 0.0, 0.2); 
         }
 
         ENDCG  
      }
   }
}

注意，两次Pass的顺序很重要：先衰减背景，再添加颜色。

总结

我们已经学会了：

• 什么是与顺序无关的透明度和与顺序无关的混合
• 顺序无关的混合的两种最重要的类型是什么（加法混合和乘法混合）。
• 如何实现加法和乘法混合。
• 如何合并两次通过以进行加法和乘法混合，以实现与顺序无关的近似alpha blending。