简单采用windows批处理命令批量合并命名安卓B站缓存视频

概述

网上找一大圈，都是让下载某款付费软件，要不合并视频有水印，本文采用windows批处理方法，将视频进行合并，并且自动为转换后视频命名，无文件时长等使用限制，无水印问题。无需安装复杂的python等环境。

下载并使用ffmpeg

进入官网链接：Builds - CODEX FFMPEG @ gyan.dev

下载release中的ffmpeg-release-full.7z版本，下载后将ffmpeg.exe解压出来，放在C:/WINDOWS/system32中。

拷贝文件到电脑

将安卓手机中需要合并的文件拷贝到电脑的目录。

在安卓设备中，缓存的视频文件，一般是在

Android/data/tv.danmaku.bili/download

目录中，每个视频文件夹中，都有video.m4s、audio.m4s。

此处以D:\Temp目录为例

编写脚本

新建一个以.bat后缀的文本文件，打开文本编辑器，记事本等均可，输入以下代码。

@echo off
setlocal enabledelayedexpansion

REM 设置大文件夹路径
set "root_folder=D:\Temp"

REM 设置字符编码为UTF-8
chcp 65001 > nul

REM 查找所有包含video.m4s文件的子文件夹
for /r "%root_folder%" %%d in (video.m4s) do (
    set "folder=%%~dpd"
    REM 获取父目录（去掉最后一个文件夹）
    for %%p in ("!folder:~0,-1!") do set "parent_folder=%%~dpp"
    set "entry_json=!parent_folder!entry.json"
    
    if not exist "%%~dpd\output.mp4" (
        if exist "%%~dpd\audio.m4s" (
            if exist "!entry_json!" (
                REM 读取entry.json文件内容
                set "output_name="
                REM 从字符串末尾向前搜索"download_subtitle"字段
                set "json_content="
                for /f "usebackq tokens=*" %%a in ("!entry_json!") do set "json_content=%%~a"
                set "substring=!json_content:*"download_subtitle":"=!"
                REM 删除字符串末尾的"}"
                set "subtitle=!substring:~0,-2!"
                set "output_name=!subtitle!"
                
                if defined output_name (
                    echo Merging video and audio in %%~dpd and naming it "!output_name!.mp4"
                    ffmpeg -i "%%~dpd\video.m4s" -i "%%~dpd\audio.m4s" -codec copy "%%~dpd\!output_name!.mp4"
                ) else (
                    echo Merging video and audio in %%~dpd and naming it output.mp4
                    ffmpeg -i "%%~dpd\video.m4s" -i "%%~dpd\audio.m4s" -codec copy "%%~dpd\output.mp4"
                )
            ) else (
                echo No entry.json found in !parent_folder!, merging video and audio in %%~dpd and naming it output.mp4
                ffmpeg -i "%%~dpd\video.m4s" -i "%%~dpd\audio.m4s" -codec copy "%%~dpd\output.mp4"
            )
        )
    )
)

endlocal

将D:\Temp替换为实际存放B站缓存视频的位置，点击运行即可。