日本人写的BMPDecoder

最新推荐文章于 2020-12-05 08:23:22 发布
最新推荐文章于 2020-12-05 08:23:22 发布
阅读量234 收藏
点赞数
分类专栏： Flash/AS3 文章标签： Flash ActionScript Apache Blog
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/u010054015/article/details/83800906
版权 
/**
 * com.voidelement.images.BMPDecoder  Class for ActionScript 3.0 
 *  
 * @author       Copyright (c) 2007 munegon
 * @version      1.0
 *  
 * @link         http://www.voidelement.com/
 * @link         http://void.heteml.jp/blog/
 * 
 * Licensed under the Apache License, Version 2.0 (the "License"); 
 * you may not use this file except in compliance with the License. 
 * You may obtain a copy of the License at 
 *  
 * http://www.apache.org/licenses/LICENSE-2.0 
 *  
 * Unless required by applicable law or agreed to in writing, software 
 * distributed under the License is distributed on an "AS IS" BASIS, 
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND,  
 * either express or implied. See the License for the specific language 
 * governing permissions and limitations under the License. 
 */



package com.voidelement.images {
	import flash.display.BitmapData;
	import flash.errors.IOError;
	import flash.utils.ByteArray;
	import flash.utils.Endian;
	
	public class BMPDecoder {
		//___________________________________________________________ const
		
		private const BITMAP_HEADER_TYPE:String = "BM";
		
		private const BITMAP_FILE_HEADER_SIZE:int = 14;
		private const BITMAP_CORE_HEADER_SIZE:int = 12;
		private const BITMAP_INFO_HEADER_SIZE:int = 40;
		
		private const COMP_RGB      :int = 0;
		private const COMP_RLE8     :int = 1;
		private const COMP_RLE4     :int = 2;
		private const COMP_BITFIELDS:int = 3;
		
		private const BIT1 :int = 1;
		private const BIT4 :int = 4;
		private const BIT8 :int = 8;
		private const BIT16:int = 16;
		private const BIT24:int = 24;
		private const BIT32:int = 32;
		
		
		//___________________________________________________________ vars
		
		private var bytes:ByteArray;
		private var palette:Array;
		private var bd:BitmapData;
	
		private var nFileSize:uint;
		private var nReserved1:uint;
		private var nReserved2:uint;
		private var nOffbits:uint;
		
		private var nInfoSize:uint;
		private var nWidth:int;
		private var nHeight:int;
		private var nPlains:uint;
		private var nBitsPerPixel:uint;
		private var nCompression:uint;
		private var nSizeImage:uint;
		private var nXPixPerMeter:int;
		private var nYPixPerMeter:int;
		private var nColorUsed:uint;
		private var nColorImportant:uint;
		
		private var nRMask:uint;
		private var nGMask:uint;
		private var nBMask:uint;
		private var nRPos:uint;
		private var nGPos:uint;
		private var nBPos:uint;
		private var nRMax:uint;
		private var nGMax:uint;
		private var nBMax:uint;
		
		
		/**
		 * コンストラクタ
		 */
		public function BMPDecoder() {
			nRPos = 0;
			nGPos = 0;
			nBPos = 0;
		}
		
		
		/**
		 * デコード
		 * 
		 * @param デコードしたいBMPファイルのバイナリデータ
		 */
		public function decode( data:ByteArray ):BitmapData {
			bytes = data;
			bytes.endian = Endian.LITTLE_ENDIAN;
			bytes.position = 0;
			
			readFileHeader();
			
			nInfoSize = bytes.readUnsignedInt();
			
			switch ( nInfoSize ) {
				case BITMAP_CORE_HEADER_SIZE:
					readCoreHeader();
					break;
				case BITMAP_INFO_HEADER_SIZE:
					readInfoHeader();
					break;
				default:
					readExtendedInfoHeader();
					break;
			}
			
			bd = new BitmapData( nWidth, nHeight );
			
			switch ( nBitsPerPixel ){
				case BIT1:
					readColorPalette();
					decode1BitBMP();
					break;
				case BIT4:
					readColorPalette();
					if ( nCompression == COMP_RLE4 ){
						decode4bitRLE();
					} else {
						decode4BitBMP();
					}
					break;
				case BIT8:
					readColorPalette();
					if ( nCompression == COMP_RLE8 ){
						decode8BitRLE();
					} else {
						decode8BitBMP();
					}
					break;
				case BIT16:
					readBitFields();
					checkColorMask();
					decode16BitBMP();
					break;
				case BIT24:
					decode24BitBMP();
					break;
				case BIT32:
					readBitFields();
					checkColorMask();
					decode32BitBMP();
					break;
				default:
					throw new VerifyError("invalid bits per pixel : " + nBitsPerPixel );
			}
			
			return bd;
		}
		
		
		/**
		 * BITMAP FILE HEADER 読み込み
		 */
		private function readFileHeader():void {
			var fileHeader:ByteArray = new ByteArray();
			fileHeader.endian = Endian.LITTLE_ENDIAN;
			
			try {
				bytes.readBytes( fileHeader, 0, BITMAP_FILE_HEADER_SIZE );
				
				if ( fileHeader.readUTFBytes( 2 ) != BITMAP_HEADER_TYPE ){
					throw new VerifyError("invalid bitmap header type");
				}
				
				nFileSize  = fileHeader.readUnsignedInt();
				nReserved1 = fileHeader.readUnsignedShort();
				nReserved2 = fileHeader.readUnsignedShort();
				nOffbits   = fileHeader.readUnsignedInt();
			} catch ( e:IOError ) {
				throw new VerifyError("invalid file header");
			}
		}
		
		
		/**
		 * BITMAP CORE HEADER 読み込み 
		 */
		private function readCoreHeader():void {
			var coreHeader:ByteArray = new ByteArray();
			coreHeader.endian = Endian.LITTLE_ENDIAN;
			
			try {
				bytes.readBytes( coreHeader, 0, BITMAP_CORE_HEADER_SIZE - 4 );
				
				nWidth  = coreHeader.readShort();
				nHeight = coreHeader.readShort();
				nPlains = coreHeader.readUnsignedShort();
				nBitsPerPixel = coreHeader.readUnsignedShort();
			} catch ( e:IOError ) {
				throw new VerifyError("invalid core header");
			}
		}
		
		
		/**
		 * BITMAP INFO HEADER 読み込み
		 */
		private function readInfoHeader():void {
			var infoHeader:ByteArray = new ByteArray();
			infoHeader.endian = Endian.LITTLE_ENDIAN;
			
			try {
				bytes.readBytes( infoHeader, 0, BITMAP_INFO_HEADER_SIZE - 4 );
				
				nWidth  = infoHeader.readInt();
				nHeight = infoHeader.readInt();
				nPlains = infoHeader.readUnsignedShort();
				nBitsPerPixel = infoHeader.readUnsignedShort();
				
				nCompression = infoHeader.readUnsignedInt();
				nSizeImage = infoHeader.readUnsignedInt();
				nXPixPerMeter = infoHeader.readInt();
				nYPixPerMeter = infoHeader.readInt();
				nColorUsed = infoHeader.readUnsignedInt();
				nColorImportant = infoHeader.readUnsignedInt();
			} catch ( e:IOError ) {
				throw new VerifyError("invalid info header");
			}
		}
		
		/**
		 * 拡張 BITMAP INFO HEADER 読み込み
		 */
		private function readExtendedInfoHeader():void {
			var infoHeader:ByteArray = new ByteArray();
			infoHeader.endian = Endian.LITTLE_ENDIAN;
			
			try {
				bytes.readBytes( infoHeader, 0, nInfoSize - 4 );
				
				nWidth  = infoHeader.readInt();
				nHeight = infoHeader.readInt();
				nPlains = infoHeader.readUnsignedShort();
				nBitsPerPixel = infoHeader.readUnsignedShort();
				
				nCompression = infoHeader.readUnsignedInt();
				nSizeImage = infoHeader.readUnsignedInt();
				nXPixPerMeter = infoHeader.readInt();
				nYPixPerMeter = infoHeader.readInt();
				nColorUsed = infoHeader.readUnsignedInt();
				nColorImportant = infoHeader.readUnsignedInt();
				
				if ( infoHeader.bytesAvailable >= 4 ) nRMask = infoHeader.readUnsignedInt();
				if ( infoHeader.bytesAvailable >= 4 ) nGMask = infoHeader.readUnsignedInt();
				if ( infoHeader.bytesAvailable >= 4 ) nBMask = infoHeader.readUnsignedInt();
			} catch ( e:IOError ) {
				throw new VerifyError("invalid info header");
			}
		}
		
		
		/**
		 * ビットフィールド読み込み
		 */
		private function readBitFields():void {
			if ( nCompression == COMP_RGB ){
				if ( nBitsPerPixel == BIT16 ){
					// RGB555
					nRMask = 0x00007c00;
					nGMask = 0x000003e0;
					nBMask = 0x0000001f;
				} else {
					//RGB888;
					nRMask = 0x00ff0000;
					nGMask = 0x0000ff00;
					nBMask = 0x000000ff;
				}
			} else if ( ( nCompression == COMP_BITFIELDS ) && ( nInfoSize < 52 ) ){
				try {
					nRMask = bytes.readUnsignedInt();
					nGMask = bytes.readUnsignedInt();
					nBMask = bytes.readUnsignedInt();
				} catch ( e:IOError ) {
					throw new VerifyError("invalid bit fields");
				}
			}
		}
		
		
		/**
		 * カラーパレット読み込み
		 */
		private function readColorPalette():void {
			var i:int;
			var len:int = ( nColorUsed > 0 ) ? nColorUsed : Math.pow( 2, nBitsPerPixel );
			palette = new Array( len );
			
			for ( i = 0; i < len; ++i ){
				palette[ i ] = bytes.readUnsignedInt();
			}
		}
		
		
		/**
		 * 1bitのBMPデコード
		 */
		private function decode1BitBMP():void {
			var x:int;
			var y:int;
			var i:int;
			var col:int;
			var buf:ByteArray = new ByteArray();
			var line:int = nWidth / 8;
			
			if ( line % 4 > 0 ){
				line = ( ( line / 4 | 0 ) + 1 ) * 4;
			}
			
			try {
				for ( y = nHeight - 1; y >= 0; --y ){
					buf.length = 0;
					bytes.readBytes( buf, 0, line );
					
					for ( x = 0; x < nWidth; x += 8 ){
						col = buf.readUnsignedByte();
						
						for ( i = 0; i < 8; ++i ){
							bd.setPixel( x + i, y, palette[ col >> ( 7 - i ) & 0x01 ] );
						}
					}
				}
			} catch ( e:IOError ) {
				throw new VerifyError("invalid image data");
			}
		}
		
		
		/**
		 * 4bitのRLE圧縮BMPデコード
		 */
		private function decode4bitRLE():void {
			var x:int;
			var y:int;
			var i:int;
			var n:int;
			var col:int;
			var data:uint;
			var buf:ByteArray = new ByteArray();
			
			try {
				for ( y = nHeight - 1; y >= 0; --y ){
					buf.length = 0;
					
					while ( bytes.bytesAvailable > 0 ){
						n = bytes.readUnsignedByte();
						
						if ( n > 0 ){
							// エンコードデータ
							data = bytes.readUnsignedByte();
							for ( i = 0; i < n/2; ++i ){
								buf.writeByte( data );
							}
						} else {
							n = bytes.readUnsignedByte();
							
							if ( n > 0 ){
								// 絶対モードデータ
								bytes.readBytes( buf, buf.length, n/2 );
								buf.position += n/2;
								
								if ( n/2 + 1 >> 1 << 1 != n/2 ){
									bytes.readUnsignedByte();
								}
							} else {
								// EOL
								break;
							}
						}
					}
					
					buf.position = 0;
					
					for ( x = 0; x < nWidth; x += 2 ){
						col = buf.readUnsignedByte();
						
						bd.setPixel( x, y, palette[ col >> 4 ] );
						bd.setPixel( x + 1, y, palette[ col & 0x0f ] );
					}
				}
			} catch ( e:IOError ) {
				throw new VerifyError("invalid image data");
			}
		}
		
		
		/**
		 * 4bitの非圧縮BMPデコード
		 */
		private function decode4BitBMP():void {
			var x:int;
			var y:int;
			var i:int;
			var col:int;
			var buf:ByteArray = new ByteArray();
			var line:int = nWidth / 2;
			
			if ( line % 4 > 0 ){
				line = ( ( line / 4 | 0 ) + 1 ) * 4;
			}
			
			try {
				for ( y = nHeight - 1; y >= 0; --y ){
					buf.length = 0;
					bytes.readBytes( buf, 0, line );
					
					for ( x = 0; x < nWidth; x += 2 ){
						col = buf.readUnsignedByte();
						
						bd.setPixel( x, y, palette[ col >> 4 ] );
						bd.setPixel( x + 1, y, palette[ col & 0x0f ] );
					}
				}
			} catch ( e:IOError ) {
				throw new VerifyError("invalid image data");
			}
		}
		
		
		/**
		 * 8bitのRLE圧縮BMPデコード
		 */
		private function decode8BitRLE():void {
			var x:int;
			var y:int;
			var i:int;
			var n:int;
			var col:int;
			var data:uint;
			var buf:ByteArray = new ByteArray();
			
			try {
				for ( y = nHeight - 1; y >= 0; --y ){
					buf.length = 0;
					
					while ( bytes.bytesAvailable > 0 ){
						n = bytes.readUnsignedByte();
						
						if ( n > 0 ){
							// エンコードデータ
							data = bytes.readUnsignedByte();
							for ( i = 0; i < n; ++i ){
								buf.writeByte( data );
							}
						} else {
							n = bytes.readUnsignedByte();
							
							if ( n > 0 ){
								// 絶対モードデータ
								bytes.readBytes( buf, buf.length, n );
								buf.position += n;
								if ( n + 1 >> 1 << 1 != n ){
									bytes.readUnsignedByte();
								}
							} else {
								// EOL
								break;
							}
						}
					}
					
					buf.position = 0;
					
					for ( x = 0; x < nWidth; ++x ){
						bd.setPixel( x, y, palette[ buf.readUnsignedByte() ] );
					}
				}
			} catch ( e:IOError ) {
				throw new VerifyError("invalid image data");
			}
		}
		
		/**
		 * 8bitの非圧縮BMPデコード
		 */
		private function decode8BitBMP():void {
			var x:int;
			var y:int;
			var i:int;
			var col:int;
			var buf:ByteArray = new ByteArray();
			var line:int = nWidth;
			
			if ( line % 4 > 0 ){
				line = ( ( line / 4 | 0 ) + 1 ) * 4;
			}
			
			try {
				for ( y = nHeight - 1; y >= 0; --y ){
					buf.length = 0;
					bytes.readBytes( buf, 0, line );
					
					for ( x = 0; x < nWidth; ++x ){
						bd.setPixel( x, y, palette[ buf.readUnsignedByte() ] );
					}
				}
			} catch ( e:IOError ) {
				throw new VerifyError("invalid image data");
			}
		}
		
		/**
		 * 16bitのBMPデコード
		 */
		private function decode16BitBMP():void {
			var x:int;
			var y:int;
			var col:int;
			
			try {
				for ( y = nHeight - 1; y >= 0; --y ){
					for ( x = 0; x < nWidth; ++x ){
						col = bytes.readUnsignedShort();
						bd.setPixel( x, y, ( ( ( col & nRMask ) >> nRPos )*0xff/nRMax << 16 ) + ( ( ( col & nGMask ) >> nGPos )*0xff/nGMax << 8 ) + ( ( ( col & nBMask ) >> nBPos )*0xff/nBMax << 0 ) );
					}
				}
			} catch ( e:IOError ) {
				throw new VerifyError("invalid image data");
			}
		}
		
		/**
		 * 24bitのBMPデコード
		 */
		private function decode24BitBMP():void {
			var x:int;
			var y:int;
			var col:int;
			var buf:ByteArray = new ByteArray();
			var line:int = nWidth * 3;
			
			if ( line % 4 > 0 ){
				line = ( ( line / 4 | 0 ) + 1 ) * 4;
			}
			
			try {
				for ( y = nHeight - 1; y >= 0; --y ){
					buf.length = 0;
					bytes.readBytes( buf, 0, line );
					
					for ( x = 0; x < nWidth; ++x ){
						bd.setPixel( x, y, buf.readUnsignedByte() + ( buf.readUnsignedByte() << 8 ) + ( buf.readUnsignedByte() << 16 ) );
					}
				}
			} catch ( e:IOError ) {
				throw new VerifyError("invalid image data");
			}
		}
		
		/**
		 * 32bitのBMPデコード
		 */
		private function decode32BitBMP():void {
			var x:int;
			var y:int;
			var col:int;
			
			try {
				for ( y = nHeight - 1; y >= 0; --y ){
					for ( x = 0; x < nWidth; ++x ){
						col = bytes.readUnsignedInt();
						bd.setPixel( x, y, ( ( ( col & nRMask ) >> nRPos )*0xff/nRMax << 16 ) + ( ( ( col & nGMask ) >> nGPos )*0xff/nGMax << 8 ) + ( ( ( col & nBMask ) >> nBPos )*0xff/nBMax << 0 ) );
					}
				}
			} catch ( e:IOError ) {
				throw new VerifyError("invalid image data");
			}
		}
		
		
		/**
		 * カラーマスクチェック
		 */
		private function checkColorMask():void {
			if ( ( nRMask & nGMask ) | ( nGMask & nBMask ) | ( nBMask & nRMask ) ){
				throw new VerifyError("invalid bit fields");
			}
			
			while ( ( nRMask >> nRPos ) & 0x00000001 == 0 ){
				nRPos++;
			}
			while ( ( nGMask >> nGPos ) & 0x00000001 == 0 ){
				nGPos++;
			}
			while ( ( nBMask >> nBPos ) & 0x00000001 == 0 ){
				nBPos++;
			}
			
			nRMax = nRMask >> nRPos;
			nGMax = nGMask >> nGPos;
			nBMax = nBMask >> nBPos;
		}
		
		
		/**
		 * 情報出力
		 */
		public function traceInfo():void {
			trace("---- FILE HEADER ----");
			trace("nFileSize: " + nFileSize );
			trace("nReserved1: " + nReserved1 );
			trace("nReserved2: " + nReserved2 );
			trace("nOffbits: " + nOffbits );
			
			trace("---- INFO HEADER ----");
			trace("nWidth: " + nWidth );
			trace("nHeight: " + nHeight );
			trace("nPlains: " + nPlains );
			trace("nBitsPerPixel: " + nBitsPerPixel );
			
			if ( nInfoSize >= 40 ){
				trace("nCompression: " + nCompression );
				trace("nSizeImage: " + nSizeImage );
				trace("nXPixPerMeter: " + nXPixPerMeter );
				trace("nYPixPerMeter: " + nYPixPerMeter );
				trace("nColorUsed: " + nColorUsed );
				trace("nColorUsed: " + nColorImportant );
			}
			
			if ( nInfoSize >= 52 ){
				trace("nRMask: " + nRMask.toString( 2 ) );
				trace("nGMask: " + nGMask.toString( 2 ) );
				trace("nBMask: " + nBMask.toString( 2 ) );
			}
		}
	}
}

 

