财务开发必备ABAP语法之 DO VARYING

最新推荐文章于 2022-11-01 16:20:28 发布

SAP菜鸟家园

最新推荐文章于 2022-11-01 16:20:28 发布

阅读量2.8k

点赞数 3

文章标签：编程语言 javascript 微软 js sql

本文链接：https://blog.csdn.net/yannickdann/article/details/115396015

版权

最近有小伙伴在SAP菜鸟之家交流群里提问如下问题，如何将左侧的数据转换成右侧结构内表样式？

我们SAP菜鸟之家的member提出了loop里面套do varyiing的用法就可以。

下面我们来看看如何实现。

*&---------------------------------------------------------------------*
*& Report ZDO_VARYING3
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ZDO_VARYING3.
TYPES: BEGIN OF ty_data,
         matnr TYPE matnr,
         charg TYPE charg_d,
         amatr TYPE matnr,             " A
         achrg TYPE charg_d,
         bmatr TYPE matnr,             " B
         bchrg TYPE charg_d,
         cmatr TYPE matnr,             " C
         cchrg TYPE charg_d,
       END OF ty_data.


TYPES: BEGIN OF ty_tran,
         matnr TYPE matnr,
         charg TYPE charg_d,
         matn2 TYPE matnr,
         chrg2 TYPE charg_d,
       END OF ty_tran.


DATA: lt_data TYPE TABLE OF ty_data,
      ls_data TYPE ty_data.


DATA: lt_tran TYPE TABLE OF ty_tran,
      ls_tran TYPE ty_tran.


DATA: lv_matnr TYPE matnr,
      lv_charg TYPE charg_d.


* 初始化数据
ls_data-matnr = '物料'.
ls_data-charg = '批次'.
ls_data-amatr = '物料-A'.
ls_data-achrg = '批次-A'.
ls_data-bmatr = '物料-B'.
ls_data-bchrg = '批次-B'.
ls_data-cmatr = '物料-C'.
ls_data-cchrg = '批次-C'.
APPEND ls_data TO lt_data.


ls_data-matnr = '物料1'.
ls_data-charg = '批次1'.
ls_data-amatr = '物料1-A'.
ls_data-achrg = '批次1-A'.
ls_data-bmatr = '物料1-B'.
ls_data-bchrg = '批次1-B'.
ls_data-cmatr = '物料1-C'.
ls_data-cchrg = '批次1-C'.
APPEND ls_data TO lt_data.


* 转换
LOOP AT lt_data INTO ls_data.
  DO 3 TIMES VARYING lv_matnr FROM ls_data-amatr
                              NEXT ls_data-bmatr
             VARYING lv_charg FROM ls_data-achrg
                              NEXT ls_data-bchrg.
    ls_tran-matnr = ls_data-matnr.
    ls_tran-charg = ls_data-charg.
    ls_tran-matn2 = lv_matnr.
    ls_tran-chrg2 = lv_charg.
    APPEND ls_tran TO lt_tran.
  ENDDO.
ENDLOOP.


* 输出
DATA: i_table      TYPE REF TO cl_salv_table.
DATA: lr_columns   TYPE REF TO cl_salv_columns_table.
DATA: lr_functions TYPE REF TO cl_salv_functions.


TRY.
    cl_salv_table=>factory(
      IMPORTING
        r_salv_table = i_table
      CHANGING
        t_table      = lt_tran ).
  CATCH cx_salv_msg.
ENDTRY.


" 功能按钮
lr_functions = i_table->get_functions( ).
lr_functions->set_all( abap_true ).


" 列自适应
lr_columns = i_table->get_columns( ).
lr_columns->set_optimize( 'X').


" alv输出
i_table->display( ).

运行结果如下：

Do varying的处理逻辑是根据from和next后面的字段间距、相同字段类型及长度确定的。

Do varying除了在上述情况下使用，还经常在财务报表开发时累加名称类似的变量，这些变量名是有序的，即存在数字规律，比如HSL01,HSL02,HSL03或WORD01,WORD02等等的情况，DO-VARYING语法可以很好的对数据进行累加。

例如：需要将FAGLFLEXT表中的hsl01，hsl02…hsl16累加，对应财务1-16账期每月发生额。

当然，除了使用do varying累加外，上述情景也可以使用ADD THEN UNTIL语法来实现累加。

上图Add 语法介绍：

添加字段顺序并将结果赋给另一个字段。

语法解释：

语法一：ADD<n1> THEN <n2>UNTIL<nz> GIVING<m>.

如果<n1>、<n2>、 ... 、 <nz> 是在内存中相同类型和长度的等距字段序列，则进行求和计算并将结果赋给<m>。

ADD除了上述语法，还有另一个语法。

语法二：ADD <n1>THEN<n2> UNTIL<nz> TO<m>.

添加字段顺序并将结果添加到另一个字段的内容中。

该语句除了将字段总和添加到<m> 的旧内容中之外，与上面语句的工作方式相同。

今天的经验分享就到这里拉，小伙伴们学会了吗？赶快打开SAP试试看吧。觉得有用的小伙伴，还请多转发留言鼓励小菜哦。

-END-

更多经验请关注公众号“菜鸟之家”，每周分享顾问经验，绝对干货满满！

长按二维码关注我们，收获更多干货满满的SAP教学。

小手点一点关注，顾问路上不迷路！

图文来源：Goldan、Lisa、天街小雨

图文编辑：Yannick

精选知识

SAP菜鸟家园

关注

3
点赞
踩
13

收藏

觉得还不错? 一键收藏
1
评论
财务开发必备ABAP语法之 DO VARYING

最近有小伙伴在SAP菜鸟之家交流群里提问如下问题，如何将左侧的数据转换成右侧结构内表样式？我们SAP菜鸟之家的member提出了loop里面套do varyiing的用法就可以。下面我们来...
复制链接

扫一扫