【FPGA】UART串口通信

已于 2022-06-01 21:43:38 修改
阅读量6.1k 收藏 141
点赞数 22
分类专栏： FPGA 文章标签： fpga开发
于 2022-06-01 20:56:28 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/wanerxr/article/details/125073615
版权

目录

前言

嵌入式电子产品是一种互连电路（处理器或其他集成电路）以创建共生系统。

为了使这些单独的电路交换其信息，它们必须共享公共通信协议。

已经定义了数百种通信协议来实现这种数据交换，并且通信的方式主要可以分为两类：并行或串行。

这一章我们需要理解串行通信，并行通信两种方式。并理清UART串口通信的整个模块设计，然后依次编写发送模块，接收模块

一丶通信方式

1.串行通信

定义：串行通信是指利用一条传输线将数据一位位地顺序传送。（也就是说串行通信传输的数据是1比特1比特的传送的）

串行通信又称为点对点通信，对于点对点之间的通信
根据数据的同步方式，又分为 异步通信 和 同步通信 两种方式
根据数据的传输方向与时间关系，又可分为：①单工通信、②半双工通信及③全双工通信三种方式。
在这里插入图片描述
1.同步通信
同步通信一般有一个同步时钟，如下图，一根数据线，一根时钟线。一个时钟传输一个Bit位。
在这里插入图片描述
2.异步通信
异步通信中，在异步通信中有两个比较重要的指标：字符帧格式和波特率。
数据通常以字符或者字节为单位组成字符帧传送，是通过双方约定好的波特率进行数据传输。
假如双方波特率不一致，则接收到数据就是乱码。

在这里插入图片描述
单工：
只允许数据按照一个固定的方向传送，在任何时刻都只能进行一个方向的通信，一个设备固定为发送设备，一个设备固定为接收设备。

半双工：
两个设备之间可以收发数据，但是不能在同一时刻进行，每次只能有一个设备发送，另一个站接收。

全双工：
在同一时刻，两个设备之间可以同时进行发送和接收数据。
在这里插入图片描述

2.并行通信

并行是指多比特数据同时通过并行线进行传送，这样数据传送速度大大提高。

但并行传送的线路长度受到限制，因为长度增加，干扰就会增加，数据也就容易出错。

并行接口同时传输多个位。它们通常需要数据总线（八、十六或更多线路），以1和0的波形传输数据。

如下图：使用9线的并行通信，由时钟控制的8位数据总线，每个时钟脉冲发送一个字节。

在这里插入图片描述

二丶UART 串口通信

它是全双工的异步通信。
串口通信的信号线需要两条线完成，TX和RX TX发送端 RX为接收端
它的协议主要由四部分组成

  • 起始位（1 bit）
  • 数据位（6/7/8 bit）
  • 奇偶校验位（1 bit）
  • 停止位（1 bit）

原理图如下：
在这里插入图片描述

注意：此原理图既作为接收的数据帧，也作为发送的数据帧。因为串行通信中，在数据线上传输的数据是一位一位的，所以在收发数据的时候要进行串并之间的转换

收发流程：

  • 发送：首先是空闲状态，线路处于高电位；当收到发送数据指令后，拉低线路一个数据位的时间T1，接着数据按低位到高位依次发送，数据发送完毕后，接着发送奇偶校验位和停止位（停止位为高电位），一帧数据发送结束。
  • 接收：首先是空闲状态，线路处于高电位；当检测到线路的下降沿（线路电位由高电位变为低电位）时说明线路有数据传输，按照约定的波特率从低位到高位接收数据，数据接收完毕后，接着接收并比较奇偶校验位是否正确，如果正确则通知后续设备准备接收数据或存入缓存，最后接收到停止位（停止位为高电位），一帧数据接收结束。

三丶模块设计

在这里插入图片描述

  • rx为接收端口
  • tx为发送端口
    上图所示分为主机和从机
    我们把FPGA当作从机，来接收上位机（也就是我们的PC）发送过来的数据，再把数据发送给上位机，内部就需要两个模块 uart_rx和uart_tx

uart_rx:
串口接收模块从 rx 接收到数据后，在内部实现接收方法，接收完毕后将数据进行串转并，然后发送给控制模块

