POV-RAY基础教程 - 相机(6)

回到上一篇 POV-RAY基础教程 - 简单贴图/纹理设置(5)

使用焦点模糊

让我们构建一个简单的场景来说明焦点模糊的使用。对于这个例子，我们将使用粉红色球体，绿色框和蓝色圆柱体，球体放置在前景中，盒子放在中心，圆柱体放在背景中。一个方格的透视地板和几个光源将完成现场。我们创建一个名为的新文件focaldem.pov并输入以下文本

  #include "colors.inc"
  #include "shapes.inc"
  #include "textures.inc"
  sphere {
    <1, 0, -6>, 0.5
    finish {
      ambient 0.1
      diffuse 0.6
    }
    pigment { NeonPink }
  }
  box {
    <-1, -1, -1>, < 1,  1,  1>
    rotate <0, -20, 0>
    finish {
      ambient 0.1
      diffuse 0.6
    }
    pigment { Green }
  }
  cylinder {
    <-6, 6, 30>, <-6, -1, 30>, 3
    finish {
      ambient 0.1
      diffuse 0.6
    }
    pigment {NeonBlue}
  }
  plane {
    y, -1.0
    pigment {
      checker color Gray65 color Gray30
    }
  }
  light_source { <5, 30, -30> color White }
  light_source { <-5, 30, -30> color White }
  

现在我们可以将焦点模糊相机放置到合适的观看位置。从我们的三个物体直接回来将产生一个美好的景色。调整焦点会将焦点移动到场景中的任何位置。我们只需在文件中添加以下行：

  camera {
    location <0.0, 1.0, -10.0>
    look_at  <0.0, 1.0,  0.0>
    focal_point < 1, 1, -6>    // pink sphere in focus
    aperture 0.4     // a nice compromise
    blur_samples 20      // more samples, higher quality image
  }

效果图

焦点只是相机焦点最清晰的点。我们将这一点定位在场景中并为光圈指定一个值，以调整我们希望焦点模糊从聚焦区域发出的距离或距离。调整focal_point为<-6, 1, 30>,使焦点落在圆柱体上
效果图

调整focal_point为<0,1,0>,使焦点落在正方体上
效果图

光圈设置可以被认为是焦点区域。打开光圈具有使焦点区域更小的效果，同时使光圈值更小，使得焦点区域更大。这就是我们如何控制焦点周围开始出现焦点模糊的方式。
aperture关键字，他的翻译是光圈，孔径。我们可以通过修改它的属性值，来获得，焦点距离我们物体的远近程度的效果，即，获得不同的聚焦效果。我们为他赋值越小，关注的区域就越大，反之，则小。
下面aperture的值为0.05时，三个物体都在焦点范围内，都能看清。
效果图

aperture的值增大到1.5时，会获得更加模糊的效果
效果图

blur_samples关键字的作用是采样设置，很容易理解的是：采样点数越多，值越大，我们就可以获得质量/分辨率越高的图像，但相应的渲染时间就会长。合理设置该属性值，是一个折中的选择。
使用焦点模糊摄像机的几点注意：

1.我们不需要在指定anti-aliasing，因为焦点模糊代码会使用它自己的采样法，从而能够自动的考虑到抗锯齿问题。
2.焦距模糊功能只能在透视摄像机上使用。

继续阅读 POV-RAY基础教程 - POV-Ray坐标系(7)