作者:y19662206
转自:http://blog.csdn.net/y19662206/article/details/2184023
这是win32汇编语言中关于钩子函数的讲解,是丛windows的底层讲的,对于c,vb,delphi以至于易语言,原理都相同,只是语法的问题。
windows钩子函数
--------------------------------------------------------------------------------
本课中我们将要学习windows钩子函数的使用方法。windows钩子函数的功能非常强大,有了它您可以探测其它进程并且改变其它进程的行为。
理论:
windows的钩子函数可以认为是windows的主要特性之一。利用它们,您可以捕捉您自己进程或其它进程发生的事件。通过“钩挂”,您可以给windows一个处理或过滤事件的回调函数,该函数也叫做“钩子函数”,当每次发生您感兴趣的事件时,windows都将调用该函数。一共有两种类型的钩子:局部的和远程的。
局部钩子仅钩挂您自己进程的事件。
远程的钩子还可以将钩挂其它进程发生的事件。远程的钩子又有两种:
基于线程的 它将捕获其它进程中某一特定线程的事件。简言之,就是可以用来观察其它进程中的某一特定线程将发生的事件。
系统范围的 将捕捉系统中所有进程将发生的事件消息。
安装钩子函数将会影响系统的性能。监测“系统范围事件”的系统钩子特别明显。因为系统在处理所有的相关事件时都将调用您的钩子函数,这样您的系统将会明显的减慢。所以应谨慎使用,用完后立即卸载。还有,由于您可以预先截获其它进程的消息,所以一旦您的钩子函数出了问题的话必将影响其它的进程。记住:功能强大也意味着使用时要负责任。
在正确使用钩子函数前,我们先讲解钩子函数的工作原理。当您创建一个钩子时,windows会先在内存中创建一个数据结构,该数据结构包含了钩子的相关信息,然后把该结构体加到已经存在的钩子链表中去。新的钩子将加到老的前面。当一个事件发生时,如果您安装的是一个局部钩子,您进程中的钩子函数将被调用。如果是一个远程钩子,系统就必须把钩子函数插入到其它进程的地址空间,要做到这一点要求钩子函数必须在一个动态链接库中,所以如果您想要使用远程钩子,就必须把该钩子函数放到动态链接库中去。当然有两个例外:工作日志钩子和工作日志回放钩子。这两个钩子的钩子函数必须在安装钩子的线程中。原因是:这两个钩子是用来监控比较底层的硬件事件的,既然是记录和回放,所有的事件就当然都是有先后次序的。所以如果把回调函数放在dll中,输入的事件被放在几个线程中记录,所以我们无法保证得到正确的次序。故解决的办法是:把钩子函数放到单个的线程中,譬如安装钩子的线程。
钩子一共有14种,以下是它们被调用的时机:
wh_callwndproc 当调用sendmessage时
wh_callwndprocret 当sendmessage的调用返回时
wh_getmessage 当调用getmessage 或 peekmessage时
wh_keyboard 当调用getmessage 或 peekmessage 来从消息队列中查询wm_keyup 或 wm_keydown 消息时
wh_mouse 当调用getmessage 或 peekmessage 来从消息队列中查询鼠标事件消息时
wh_hardware 当调用getmessage 或 peekmessage 来从消息队列种查询非鼠标、键盘消息时
wh_msgfilter 当对话框、菜单或滚动条要处理一个消息时。该钩子是局部的。它时为那些有自己的消息处理过程的控件对象设计的。
wh_sysmsgfilter 和wh_msgfilter一样,只不过是系统范围的
wh_journalrecord 当windows从硬件队列中获得消息时
wh_journalplayback 当一个事件从系统的硬件输入队列中被请求时
wh_shell 当关于windows外壳事件发生时,譬如任务条需要重画它的按钮.
wh_cbt 当基于计算机的训练(cbt)事件发生时
wh_foregroundidle 由windows自己使用,一般的应用程序很少使用
wh_debug 用来给钩子函数除错
现在我们知道了一些基本的理论,现在开始讲解如何安装/卸载一个钩子。
要安装一个钩子,您可以调用setwindowhookex函数。该函数的原型如下:
setwindowshookex proto hooktype:dword, phookproc:dword, hinstance:dword, threadid:dword
hooktype 是我们上面列出的值之一,譬如: wh_mouse, wh_keyboard
phookproc 是钩子函数的地址。如果使用的是远程的钩子,就必须放在一个dll中,否则放在本身代码中
hinstance 钩子函数所在dll的实例句柄。如果是一个局部的钩子,该值为null
threadid 是您安装该钩子函数后想监控的线程的id号。该参数可以决定该钩子是局部的还是系统范围的。如果该值为null,那么该钩子将被解释成系统范围内的,那它就可以监控所有的进程及它们的线程。如果您指定了您自己进程中的某个线程id 号,那该钩子是一个局部的钩子。如果该线程id是另一个进程中某个线程的id,那该钩子是一个全局的远程钩子。这里有两个特殊情况:wh_journalrecord 和 wh_journalplayback总是代表局部的系统范围的钩子,之所以说是局部,是因为它们没有必要放到一个dll中。wh_sysmsgfilter 总是一个系统范围内的远程钩子。其实它和wh_msgfilter钩子类似,如果把参数threadid设成0的话,它们就完全一样了。
如果该函数调用成功的话,将在eax中返回钩子的句柄,否则返回null。您必须保存该句柄,因为后面我们还要它来卸载钩子。
要卸载一个钩子时调用unhookwidowhookex函数,该函数仅有一个参数,就是欲卸载的钩子的句柄。如果调用成功的话,在eax中返回非0值,否则返回null。
现在您知道了如何安装和卸载一个钩子了,接下来我们将看看钩子函数。.
只要您安装的钩子的消息事件类型发生,windows就将调用钩子函数。譬如您安装的钩子是wh_mouse类型,那么只要有一个鼠标事件发生时,该钩子函数就会被调用。不管您安装的时那一类型钩子,钩子函数的原型都时是一样的:
hookproc proto ncode:dword, wparam:dword, lparam:dword
ncode 指定是否需要处理该消息
wparam 和 lparam 包含该消息的附加消息
hookproc 可以看作是一个函数名的占位符。只要函数的原型一致,您可以给该函数取任何名字。至于以上的几个参数及返回值的具体含义各种类型的钩子都不相同。譬如:
wh_callwndproc
ncode 只能是hc_action,它代表有一个消息发送给了一个窗口
wparam 如果非0,代表正被发送的消息
lparam 指向cwpstruct型结构体变量的指针
return value: 未使用,返回0
wh_mouse
ncode 为hc_action 或 hc_noremove
wparam 包含鼠标的事件消息
lparam 指向mousehookstruct型结构体变量的指针
return value: 如果不处理返回0,否则返回非0值
所以您必须查询您的win32 api 指南来得到不同类型的钩子的参数的详细定义以及它们返回值的意义。这里还有一个问题需要注意:所有的钩子都串在一个链表上,最近加入的钩子放在链表的头部。当一个事件发生时,windows将按照从链表头到链表尾调用的顺序。所以您的钩子函数有责任把消息传到下一个链中的钩子函数。当然您可以不这样做,但是您最好明白这时这么做的原因。在大多数的情况下,最好把消息事件传递下去以便其它的钩子都有机会获得处理这一消息的机会。调用下一个钩子函数可以调用函数callnexthookex。该函数的原型如下:
callnexthookex proto hhook:dword, ncode:dword, wparam:dword, lparam:dword
hhook 时是您自己的钩子函数的句柄。利用该句柄可以遍历钩子链。
ncode, wparam and lparam 您只要把传入的参数简单传给callnexthookex即可。
请注意:对于远程钩子,钩子函数必须放到dll中,它们将从dll中映射到其它的进程空间中去。当windows映射dll到其它的进程空间中去时,不会把数据段也进行映射。简言之,所有的进程仅共享dll的代码,至于数据段,每一个进程都将有其单独的拷贝。这是一个很容易被忽视的问题。您可能想当然的以为,在dll中保存的值可以在所有映射该dll的进程之间共享。在通常情况下,由于每一个映射该dll的进程都有自己的数据段,所以在大多数的情况下您的程序运行得都不错。但是钩子函数却不是如此。对于钩子函数来说,要求dll的数据段对所有的进程也必须相同。这样您就必须把数据段设成共享的,这可以通过在链接开关中指定段的属性来实现。在masm中您可以这么做:
/section:<section name>, s
已初期化的段名是.data,未初始化的段名是.bss。`加入您想要写一个包含钩子函数的dll,而且想使它的未初始化的数据段在所有进程间共享,您必须这么做:
link /section:.bss,s /dll /subsystem:windows ..........
s 代表该段是共享段。
例子:
一共有两个模块:一个是gui部分,另一个是安装和卸载钩子的dll。
;--------------------------------------------- 主程序的源代码部分--------------------------------------
.386
.model flat,stdcall
option casemap:none
include /masm32/include/windows.inc
include /masm32/include/user32.inc
include /masm32/include/kernel32.inc
include mousehook.inc
includelib mousehook.lib
includelib /masm32/lib/user32.lib
includelib /masm32/lib/kernel32.lib
wsprintfa proto c :dword,:dword,:vararg
wsprintf textequ <wsprintfa>
.const
idd_maindlg equ 101
idc_classname equ 1000
idc_handle equ 1001
idc_wndproc equ 1002
idc_hook equ 1004
idc_exit equ 1005
wm_mousehook equ wm_user+6
dlgfunc proto :dword,:dword,:dword,:dword
.data
hookflag dd false
hooktext db "&hook",0
unhooktext db "&unhook",0
template db "%lx",0
.data?
hinstance dd ?
hhook dd ?
.code
start:
invoke getmodulehandle,null
mov hinstance,eax
invoke dialogboxparam,hinstance,idd_maindlg,null,addr dlgfunc,null
invoke exitprocess,null
dlgfunc proc hdlg:dword,umsg:dword,wparam:dword,lparam:dword
local hlib:dword
local buffer[128]:byte
local buffer1[128]:byte
local rect:rect
.if umsg==wm_close
.if hookflag==true
invoke uninstallhook
.endif
invoke enddialog,hdlg,null
.elseif umsg==wm_initdialog
invoke getwindowrect,hdlg,addr rect
invoke setwindowpos, hdlg, hwnd_topmost, rect.left, rect.top, rect.right, rect.bottom, swp_showwindow
.elseif umsg==wm_mousehook
invoke getdlgitemtext,hdlg,idc_handle,addr buffer1,128
invoke wsprintf,addr buffer,addr template,wparam
invoke lstrcmpi,addr buffer,addr buffer1
.if eax!=0
invoke setdlgitemtext,hdlg,idc_handle,addr buffer
.endif
invoke getdlgitemtext,hdlg,idc_classname,addr buffer1,128
invoke getclassname,wparam,addr buffer,128
invoke lstrcmpi,addr buffer,addr buffer1
.if eax!=0
invoke setdlgitemtext,hdlg,idc_classname,addr buffer
.endif
invoke getdlgitemtext,hdlg,idc_wndproc,addr buffer1,128
invoke getclasslong,wparam,gcl_wndproc
invoke wsprintf,addr buffer,addr template,eax
invoke lstrcmpi,addr buffer,addr buffer1
.if eax!=0
invoke setdlgitemtext,hdlg,idc_wndproc,addr buffer
.endif
.elseif umsg==wm_command
.if lparam!=0
mov eax,wparam
mov edx,eax
shr edx,16
.if dx==bn_clicked
.if ax==idc_exit
invoke sendmessage,hdlg,wm_close,0,0
.else
.if hookflag==false
invoke installhook,hdlg
.if eax!=null
mov hookflag,true
invoke setdlgitemtext,hdlg,idc_hook,addr unhooktext
.endif
.else
invoke uninstallhook
invoke setdlgitemtext,hdlg,idc_hook,addr hooktext
mov hookflag,false
invoke setdlgitemtext,hdlg,idc_classname,null
invoke setdlgitemtext,hdlg,idc_handle,null
invoke setdlgitemtext,hdlg,idc_wndproc,null
.endif
.endif
.endif
.endif
.else
mov eax,false
ret
.endif
mov eax,true
ret
dlgfunc endp
end start
;----------------------------------------------------- dll的源代码部分 --------------------------------------
.386
.model flat,stdcall
option casemap:none
include /masm32/include/windows.inc
include /masm32/include/kernel32.inc
includelib /masm32/lib/kernel32.lib
include /masm32/include/user32.inc
includelib /masm32/lib/user32.lib
.const
wm_mousehook equ wm_user+6
.data
hinstance dd 0
.data?
hhook dd ?
hwnd dd ?
.code
dllentry proc hinst:hinstance, reason:dword, reserved1:dword
.if reason==dll_process_attach
push hinst
pop hinstance
.endif
mov eax,true
ret
dllentry endp
mouseproc proc ncode:dword,wparam:dword,lparam:dword
invoke callnexthookex,hhook,ncode,wparam,lparam
mov edx,lparam
assume edx:ptr mousehookstruct
invoke windowfrompoint,[edx].pt.x,[edx].pt.y
invoke postmessage,hwnd,wm_mousehook,eax,0
assume edx:nothing
xor eax,eax
ret
mouseproc endp
installhook proc hwnd:dword
push hwnd
pop hwnd
invoke setwindowshookex,wh_mouse,addr mouseproc,hinstance,null
mov hhook,eax
ret
installhook endp
uninstallhook proc
invoke unhookwindowshookex,hhook
ret
uninstallhook endp
end dllentry
;---------------------------------------------- dll的makefile文件 ----------------------------------------------
name=mousehook
$(name).dll: $(name).obj
link /section:.bss,s /dll /def:$(name).def /subsystem:windows /libpath:c:/masm/lib $(name).obj
$(name).obj: $(name).asm
ml /c /coff /cp $(name).asm
分析:
该应用程序的主窗口中包括三个编辑控件,它们将分别显示当前鼠标光标所在位置的窗口类名、窗口句柄和窗口过程的地址。还有两个按钮:“hook”和“eixt”。当您按下hook时,应用程序将钩挂鼠标输入的事件消息,该按钮的文本将变成“unhook”。当您把鼠标关标滑过一个窗口时,该窗口的有关消息将显示在主窗口中。当您按下“unhook”时,应用程序将卸载钩子。 主窗口使用一个对话框来作为它的主窗口。它自定义了一个消息wm_mousehook,用来在主窗口和dll之间传递消息。当主窗口接收到该消息时,wparam中包含了光标所在位置的窗口的句柄。当然这是我们做的安排。我这么做只是为了方便。您可以使用您自己的方法在主应用程序和dll之间进行通讯。
.if hookflag==false
invoke installhook,hdlg
.if eax!=null
mov hookflag,true
invoke setdlgitemtext,hdlg,idc_hook,addr unhooktext
.endif
该应用程序有一个全局变量,hookflag,它用来监视钩子的状态。如果安装来钩子它就是true,否则是false。 当用户按下hook按钮时,应用程序检查钩子是否已经安装。如果还没有的话,它将调用dll中引出的函数installhook来安装它。注意我们把主对话框的句柄传递给了dll,这样这个钩子dll就可以把wm_mousehook消息传递给正确的窗口了。当应用程序加载时,钩子dll也同时加载。时机上当主程序一旦加载到内存中后,dll就立即加载。dll的入口点函数载主程序的第一条语句执行前就前执行了。所以当主程序执行时,dll已经初始化好了。我们载入口点处放入如下代码:
.if reason==dll_process_attach
push hinst
pop hinstance
.endif
该段代码把dll自己的实例句柄放到一个全局变量中保存。由于入口点函数是在所有函数调用前被执行的,所以hinstance总是有效的。我们把该变量放到.data中,使得每一个进程都有自己一个该变量的值。因为当鼠标光标停在一个窗口上时,钩子dll被映射进进程的地址空间。加入在dll缺省加载的地址处已经加载其它的dll,那钩子dll将要被映射到其他的地址。hinstance将被更新成其它的值。当用户按下unhook再按下hook时,setwindowshookex将被再次调用。这一次,它将把新的地址作为实例句柄。而在例子中这是错误的,dll装载的地址并没有变。这个钩子将变成一个局部的,您只能钩挂发生在您窗口中的鼠标事件,这是很难让人满意的 。
installhook proc hwnd:dword
push hwnd
pop hwnd
invoke setwindowshookex,wh_mouse,addr mouseproc,hinstance,null
mov hhook,eax
ret
installhook endp
installhook 函数非常简单。它把传递过来的窗口句柄保存在hwnd中以备后用。接着调用setwindowshookex函数来安装一个鼠标钩子。该函数的返回值放在全局变量hhook中,将来在unhookwindowshookex中还要使用。在调用setwindowshookex后,鼠标钩子就开始工作了。无论什么时候发生了鼠标事件,mouseproc函数都将被调用:
mouseproc proc ncode:dword,wparam:dword,lparam:dword
invoke callnexthookex,hhook,ncode,wparam,lparam
mov edx,lparam
assume edx:ptr mousehookstruct
invoke windowfrompoint,[edx].pt.x,[edx].pt.y
invoke postmessage,hwnd,wm_mousehook,eax,0
assume edx:nothing
xor eax,eax
ret
mouseproc endp
钩子函数首先调用callnexthookex函数让其它的钩子处理该鼠标事件。然后,调用windowfrompoint函数来得到给定屏幕坐标位置处的窗口句柄。注意:我们用lparam指向的mousehookstruct型结构体变量中的point成员变量作为当前的鼠标位置。在我们调用postmessage函数把wm_mousehook消息发送到主程序。您必须记住的一件事是:在钩子函数中不要使用sendmessage函数,它会引起死锁。mousehookstruct的定义如下:
mousehookstruct struct dword
pt point <>
hwnd dword ?
whittestcode dword ?
dwextrainfo dword ?
mousehookstruct ends
pt 是当前鼠标所在的屏幕位置。
hwnd 是将接收鼠标消息的窗口的句柄。通常它是鼠标所在处的窗口,但是如果窗口调用了setcapture,鼠标的输入将到向到这个窗口。因我们不用该成员变量而是用windowfrompoint函数。
whittestcode 指定hit-test值,该值给出了更多的鼠标位置值。它指定了鼠标在窗口的那个部位。该值的完全列表,请参考win32 api 指南中的wm_nchittest消息。
dwextrainfo 该值包含了相关的信息。一般该值由mouse_event函数设定,可以调用getmessageextrainfo来获得。
当主窗口接收到wm_mousehook 消息时,它用wparam参数中的窗口句柄来查询窗口的消息。
.elseif umsg==wm_mousehook
invoke getdlgitemtext,hdlg,idc_handle,addr buffer1,128
invoke wsprintf,addr buffer,addr template,wparam
invoke lstrcmpi,addr buffer,addr buffer1
.if eax!=0
invoke setdlgitemtext,hdlg,idc_handle,addr buffer
.endif
invoke getdlgitemtext,hdlg,idc_classname,addr buffer1,128
invoke getclassname,wparam,addr buffer,128
invoke lstrcmpi,addr buffer,addr buffer1
.if eax!=0
invoke setdlgitemtext,hdlg,idc_classname,addr buffer
.endif
invoke getdlgitemtext,hdlg,idc_wndproc,addr buffer1,128
invoke getclasslong,wparam,gcl_wndproc
invoke wsprintf,addr buffer,addr template,eax
invoke lstrcmpi,addr buffer,addr buffer1
.if eax!=0
invoke setdlgitemtext,hdlg,idc_wndproc,addr buffer
.endif
为了避免重绘文本时的抖动,我们把已经在编辑空间中线时的文本和我们将要显示的对比。如果相同,就可以忽略掉。得到类名调用getclassname,得到窗口过程调用getclasslong并传入gcl_wndproc标志,然后把它们格式化成文本串并放到相关的编辑空间中去。
invoke uninstallhook
invoke setdlgitemtext,hdlg,idc_hook,addr hooktext
mov hookflag,false
invoke setdlgitemtext,hdlg,idc_classname,null
invoke setdlgitemtext,hdlg,idc_handle,null
invoke setdlgitemtext,hdlg,idc_wndproc,null
当用户按下unhook后,主程序调用dll中的uninstallhook函数。该函数调用unhookwindowshookex函数。然后,它把按钮的文本换回“hook”,hookflag的值设成false再清除掉编辑控件中的文本。
链接器的开关选项如下:
link /section:.bss,s /dll /def:$(name).def /subsystem:windows
它指定.bss段作为一个共享段以便所有映射该dll的进程共享未初始化的数据段。如果不用该开关,您dll中的钩子就不能正常工作了。
如果要用全局钩子,一定要放在dll中的,不然其他进程的消息就不能得到了,但是易语言目前还不能做dll,还是用其他语言(比如汇编,vb,vc,delphi等)做个dll,就可以了,最好还是用自己做的dll,其他人做的dll并不一定适合的。