HBase2.x（十六） HBase与 Hive 的集成

使用场景

如果大量的数据已经存放在 HBase 上面，需要对已经存在的数据进行数据分析处理，那么 Phoenix 并不适合做特别复杂的 SQL 处理，此时可以使用 hive 映射 HBase 的表格，之后写 HQL 进行分析处理。

HBase 与 Hive 集成使用

在 hive-site.xml 中添加 zookeeper 的属性，如下：

<property>
    <name>hive.zookeeper.quorum</name>
    <value>hadoop102,hadoop103,hadoop104</value>
</property>
<property>
    <name>hive.zookeeper.client.port</name>
    <value>2181</value>
</property>

案例一

目标：建立 Hive 表，关联 HBase 表，插入数据到 Hive 表的同时能够影响 HBase 表。
分步实现：
（1）在 Hive 中创建表同时关联 HBase

CREATE TABLE hive_hbase_emp_table(
  empno INT,
  ename string,
  job string,
  mgr INT,
  hiredate string,
  sal DOUBLE,
  comm DOUBLE,
  deptno INT
) STORED BY 'org.apache.hadoop.hive.hbase.HBaseStorageHandler' WITH SERDEPROPERTIES (
  "hbase.columns.mapping" = ":key,info:ename,info:job,info:mgr,info:hiredate,info:sal,info:comm,info:deptno"
) TBLPROPERTIES ("hbase.table.name" = "hbase_emp_table");

提示：完成之后，可以分别进入 Hive 和 HBase 查看，都生成了对应的表。

（2）在 Hive 中创建临时中间表，用于 load 文件中的数据

提示：不能将数据直接 load 进 Hive 所关联 HBase 的那张表中。

CREATE TABLE emp(
 empno int,
 ename string,
 job string,
 mgr int,
 hiredate string,
 sal double,
 comm double,
 deptno int
)
row format delimited fields terminated by '	';

（3）在虚拟机/opt/software/中新建emp.txt文件，内容如下

7369	SMITH	CLERK	7902	1980-12-17	800.00		20
7499	ALLEN	SALESMAN	7698	1981-2-20	1600.00	300.00	30
7521	WARD	SALESMAN	7698	1981-2-22	1250.00	500.00	30
7566	JONES	MANAGER	7839	1981-4-2	2975.00		20
7654	MARTIN	SALESMAN	7698	1981-9-28	1250.00	1400.00	30
7698	BLAKE	MANAGER	7839	1981-5-1	2850.00		30
7782	CLARK	MANAGER	7839	1981-6-9	2450.00		10
7788	SCOTT	ANALYST	7566	1987-4-19	3000.00		20
7839	KING	PRESIDENT		1981-11-17	5000.00		10
7844	TURNER	SALESMAN	7698	1981-9-8	1500.00	0.00	30
7876	ADAMS	CLERK	7788	1987-5-23	1100.00		20
7900	JAMES	CLERK	7698	1981-12-3	950.00		30
7902	FORD	ANALYST	7566	1981-12-3	3000.00		20
7934	MILLER	CLERK	7782	1982-1-23	1300.00		10

（4）向 Hive 中间表中 load 数据

hive> load data local inpath '/opt/software/emp.txt' into table emp;

（5）通过 insert 命令将中间表中的数据导入到 Hive 关联 Hbase 的那张表中

hive> insert into table hive_hbase_emp_table select * from emp;

（6）查看 Hive 以及关联的 HBase 表中是否已经成功的同步插入了数据

Hive表中查看数据

hive> select * from hive_hbase_emp_table;

HBase表中查看数据

hbase:002:0> scan 'hbase_emp_table'

注意：如果插入数据过程抛如下异常

Caused by: javax.security.sasl.SaslException：Server closed before SASL negotiation finished.

修改/opt/module/hadoop-3.1.3/etc/hadoop/capacity-scheduler.xml中am启动的最大资源配置。分发、并重新启动resourcemanager

vim capacity-scheduler.xml

 <property>
     <name>yarn.scheduler.capacity.maximum-am-resource-percent</name>
     <value>1</value>
 </property>

案例二

目标：在 HBase 中已经存储了某一张表 hbase_emp_table，然后在 Hive 中创建一个外部表来关联 HBase 中的 hbase_emp_table 这张表，使之可以借助 Hive 来分析 HBase 这张表中的数据。

注：该案例 2 紧跟案例 1 的脚步，所以完成此案例前，请先完成案例 1。
分步实现：

（1）在 Hive 中创建外部表

CREATE EXTERNAL TABLE relevance_hbase_emp(
  empno INT,
  ename string,
  job string,
  mgr INT,
  hiredate string,
  sal DOUBLE,
  comm DOUBLE,
  deptno INT
) STORED BY 'org.apache.hadoop.hive.hbase.HBaseStorageHandler' WITH SERDEPROPERTIES (
  "hbase.columns.mapping" = ":key,info:ename,info:job,info:mgr,info:hiredate,info:sal,info:comm,info:deptno"
) TBLPROPERTIES ("hbase.table.name" = "hbase_emp_table");

（2）关联后就可以使用 Hive 函数进行一些分析操作了

hive (default)> select deptno,avg(sal) monery from relevance_hbase_emp group by deptno;