uart_tx:
串口发送模块接收到uart_rx模块传来的数据，将数据进行并转串，通过tx端口发送出去

四丶发送模块

1.代码

uart_tx.v

module uart_tx (
    input  wire         clk,
    input  wire         rst_n,
    input  wire [7:0]   din,
    input  wire         din_vld,
    output reg          tx
);
//定义一个寄存器来锁存 din_vld 时的din
reg [9:0]       data;

//波特率计数器
reg [8:0]       cnt_bps;
wire            add_cnt_bps;
wire            end_cnt_bps;

//比特计数器
reg [4:0]       cnt_bit;
wire            add_cnt_bit;
wire            end_cnt_bit;

reg             flag;   //计数器开启标志位

parameter       BPS_115200=434;  //发送一bit数据需要的周期数

//data
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        data<=0;
    end
    else if(din_vld) begin
        data<={1'b1,din,1'b0};   //拼接起始位和停止位
    end
    else
        data<=data;
end

//发送数据 tx
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        tx<=1'b1;
    end
    else if(cnt_bps==1) begin
        tx<=data[cnt_bit];
    end
end

//flag
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        flag<=0;
    end
    else if(din_vld) begin
        flag<=1;
    end
    else if(end_cnt_bit) begin   //发送完成关闭计数器
        flag<=0;
    end
    else
        flag<=flag;
end

//cnt_bps
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        cnt_bps<=0;
    end
    else if(add_cnt_bps) begin
        if (end_cnt_bps) begin
            cnt_bps<=0;
        end
        else
            cnt_bps<=cnt_bps+1;
    end
end

assign add_cnt_bps=flag;
assign end_cnt_bps=add_cnt_bps&&cnt_bps==BPS_115200-1;

//cnt_bit
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        cnt_bit<=0;
    end
    else if(add_cnt_bit) begin
        if (end_cnt_bit) begin
            cnt_bit<=0;
        end
        else
            cnt_bit<=cnt_bit+1;
    end
end

assign add_cnt_bit=end_cnt_bps;
assign end_cnt_bit=add_cnt_bit&&cnt_bit==9;

endmodule //uart_tx

2.仿真

testbench