u010054015
关注
专栏目录
源码解析: Imread函数
松子茶的专栏
09-18 1万+
imread()函数在opencv使用比较。声明：Mat imread( const string& filename, int flags )；//这很标准的写法，传入一个string类型的常量引用。下面是定义：Mat imread( const string& filename, int flags ){Mat img;//创建一个变量imread_( filename, flags,其中imread_()中&img用的是地址符号，为什么呢？当然是为了改变其里面的数据了。imread( )函数是就这么几
BMP 的编码与解码
博览不精
04-23 2160
bmp的解析：                  bmp的解析比较简单，参考bmp的文件格式几个正确的将bmp文件解析出来，只是要注意：每一扫描行的字节数必需是4的整倍数，也就是DWORD对齐的。如果你想确保图像的扫描行DWORD对齐可使用下面的代码：(((width*biBitCount)+31)>>5) bmp的编码:                   对于24位bmp编码难度不大，因为没有
BMPDecoder.rar
11-20
一个as3.0的bmp解码类，可以用URLLoader导入bmp图片为2进制，在用这个类解码为BitmapData数据
BMP解码器的练习
改变世界的力量
09-23 175
这是一个BMP解码器的练习，实现8位，24位真彩的解码，放在这里做个记录。希望对各位有用：（分为四个文件，大家可以下载压缩文件，不需要Ctrl+A） package text;   import java.awt.Color; import java.awt.FlowLayout; import java.awt.Font; import java.awt.Graphics; im...
读取bmp图片文件，并获取任意一点的RGB值，并可按任意指定大小保存bmp文件
07-14
bmp文件的读取，可以获得其RGB值，并能按给定大小保存成bmp文件 bmp file to read, get their RGB values, and preservation of a given size into a bmp file
炬力方案系统修改杂记
一块钢板
05-23 2907
1，android4.4修改WiFi里显示的WiFi名android\frameworks\base\wifi\java\android\net\wifi\p2p下的 WifiP2pService.java下的 private String getPersistedDeviceName() { String deviceName = Settings.Global.getString
[RK3288][Android6.0] 调试笔记 --- 移除uboot和kernel开机logo
Kris Fei's blog
05-11 9062
Platform: RockchipOS: Android 6.0Kernel: 3.10.92diff --git a/arch/arm/boot/dts/rk3288-b.dts b/arch/arm/boot/dts/rk3288-b.dtsindex ad3bc1a..f000e29 100644--- a/arch/arm/boot/dts/rk3288-b.dts+++ b/arch/...
Micropython ST7735驱动
09-28
**正文** 在嵌入式开发领域，MicroPython是一种精简版的Python编程语言，它被设计用于资源有限的微控制器，如Arduino或Raspberry Pi Pico等。ST7735是一款广泛应用于小型TFT LCD显示屏的驱动芯片，主要用于显示图形...
显示BMP的AS3支持类库
09-11
1. **BMPDecoder.as**: 这个文件很可能是实现BMP文件解析的核心类。在AS3中，开发者通常会创建一个类来处理BMP文件的二进制数据，将其转化为可以显示的Bitmap对象。BMPDecoder可能包含读取BMP文件头信息、解析像素...
位图解码器BitmapDecoder
认真梳理
10-13 1699
/* * Copyright (C) 2013 Peng fei Pan * * Licensed under the Apache License, Version 2.0 (the "License"); * you may not use this file except in compliance with the License. * You may obtain a co
basename() does not work with Japanese
tengbintang的专栏
10-15 428
<br /><br /><br />http://bugs.php.net/bug.php?id=37738<br />Problem Description:<br />------------<br />Simply put, basename() does ot work with Japanese filepaths. If the filename is Japanese only the extension part of the filename is returned. So a filen
bmp图片格式详解
热门推荐
yun_hen的博客
09-29 2万+
bmp图片格式详解1. BMP文件简介BMP(Bitmap-File）图形文件是Windows采用的图形文件格式，在Windows环境下运行的所有图象处理软件都支持BMP图象文件格式。Windows系统内部各图像绘制操作都是以BMP为基础的。windows 3.0以前的BMP图文件格式与显示设备有关，因此把这种BMP图象文件格式称为设备相关位图DDB(device-dependent bitmap）
BMP Decode
04-18 1609
BMP图象格式
python单片机驱动点阵_[micropython_python]读单色bmp颜色点阵，生成数组
weixin_39936558的博客
12-05 323
颜色点阵，生成数组定义和文本图像文件。(红色字，是局限性说明)按 bmp 格式、二进制读取，所以，很方便转成别的编程语言。至于代码里面的旋转、缩放，就看需要了。Football.jpg (36.98 KB, 下载次数: 0)2020-7-15 15:06 上传原图Football_1bit.jpg (2.94 KB, 下载次数: 0)2020-7-15 15:07 上传缩放、旋转180snap00...
日本人常用的口头禅
06-28 177
日本人常用的口头禅[@more@]あの 、あのう→想不出适当的话时，或说话表现出迟疑，经过大脑思考才说出来比较慎重的缓冲用词。带有'这个嘛，让我想想看。恩，讲起来。我说啊。啊！对了。' ええと →想不起下句话该怎麼说的时候ˇ一种...
Flex Image控件显示BMP图片实现方法
chen550220的专栏
04-11 1573
主要原理是使用2进制载入，再按24位BMP文件格试进行读取并转换成BitmapData再显示出来，只要读入BMP图片转换成二进制，再转成BitmapData，最后把获取位图数据的Bitmap传给Image源，让Image控件显示出来。 请看下面一个Flex工程：
opencv 解决读图像宽度大于1400 BMP图像问题
lcy9819的专栏
09-30 3154
<br />此问题是由于opencv库中cxcore中一处行模板大小内存固定长度为4096限定造成的。<br />通过代码跟踪发现：<br /> <br />1 在bmp解码器中定位到问题(在grfmt_bmp.cpp文件中)<br />bool  BmpDecoder::readData( Mat& img )<br />{<br />…<br />AutoBuffer<uchar> _src, _bgr; //问题源处，此处大小为4096<br />…<br />      uchar *src = _
2019年计算机应用基础统考题库 网考计算机应用基础真题7.pdf
10-06
计算机试题试卷课件
MATLAB使用蚁群算法优化的BP神经网络（ACO-BP）进行多变量时间序列预测（包含详细的完整的程序和数据）
最新发布
10-06
内容概要：本文详述了如何利用MATLAB实现蚁群算法优化的BP神经网络(ACO-BP)，并通过实例演示这种优化方法如何应用于带有天气因子影响的发电量多变量时间序列预测任务上。介绍了ACO-BP的基础概念、算法实施过程以及代码实现，并通过计算均方根误差（RMSE）和平均绝对误差（MAE）验证优化模型的有效性和预测精准度。 适用人群：电气工程相关专业的学生，专注于数据分析与预测的专业人士。 使用场景及目标：适用于电力系统发电量预测的需求，尤其是需要考虑到气象参数变化对于发电产能的具体影响的情境下，用于提高模型预测准确性。 其他说明：提供的详细数据和源码有助于深入理解和实作优化BP网络解决多变数预测挑战，提升预测精度，为相关领域的科研工作者提供了一套完整的实验研究路径和理论参考文献清单。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值