`timescale 1ns/1ns
module tb_uart_tx ();
reg         clk;
reg         rst_n;
reg [7:0]   din;
reg         din_vld;
wire        tx;

parameter       CYCLE=20;

uart_tx uart_tx(
    .clk              (clk),
    .rst_n            (rst_n),
    .din              (din),
    .din_vld          (din_vld),
    .tx               (tx)
);

always #(CYCLE/2)  clk=~clk;

initial begin
    clk=1;
    rst_n=1;
    #(CYCLE*10);
    rst_n=0;
    din_vld=0;
    #(CYCLE*10);
    rst_n=1;

    din=8'b1001_0101;
    din_vld=1;
    #CYCLE;
    din_vld=0;
    #(CYCLE*434*12);
    $stop;

end

endmodule //tb_uart_tx

如下图所示：
一开始我们进行复位之后，用仿真模拟了uart_rx接收模块，把din（也就是本应该在uart_tx模块进行串转并）和din_vld信号给uart_tx模块，检测到din_vld拉高，data锁存住din，同时开启波特率计数器，从起始位开始发送，直到停止位
在这里插入图片描述
因为我们仿真文件给din赋值为8’b1001_0101，在uart_tx模块中用data拼接起始位和停止位，拼接之后的data为10位的1_1001_0101_0
仿真时序图中可以看到tx端口为0101010011，按顺序输出

在这里插入图片描述

五丶接收模块

1.代码

uart_rx：

module uart_rx (
    input  wire         clk,
    input  wire         rst_n,
    input  wire         rx,
    output reg  [7:0]   dout,    //由接收到的数据进行并转串输出给uart_tx模块
    output reg          dout_vld //接收完成标志位
);

reg             flag;       //rx下降沿来临flag拉高   
reg [9:0]       dout_r;     //锁存rx接收到的数据(从起始位 到数据为 到停止位)

reg             rx_r0;      //同步
reg             rx_r1;      //打拍
wire            nedge;      //下降沿检测

//波特率计数器
reg [8:0]       cnt_bps;
wire            add_cnt_bps;
wire            end_cnt_bps;

//bit计数器
reg [3:0]       cnt_bit;
wire            add_cnt_bit;
wire            end_cnt_bit;

parameter       BPS_115200 = 434;


//同步
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        rx_r0<=1;
    end
    else
        rx_r0<=rx;
end
//打拍
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        rx_r1<=1;   
    end
    else
         rx_r1<=rx_r0;
end

assign nedeg=~rx_r0 & rx_r1;   //下降沿检测，起始位为低电平

//flag
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        flag<=0;
    end
    else if(nedeg) begin
        flag<=1;
    end
    else if(end_cnt_bit) begin
        flag<=0;
    end
end

//cnt_bps
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        cnt_bps<=0;
    end
    else if(add_cnt_bps) begin
        if (end_cnt_bps) begin
            cnt_bps<=0;
        end
        else
            cnt_bps<=cnt_bps+1;
    end
end

assign add_cnt_bps=flag;
assign end_cnt_bps=add_cnt_bps&&cnt_bps==BPS_115200-1;

//cnt_bit
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        cnt_bit<=0;
    end
    else if(add_cnt_bit) begin
        if (end_cnt_bit) begin
            cnt_bit<=0;
        end
        else
            cnt_bit<=cnt_bit+1;
    end
end

assign add_cnt_bit=end_cnt_bps;
assign end_cnt_bit=add_cnt_bit&&cnt_bit==10 -1;

//dout_r
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        dout_r<=0;
    end
    else if(cnt_bps==(BPS_115200>>1)) begin
        dout_r[cnt_bit]<=rx_r0;
    end
end

//dout
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        dout<=0;
    end
    else if(end_cnt_bit) begin
        dout<=dout_r[8:1];        //只用把数据位传给uart_tx模块，所以取中间的8位
    end
end

//dout_vld
always @(posedge clk or negedge rst_n) begin
    if (!rst_n) begin
        dout_vld<=0;
    end
    else if(end_cnt_bit) begin
        dout_vld<=1;        //给发送模块的数据有效信号
    end
    else
        dout_vld<=0;
end
endmodule //uart_rx

2.仿真

testbench

`timescale 1ns/1ns
module tb_uart_rx ();
reg         clk;
reg         rst_n;
reg         rx;
wire[7:0]   dout;
wire        dout_vld;

integer i;

parameter       CYCLE=20;

uart_rx uart_rx(
    .clk               (clk),
    .rst_n             (rst_n),
    .dout              (dout),
    .dout_vld          (dout_vld),
    .rx                (rx)
);

always #(CYCLE/2)  clk=~clk;

initial begin
    clk=1;
    rst_n=1;
    #(CYCLE*10);
    rst_n=0;
    rx=1;
    #(CYCLE*10);
    rst_n=1;
    rx=0;   //起始位
    #(CYCLE*434);
    for (i = 0; i<8; i=i+1) begin
        #(CYCLE*434);
        rx={$random}%2;  //产生0~1的随机数
    end

    rx=1;   //停止位

    #(CYCLE*1000);
    $stop;

end

endmodule

结果如下图所示：

我们在接收模块需要把接收到的串行数据转换成并行数据再传给uart_tx模块
空闲状态的时候，rx处于高电平状态，我们在仿真文件中模拟rx拉低，也就是接收到了起始位，波特率计数器（add_cnt_bps）开启

在这里插入图片描述rx接收到停止位，也就是一共接收了10bit（1bit起始位+8bit数据位+1bit停止位），此时bit计数器拉低（end_cnt_bit），并行数据dout锁存，拉高一个周期的数据有效信号（dout_vld）
在这里插入图片描述

六丶顶层模块

1.代码

uart.v

module uart (
    input  wire             clk,
    input  wire             rst_n,
    input  wire             rx,    //接收
    output wire             tx     //发送
);
wire [7:0]      dout;   
wire            dout_vld;  

uart_tx  u_uart_tx(           //将发送的并行数据转换成串行数据
    .clk            (clk),
    .rst_n          (rst_n),
    .tx             (tx),     //串行数据
    .din            (dout),   //并行数据
    .din_vld        (dout_vld)
);

uart_rx  u_uarr_rx(           //将接收到的串行数据转换成并行数据
    .clk            (clk),
    .rst_n          (rst_n),
    .rx             (rx),     //串行数据
    .dout           (dout),   //并行数据
    .dout_vld       (dout_vld)
);
endmodule //uart

2.模块原理图

在这里插入图片描述

3.仿真

对于顶层的仿真，我们需要模拟出一个上位机来给我们的FPGA发送数据，
所以在例化模块的时候，我们首先例化一个uart_tx当作上位机，来给我们的从机发送数据，然后例化一个uart模块当作从机，也就是例化顶层模块

思路清晰了，进行testbench的编写

`timescale 1ns/1ns
module tb_uart ();
reg         clk;
reg         rst_n;
reg [7:0]   din;
reg         din_vld;
wire        tx_r;   //用来连接上位机的tx和从机的rx
wire        rx;

parameter       CYCLE=20;

//例化从机（顶层模块，包含了一个uart_rx和一个uart_tx）
uart uart(
    .clk            (clk),
    .rst_n          (rst_n),
    .rx             (tx_r),    //接收
    .tx             (tx)     //发送
);

//例化上位机（用来给从机发送数据）
uart_tx uart_tx(
    .clk              (clk),
    .rst_n            (rst_n),
    .din              (din),
    .din_vld          (din_vld),
    .tx               (tx_r)
);

always #(CYCLE/2)  clk=~clk;

initial begin
    clk=1;
    rst_n=1;
    #(CYCLE*10);
    rst_n=0;
    din_vld=0;
    #(CYCLE*10);
    rst_n=1;

    din=8'b1001_0101;
    din_vld=1;
    #CYCLE;
    din_vld=0;
    #(CYCLE*434*22);
    $stop;

end

endmodule //tb_uart_tx

首先，我们模拟上位机发送数据，在仿真文件中拉高dout_vld，并给dout一个8位的数据1001_0101，经过拼接起始位和停止位，data锁存这一帧的数据：1_1001_0101_0

在这里插入图片描述放大观察细节，在时钟上升沿检测到cnt_bps为1，则把data的第0位给tx发送
在这里插入图片描述对照uart_tx的这一部分代码来理解

在这里插入图片描述
发送了起始位之后，从机（FPGA）收到起始位
在这里插入图片描述
下图 第3步 从机的接收模块接收完成之后，给自己的发送模块 传送并行数据 dout 以及数据有效信号dout_vld

在这里插入图片描述

发送模块接收到数据有效信号dout_vld拉高，将数据缓存，并开启计数器（意味着开始传数据，！！！从起始位开始，这里缓存数据也要拼接起始位和停止位）

在这里插入图片描述之后就跟上位机发送数据一模一样了

七丶上板验证

管脚绑定
在这里插入图片描述
本次实验的结果：上位机（PC）给我们的从机（FPGA）发送数据之后，从机收到数据并将数据发送给上位机，如图显示的一样
下一章，我们将使用FIFO作为数据缓存单元，完成数据回环
请添加图片描述

八丶源码

https://github.com/xuranww/uart.git

参考文章：
1.https://blog.csdn.net/Rocher_22/article/details/116590629
2.https://blog.csdn.net/ybhuangfugui/article/details/109465401

  1. 本文采用的比特率是115200bps，也就是1s传输115200bit的数据，
    且我们使用的时钟是20MHz
    计算传输一次需要的时间：
    计数时间 = 1_000_000_000ns/115200 = 8680ns
    50MHz的时钟周期为20ns,所以计数传输一个比特的次数为8680 / 20 = 434 ↩︎

ww丶121
关注
  • 22
    点赞
  • 踩
  • 141
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
FPGA UART串口通信Verilog参考代码
10-03
FPGA UART串口通信Verilog参考代码
uart串口通信（收、发）fpga实现
06-12
通过Verilog实现了RS232串口通信功能，包括串口的接收和发送，并给出了详细的注释，易于代码的理解，只需针对自己的实际情况稍加修改便可直接使用。实际上板验证可用
FPGA(Verilog)实现uart传输协议传输数据(含仿真)
qq_69866029的博客
04-05 1323
FPGA(Verilog)实现uart传输协议传输数据。
干货 | 在FPGA上实现UART串口通信
dpwkj的博客
06-12 469
UART（Universal Asynchronous Receiver/Transmitter）是一种通信协议，用于在电子设备之间传输数据。它是一种串行通信协议，意味着数据位按顺序一个接一个地传输。
FPGA基础协议一：UART
ChenJ_1012的博客
07-09 1494
赢麻了！
基于FPGA的UART通信——基础篇
weixin_51116586的博客
11-10 1699
基于FPGA实现的UART异步串行通信,这是基础篇.
FPGA——UART串口通信
zhu1289的博客
10-16 841
UART通信——FPGA
【FPGA】八、UART串口通信
weixin_62912626的博客
12-23 8571
FPGA UART串口通信
FPGA入门 —— FPGA UART 串口通信
ppqppl的博客
06-06 4976
FPGA入门 —— FPGA UART 串口通信 串口简介 UART 通用异步收发传输器( Universal Asynchronous Receiver/Transmitter) ，通常称作 UART。 UART 是一种通用的数据通信协议，也是异步串行通信口(串口)的总称，它在发送数据时将并行数据转换成串行数据来传输，在接收数据时将接收到的串行数据转换成并行数据。 它包括了ch340、 RS2...
FPGA实现UART串口通信最全资料
02-19
FPGA实现UART串口通信资料，不仅有基于Quratus II 的源代码，还有一篇WORD文档的详细说明，并附有串口调试助手。学习RS232串口通信,真的比较全了。
FPGA实现串口UART通信，内涵详细工程文件
01-24
通用异步收发传输器（Universal Asynchronous Receiver/Transmitter)，通常称作UART，是一种异步收发传输器，是电脑硬件的一部分。它将要传输的资料在串行通信与并行通信之间加以转换。作为把并行输入信号转成串行输出信号的芯片，UART通常被集成于其他通讯接口的连结上。 具体实物表现为独立的模块化芯片，或作为集成于微处理器中的周边设备。一般是RS-232C规格的，与类似Maxim的MAX232之类的标准信号幅度变换芯片进行搭配，作为连接外部设备的接口。在UART上追加同步方式的序列信号变换电路的产品，被称为USART(Universal Synchronous Asynchronous Receiver Transmitter)。
FPGA UART通信
11-13
文件包括接收模块，发送模块，波特率产生模块以及测试文件，接收以16倍波特率接收，发送以波特率速度发送，代码风格良好，采用三段式状态机编码
fpga开发 uart串口通信通用
03-06
UART（Universal Asynchronous Receiver/Transmitter）通用异步收发传输器是一种常见的串行通信接口，在FPGA（Field-Programmable Gate Array）开发中，UART接口被广泛用于实现FPGA与外部设备间的通信，例如微处理器...
FPGA搭建UART实现串口通信源码.zip
最新发布
06-26
FPGA搭建UART实现串口通信源码.zipFPGA搭建UART实现串口通信源码.zipFPGA搭建UART实现串口通信源码.zipFPGA搭建UART实现串口通信源码.zipFPGA搭建UART实现串口通信源码.zipFPGA搭建UART实现串口通信源码.zipFPGA搭建...
FPGA开发UART串口通信通用模块
03-03
fpga uart串口通信通用模块。包含所有模块源文件、测试文件、测试工程、及模块使用介绍和模块测试报告。模块通用性强，可移植性强，可通过测试工程自行修改，或自行例化模块，只需简单配置几个参数，驱动相应信号...
基于FPGA的uart串口通信
01-17
UART（通用异步收发传输器）是一种广泛用于设备间串行通信的接口标准，尤其在嵌入式系统和FPGA设计中应用颇广。基于FPGA实现UART通信，能够利用其并行处理能力，提高数据传输效率。下面将详细阐述UART的工作原理、...
FPGA入门基础之UART串口通信设计
FPGA_Designer
05-17 896
引言：UART是一种通用串行数据总线，用于异步通信。该总线双向通信，可实现全双工传输和接收。UART通常用来实现与PC之间数据通信，命令和控制信息的传输等。本文我们介绍UART通信协议、传输时序及如何利用HDL编程实现FPGA与PC通信。
FPGA uart串口通信
05-21
FPGA可以通过配置内部的逻辑电路实现UART串口通信。 在FPGA中，UART串口通信需要通过FPGA上的串口模块进行实现。串口模块主要包括收发电路和状态机两个部分。收发电路用于将数据从串口输入或输出，状态机用于控制...
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值