第七章 Caché 持久性对象介绍

最新推荐文章于 2025-04-25 15:14:51 发布
最新推荐文章于 2025-04-25 15:14:51 发布
阅读量1.3k 收藏 1
点赞数 3
分类专栏： Caché 从入门到精通
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/yaoxin521123/article/details/104960396
版权

文章目录

第七章 Caché 持久性对象介绍

持久化类

持久类是继承自%persistent的任何类。持久对象就是这样一个类的实例。

%Persistent类是%RegisteredObject的子类，因此是一个对象类。除了提供前一章中描述的方法之外，%Persistent类还定义了持久性接口和一组方法。除其他外，这些方法能够将对象保存到数据库、从数据库加载对象、删除对象和测试是否存在。

介绍默认的SQL映射

对于任何持久性类，编译器都会生成一个SQL表定义，以便除了通过本书中描述的对象接口之外，还可以通过SQL访问存储的数据。

该表包含每个保存对象的每一条记录，可以通过 Caché SQL查询该表。下面显示了示例的查询结果。Sample.Person 表:

下表总结了默认的映射:

Object-SQL映射

From (Object Concept) …To (Relational Concept) …
PackageSchema
ClassTable
OIDIdentity field
Data type propertyField
Reference propertyReference field
Embedded objectSet of fields
List propertyList field
Array propertyChild table
Stream propertyBLOB
IndexIndex
Class methodStored procedure

保存对象标识符:ID和OID

当第一次保存一个对象时，Caché会为它创建两个永久标识符，可以使用其中一个来访问或删除保存的对象。更常用的标识符是对象ID。ID是表中惟一的值。默认情况下，Caché生成一个整数作为ID。

OID更加通用:它还包含类名，并且在数据库中是惟一的。在一般实践中，应用程序永远不需要使用OID值;ID值通常就足够了。

%Persistent类提供使用ID或OID的方法。在使用%OpenId()、%ExistsId()和%DeleteId()等方法时指定ID。将OID指定为方法的参数，如%Open()、%Exists()和%Delete()。也就是说，使用ID作为参数的方法在它们的名称中包含ID。使用OID作为参数的方法的名称中不包含Id;这些方法的使用频率要低得多。

当持久对象存储在数据库中时，其任何引用属性(即对其他持久对象的引用)的值都存储为OID值。对于没有oid的对象属性，对象的文字值与对象的其他状态一起存储。

对象ID映射到SQL

对象的ID在对应的SQL表中可用。如果，Caché 使用字段名ID。如果不确定要使用哪个字段名，Caché 还提供了访问ID的方法。系统如下:

  • 对象ID不是对象的属性，与属性不同。
  • 如果类不包含名为ID的属性，那么表也包含字段ID，而该字段包含对象ID。
  • 如果类包含一个属性，这个属性用名称ID(在任何情况下都是变体)映射到SQL，那么表也包含字段ID1，这个字段包含对象ID的值。

类似地，如果类包含映射为ID和ID1的属性，那么表也包含ID2字段，该字段包含对象ID的值。

  • 在所有情况下，表还提供了伪字段%ID，其中保存了对象ID的值。

OID在SQL表中不可用。

SQL中的对象ID

Caché 强制ID字段的唯一性(无论它的实际名称是什么)。Caché也防止更改此字段。这意味着不能在该字段上执行SQL更新或插入操作。

例如，下面显示了向表添加新记录所需的SQL:

INSERT INTO PERSON (FNAME, LNAME)VALUES (:fname, :lname)

注意，此SQL不引用ID字段。Caché 为ID字段生成一个值，并在创建请求的记录时插入该值。

特定于持久类的类成员

Caché 类可以包含几种只有在持久类中才有意义的类成员。存储过程、索引、外键和触发器。 storage definitions, indices, foreign keys, and triggers.

存储定义

在大多数情况下(如后面讨论的)，每个持久类都有一个存储定义。存储定义的目的是描述Caché在为类保存数据或为类读取保存的数据时使用的全局结构。在以编辑模式查看类时，Studio将在类定义的末尾显示存储定义。以下是部分例子:

<Storage name="Default">
<Data name="PersonDefaultData">
<Value name="1">
<Value>%%CLASSNAME</Value>
</Value>
<Value name="2">
<Value>Name</Value>
</Value>
<Value name="3">
<Value>SSN</Value>
</Value>
<Value name="4">
<Value>DOB</Value>
</Value>
<Value name="5">
<Value>Home</Value>
</Value>
<Value name="6">
<Value>Office</Value>
</Value>
<Value name="7">
<Value>Spouse</Value>
</Value>
<Value name="8">
<Value>FavoriteColors</Value>
</Value>
</Data>
<DataLocation>^Sample.PersonD</DataLocation>
<DefaultData>PersonDefaultData</DefaultData>
<ExtentSize>200</ExtentSize>
<IdLocation>^Sample.PersonD</IdLocation>
<IndexLocation>^Sample.PersonI</IndexLocation>
<Property name="%%CLASSNAME">
<Selectivity>50.0000%</Selectivity>
</Property>
...

在大多数情况下，编译器也会生成和更新存储定义。

索引

与其他SQL表一样，Caché SQL表可以有索引;要定义这些，需要将索引定义添加到相应的类定义中。

索引可以添加约束，以确保给定字段或字段组合的唯一性。

索引的另一个用途是定义与类关联的常用请求数据的特定排序子集，以便查询可以更快地运行。例如，作为一般规则，如果一个查询包含使用给定字段的WHERE子句，那么如果该字段被索引，则查询运行得更快。相反，如果该字段上没有索引，则引擎必须执行一个完整的表扫描，检查每一行，以查看它是否符合给定的条件——如果表很大，这是一个耗时的操作。

外键

Caché SQL表也可以有外键。要定义这些，需要将外键定义添加到相应的类定义中。

外键在表之间建立引用完整性约束，Caché在添加新数据或更改数据时使用这些约束。如果使用的是关系，那么Caché将自动将这些关系视为外键。但是，如果不想使用关系或者有其他原因需要添加他们，则可以添加外键。

触发器

Caché SQL表也可以有触发器。要定义这些，需要将触发器定义添加到相应的类定义中。

触发器定义在特定事件发生时自动执行的代码，特别是在插入、修改或删除记录时。

其他类成员

可以定义类方法或类查询，以便将其作为存储过程调用，能够从SQL调用它。
对于本章没有讨论的类成员，SQL没有对应映射。也就是说，Caché 不提供直接的方式使用它们 从SQL或使它们从SQL可用的直接方法。

术语继承是指磁盘上给定持久类的所有记录。如下一章所示，%Persistent类提供了几个对类继承进行操作的方法。

  • 如果持久类Person拥有子类Employee，则Person继承包括Person的所有实例和Employee的所有实例。
  • 对于类Employee的任何给定实例，该实例都包含在Person继承和Employee继承中。

索引自动跨越其定义的类的整个范围。Person中定义的索引同时包含Person实例和Employee实例。在Employee继承中定义的索引只包含Employee实例。

子类可以定义父类中未定义的其他属性。这些在子类范围内可用，但在父类范围内不可用。例如，Employee继承可能包括Department字段，而人员继承不包括该字段。

前面几点意味着在Caché中编写一个查询来检索相同类型的所有记录相对容易。例如，如果希望统计所有类型的人员，可以对Person表运行查询。如果只想计算雇员数量，请对Employee 表运行相同的查询。与其他对象数据库相反，为了统计所有类型的人员，需要编写一个更复杂的组合表的查询，并且需要在添加另一个子类时更新这个查询。

类似地，使用ID的方法都具有多态性。也就是说，它们可以根据传递的ID值对不同类型的对象进行操作。

例如，Sample.Person对象包括Sample.Person实例和Sample.Employee 实例。当调用 Sample.Person类的%OpenId()时，得到的OREF是Sample.Person或Sample.Employee实例,取决于是存储在数据库的是什么:

/// d ##class(PHA.OP.MOB.Test).TestObjectID()
ClassMethod TestObjectID()
{
	 Set obj = ##class(Sample.Person).%OpenId(1)
	 Write $ClassName(obj),!  
	 Set obj = ##class(Sample.Person).%OpenId(2)
	 Write $ClassName(obj),!
}

DHC-APP>d ##class(PHA.OP.MOB.Test).TestObjectID()
Sample.Person
Sample.Employee

注意示例的%OpenId()方法。如果尝试打开ID 1, Sample.Employee 类将不会返回对象，因为ID 1不是Sample.Employee的继承:

ClassMethod TestIsObject()
{
	Set obj = ##class(Sample.Employee).%OpenId(1)
	Write $IsObject(obj),! 
	Set obj = ##class(Sample.Employee).%OpenId(2)
	Write $IsObject(obj),!
}



DHC-APP>d ##class(PHA.OP.MOB.Test).TestIsObject()
0
1

继承管理

对于使用默认存储类(%Library.CacheStorage)的类，Caché维护继承定义和那些继承注册到其继承管理器中使用的全局变量。到继承管理器的接口是通%ExtentMgr.Util实现的。这个注册过程发生在类编译期间。如果存在任何错误或名称冲突，则会导致编译失败。若要编译成功，解决冲突;这通常涉及更改索引的名称或添加数据的显式存储位置。

MANAGEDEXTENT类参数的默认值为1;此值将导致全局名称注册和冲突使用检查。值0指定既不进行注册也不进行冲突检查。

注意：如果一个应用程序有多个类有意共享一个全局引用，那么对于所有相关的类指定MANAGEDEXTENT类参数的默认值为1为0(如果它们使用默认存储)。否则，重新编译将生成以下错误

ERROR #5564: Storage reference: '^This.App.Global used in 'User.ClassA.cls' 
is already registered for use by 'User.ClassB.cls'

要删除继承元数据，有多种方法:

  • 使用 ##class(%ExtentMgr.Util).DeleteExtentDefinition(extent,extenttype)
  1. extent 通常是类名
  2. extenttype 是继承类型
  3. 对于类，这是cls，它也是这个参数的默认值
  • 使用以下调用之一:
  1. $SYSTEM.OBJ.Delete(classname,flags) classname是要删除的类，flags 包含e
  2. $SYSTEM.OBJ.DeletePackage(packagename,flags) packagename 是要删除的包 ，flags 包含e
  3. $SYSTEM.OBJ.DeleteAll(flags) flags 包含e

继承查询

每个持久化类都会自动包含一个类查询。称为“范围”，它提供范围中的所有id的集合。称为“继承”，它提供继承中所有id的集合。

有关使用类查询的一般信息，下面的示例使用一个类查询来显示示例的所有id。Sample.Person :

/// d ##class(PHA.OP.MOB.Test).TestExtentQueries()
ClassMethod TestExtentQueries()
{
	set query = ##class(%SQL.Statement).%New()
	set status= query.%PrepareClassQuery("Sample.Person","Extent")
	if 'status {
		do $system.OBJ.DisplayError(status)
	}
	set rset=query.%Execute()

	While (rset.%Next()) {
		Write rset.%Get("ID"),!
	}
}


DHC-APP> d ##class(PHA.OP.MOB.Test).TestExtentQueries()
1
2

Sample.Person 拓展包含 Sample.Person 的实例和它的子类

“extent”查询相当于以下SQL查询:

SELECT %ID FROM Sample.Person

注意，不能依赖的顺序，其中的ID值返回使用这些方法之一:Caché 可以确定使用其他属性值排序的索引来满足此请求的效率更高。如果需要，可以将ORDER BY %ID子句添加到SQL查询中。

INSERT INTO Sample.Person (Age,SSN,Name) VALUES (1,"3N1","yaoxin")
INSERT INTO Sample.Employee (Age,SSN,Name,Title,Salary) VALUES (30,"111-11-1111","xiaoli","test",2000)

附录

Sample.Person

/// This sample persistent class represents a person.
/// <p>Maintenance note: This class is used by some of the bindings samples.
Class Sample.Person Extends (%Persistent, %Populate, %XML.Adaptor)
{

Parameter EXTENTQUERYSPEC = "Name,SSN,Home.City,Home.State";

// define indices for this class

/// Define a unique index for <property>SSN</property>.
Index SSNKey On SSN [ Type = index, Unique ];

/// Define an index for <property>Name</property>.
Index NameIDX On Name [ Data = Name ];

/// Define an index for embedded object property <b>ZipCode</b>.
Index ZipCode On Home.Zip [ Type = bitmap ];

// define properties for this class

/// Person's name.
Property Name As %String(POPSPEC = "Name()") [ Required ];

/// Person's Social Security number. This is validated using pattern match.
Property SSN As %String(PATTERN = "3N1""-""2N1""-""4N") [ Required ];

/// Person's Date of Birth.
Property DOB As %Date(POPSPEC = "Date()");

/// Person's home address. This uses an embedded object.
Property Home As Address;

/// Person's office address. This uses an embedded object.
Property Office As Address;

/// Person's spouse. This is a reference to another persistent object.
Property Spouse As Person;

/// A collection of strings representing the person's favorite colors.
Property FavoriteColors As list Of %String(JAVATYPE = "java.util.List", POPSPEC = "ValueList("",Red,Orange,Yellow,Green,Blue,Purple,Black,White""):2");

/// Person's age.<br>
/// This is a calculated field whose value is derived from <property>DOB</property>.
Property Age As %Integer [ Calculated, SqlComputeCode = { Set {Age}=##class(Sample.Person).CurrentAge({DOB})
}, SqlComputed, SqlComputeOnChange = DOB ];

/// This class method calculates a current age given a date of birth <var>date</var>.
ClassMethod CurrentAge(date As %Date = "") As %Integer [ CodeMode = expression ]
{
$Select(date="":"",1:($ZD($H,8)-$ZD(date,8)\10000))
}

/// Prints the property <property>Name</property> to the console.
Method PrintPerson()
{
	Write !, "Name: ", ..Name
	Quit
}

/// A simple, sample method: add two numbers (<var>x</var> and <var>y</var>) 
/// and return the result.
Method Addition(x As %Integer = 1, y As %Integer = 1) As %Integer
{
	Quit x + y // comment
}

/// A simple, sample expression method: returns the value 99.
Method NinetyNine() As %Integer [ CodeMode = expression ]
{
99
}

/// Invoke the <method>PrintPerson</method> on all <class>Person</class> objects 
/// within the database.
ClassMethod PrintPersons()
{
	// use the extent result set to find all person
	Set extent = ##class(%ResultSet).%New("Sample.Person:Extent")
	Do extent.Execute()
	
	While (extent.Next()) {
		Set person = ..%OpenId(extent.GetData(1))
		Do person.PrintPerson()
	}
	
	Quit
}

/// Prints out data on all persons within the database using SQL to 
/// iterate over all the person data.
ClassMethod PrintPersonsSQL()
{
	// use dynamic SQL result set to find person data
	Set query = ##class(%ResultSet).%New("%DynamicQuery:SQL")
	Do query.Prepare("SELECT ID, Name, SSN FROM Sample.Person ORDER BY Name")
	Do query.Execute()
	
	While (query.Next()) {
		Write !,"Name: ", query.Get("Name"), ?30, query.Get("SSN")
	}
	
	Quit
}

/// This is a sample of how to define an SQL stored procedure using a 
/// class method. This method can be called as a stored procedure via 
/// ODBC or JDBC.<br>
/// In this case this method returns the concatenation of a string value.
ClassMethod StoredProcTest(name As %String, ByRef response As %String) As %Integer [ SqlName = Stored_Procedure_Test, SqlProc ]
{
	// Set response to the concatenation of name.
	Set response = name _ "||" _ name
	QUIT 29
}

/// This is a sample of how to define an SQL stored procedure using a 
/// class method. This method can be called as a stored procedure via 
/// ODBC or JDBC.<br>
/// This method performs an SQL update operation on the database 
/// using embedded SQL. The update modifies the embedded properties 
/// <var>Home.City</var> and <var>Home.State</var> for all rows whose 
/// <var>Home.Zip</var> is equal to <var>zip</var>.
ClassMethod UpdateProcTest(zip As %String, city As %String, state As %String) As %Integer [ SqlProc ]
{
	New %ROWCOUNT,%ROWID
	
	&sql(UPDATE Sample.Person 
	SET Home_City = :city, Home_State = :state 
	WHERE Home_Zip = :zip)
	
	// Return context information to client via %SQLProcContext object
	If ($g(%sqlcontext)'=$$$NULLOREF) { 
		Set %sqlcontext.SQLCode = SQLCODE
		Set %sqlcontext.RowCount = %ROWCOUNT
	}
	QUIT 1
}

/// A sample class query that defines a result set that returns Person data 
/// ordered by <property>Name</property>.<br>
/// This query can be used within another Cach&eacute; method (using the
/// <class>%ResultSet</class> class), from Java, or from ActiveX.<br>
/// This query is also accessible from ODBC and/or JDBC as the SQL stored procedure 
/// <b>SP_Sample_By_Name</b>.
Query ByName(name As %String = "") As %SQLQuery(CONTAINID = 1, SELECTMODE = "RUNTIME") [ SqlName = SP_Sample_By_Name, SqlProc ]
{
SELECT ID, Name, DOB, SSN
FROM Sample.Person
WHERE (Name %STARTSWITH :name)
ORDER BY Name
}

Storage Default
{
<Data name="PersonDefaultData">
<Value name="1">
<Value>%%CLASSNAME</Value>
</Value>
<Value name="2">
<Value>Name</Value>
</Value>
<Value name="3">
<Value>SSN</Value>
</Value>
<Value name="4">
<Value>DOB</Value>
</Value>
<Value name="5">
<Value>Home</Value>
</Value>
<Value name="6">
<Value>Office</Value>
</Value>
<Value name="7">
<Value>Spouse</Value>
</Value>
<Value name="8">
<Value>FavoriteColors</Value>
</Value>
</Data>
<DataLocation>^Sample.PersonD</DataLocation>
<DefaultData>PersonDefaultData</DefaultData>
<ExtentSize>200</ExtentSize>
<IdLocation>^Sample.PersonD</IdLocation>
<IndexLocation>^Sample.PersonI</IndexLocation>
<Property name="%%CLASSNAME">
<AverageFieldSize>8.5</AverageFieldSize>
<Selectivity>50.0000%</Selectivity>
</Property>
<Property name="%%ID">
<AverageFieldSize>2.46</AverageFieldSize>
<Selectivity>1</Selectivity>
</Property>
<Property name="Age">
<AverageFieldSize>1.88</AverageFieldSize>
<Selectivity>1.1765%</Selectivity>
</Property>
<Property name="DOB">
<AverageFieldSize>5</AverageFieldSize>
<Selectivity>0.5000%</Selectivity>
</Property>
<Property name="FavoriteColors">
<AverageFieldSize>6.71</AverageFieldSize>
<OutlierSelectivity>.34:</OutlierSelectivity>
<Selectivity>1.4043%</Selectivity>
</Property>
<Property name="Home">
<AverageFieldSize>36.23,City:7.27,State:2,Street:16.58,Zip:5</AverageFieldSize>
<Selectivity>0.5000%,City:3.8462%,State:2.0408%,Street:0.5000%,Zip:0.5000%</Selectivity>
</Property>
<Property name="Name">
<AverageFieldSize>15.83</AverageFieldSize>
<Selectivity>0.5000%</Selectivity>
</Property>
<Property name="Office">
<AverageFieldSize>36.43,City:7.15,State:2,Street:16.91,Zip:5</AverageFieldSize>
<Selectivity>0.5000%,City:3.8462%,State:2.0408%,Street:0.5000%,Zip:0.5000%</Selectivity>
</Property>
<Property name="SSN">
<AverageFieldSize>11</AverageFieldSize>
<Selectivity>1</Selectivity>
</Property>
<Property name="Spouse">
<AverageFieldSize>.95</AverageFieldSize>
<OutlierSelectivity>.5:</OutlierSelectivity>
<Selectivity>0.7937%</Selectivity>
</Property>
<SQLMap name="$Person">
<BlockCount>-4</BlockCount>
</SQLMap>
<SQLMap name="IDKEY">
<BlockCount>-20</BlockCount>
</SQLMap>
<SQLMap name="NameIDX">
<BlockCount>-8</BlockCount>
</SQLMap>
<SQLMap name="SSNKey">
<BlockCount>-8</BlockCount>
</SQLMap>
<SQLMap name="ZipCode">
<BlockCount>-8</BlockCount>
</SQLMap>
<StreamLocation>^Sample.PersonS</StreamLocation>
<Type>%Library.CacheStorage</Type>
}

}

Sample.Employee

/// This sample persistent class represents an employee.<br>
Class Sample.Employee Extends Person
{

/// The employee's job title.
Property Title As %String(MAXLEN = 50, POPSPEC = "Title()");

/// The employee's current salary.
Property Salary As %Integer(MAXVAL = 100000, MINVAL = 0);

/// A character stream containing notes about this employee.
Property Notes As %Stream.GlobalCharacter;

/// A picture of the employee
Property Picture As %Stream.GlobalBinary;

/// The company this employee works for.
Relationship Company As Company [ Cardinality = one, Inverse = Employees ];

/// This method overrides the method in <class>Person</class>.<br>
/// Prints the properties <property>Name</property> and <property>Title</property> 
/// to the console.
Method PrintPerson()
{
	Write !,"Name: ", ..Name, ?30, "Title: ", ..Title
	Quit
}

/// writes a .png file containing the picture, if any, of this employee
/// the purpose of this method is to prove that Picture really contains an image
Method WritePicture()
{
	if (..Picture="") {quit}
	set name=$TR(..Name,".") ; strip off trailing period
	set name=$TR(name,", ","__") ; replace commas and spaces
	set filename=name_".png"
	
	set file=##class(%Stream.FileBinary).%New()
	set file.Filename=filename
	do file.CopyFrom(..Picture)
	do file.%Save()
	write !, "Generated file: "_filename
}

Storage Default
{
<Data name="EmployeeDefaultData">
<Subscript>"Employee"</Subscript>
<Value name="1">
<Value>Company</Value>
</Value>
<Value name="2">
<Value>Notes</Value>
</Value>
<Value name="3">
<Value>Salary</Value>
</Value>
<Value name="4">
<Value>Title</Value>
</Value>
<Value name="5">
<Value>Picture</Value>
</Value>
</Data>
<DefaultData>EmployeeDefaultData</DefaultData>
<ExtentSize>100</ExtentSize>
<Property name="%%CLASSNAME">
<AverageFieldSize>17</AverageFieldSize>
<Selectivity>100.0000%</Selectivity>
</Property>
<Property name="%%ID">
<AverageFieldSize>3</AverageFieldSize>
<Selectivity>1</Selectivity>
</Property>
<Property name="Age">
<AverageFieldSize>1.85</AverageFieldSize>
<Selectivity>1.5873%</Selectivity>
</Property>
<Property name="Company">
<AverageFieldSize>1.45</AverageFieldSize>
<Selectivity>5.0000%</Selectivity>
</Property>
<Property name="DOB">
<AverageFieldSize>5</AverageFieldSize>
<Selectivity>1.0000%</Selectivity>
</Property>
<Property name="FavoriteColors">
<AverageFieldSize>5.81</AverageFieldSize>
<OutlierSelectivity>.39:</OutlierSelectivity>
<Selectivity>2.2593%</Selectivity>
</Property>
<Property name="Home">
<AverageFieldSize>36.56,City:7.66,State:2,Street:16.5,Zip:5</AverageFieldSize>
<Selectivity>1.0000%,City:3.8462%,State:2.4390%,Street:1.0000%,Zip:1.0000%</Selectivity>
</Property>
<Property name="Name">
<AverageFieldSize>15.92</AverageFieldSize>
<Selectivity>1.0000%</Selectivity>
</Property>
<Property name="Notes">
<Selectivity>100.0000%</Selectivity>
</Property>
<Property name="Office">
<AverageFieldSize>36.83,City:7.22,State:2,Street:17.19,Zip:5</AverageFieldSize>
<Selectivity>1.0000%,City:4.0000%,State:2.1739%,Street:1.0000%,Zip:1.0000%</Selectivity>
</Property>
<Property name="Picture">
<Selectivity>100.0000%</Selectivity>
</Property>
<Property name="SSN">
<AverageFieldSize>11</AverageFieldSize>
<Selectivity>1</Selectivity>
</Property>
<Property name="Salary">
<AverageFieldSize>4.91</AverageFieldSize>
<Selectivity>1.0000%</Selectivity>
</Property>
<Property name="Spouse">
<AverageFieldSize>1.89</AverageFieldSize>
<Selectivity>1.5873%</Selectivity>
</Property>
<Property name="Title">
<AverageFieldSize>21.36</AverageFieldSize>
<Selectivity>1.5385%</Selectivity>
</Property>
<SQLMap name="$Employee">
<BlockCount>-4</BlockCount>
</SQLMap>
<Type>%Library.CacheStorage</Type>
}

}
深度学习实现工业零件的缺陷检测
qq_29462849的博客
09-12 5万+
介绍 工业零件在制造完成的时候，往往需要去检测其完整性和功能性。如下图所示，从左上到右下，分别是擦花、漏底、碰凹、凸粉。本篇博文主要讲解如何去识别这四类图像，所用框架为keras-2.1.6+tensorflow-1.7.0+GTX1060。 数据集 所获得的数据不是太多，一共250幅图像，其中擦花图像29幅、漏底图像140幅、碰凹图像20幅、凸粉图像61幅。可以发现，这样的数据对深度卷...
DeepSeek与PyTorch携手：开启工业缺陷检测新时代（4/18）
小相探索IT世界
02-14 2354
经过项目团队的努力，成功实现了手机主板表面缺陷检测系统的部署和应用。在实际运行中，系统的缺陷检测准确率达到了 96%，召回率达到了 92%，检测速度达到了每分钟处理 35 块主板，完全满足了项目的预期目标。通过该系统的应用，企业的次品率显著降低，从原来的 5% 降低到了 2% 以下，有效提高了产品质量和市场竞争力。人工成本也大幅减少，原本需要 10 名检测人员的工作，现在仅需 2 名技术人员进行设备维护和监控，为企业节省了大量的人力成本。在项目实施过程中，也积累了宝贵的经验教训。
改进yolov8缺陷检测+swin+transformer
QQ_1309399183的博客
11-08 673
改进yolov8缺陷检测+swin+transformer
工业外观缺陷检测 无监督异常检测模型FastFlow
m0_37302966的博客
04-16 539
工业外观缺陷检测 无监督异常检测模型FastFlow
毕业设计-基于卷积神经网络的金属焊缝缺陷识别方法 YOLO python 算法
2301_79555157的博客
12-24 951
毕业设计-基于卷积神经网络（CNN）的金属焊缝缺陷识别方法，旨在提升焊缝质量检测的自动化水平和准确性。首先，针对焊缝缺陷的特点，构建了适合于焊缝图像处理的深度学习模型，并通过大量焊缝图像数据进行训练。其次，优化了网络结构和超参数，以提升模型在各种焊缝缺陷（如气孔、裂纹、夹杂物等）识别中的表现。涵盖了深度学习、机器学习、算法、人工智能、大数据、信息安全、推荐系统、目标检测等多个热门领域。对于计算机专业、软件工程专业、人工智能专业、大数据专业的毕业生而言，毕业设计选题至关重要。
halcon 深度学习标注_深度学习工业应用: 缺陷检测
weixin_34847198的博客
01-06 1046
本文转自知乎，原文https://zhuanlan.zhihu.com/p/392509081. 应用背景 随着机器视觉，工业自动化的快速发展，工业4.0的概念已经被提上日程。传统很多需要人工来手动操作的工作，渐渐的被机器所替代。这当然也是人类科技进步和发展的必然趋势，工业的进步到头来还是服务于人类，给人类带来高质量的生活体验，而不是整天做着乏味无趣的工作。图一 自动化车间...
【大语言模型】大语言模型（LLMs）在工业缺陷检测领域的应用
最新发布
扶着老奶奶闯红灯
04-25 818
大语言模型（LLMs）在工业缺陷检测领域的应用场景正在快速扩展，结合其多模态理解、文本生成和逻辑推理能力，为传统检测方法提供了新的技术路径。
万字长文细说工业缺陷检测
极市平台的技术博客
07-23 3195
作者丨皮特潘 编辑丨极市平台 注意：本文从我的一个PPT整理而来，行文可能比较随意，很多细节没有写清楚，后续有时间会持续修改。 上次说到，要写一个系列，最后整理才发现，还是合成一篇比较好一点。 [皮特潘：AI 工业缺陷检测 —— 写在前面的话zhuanlan.zhihu.com(https://zhuanlan.zhihu.com/p/375383384) 主要内容还是围绕着场景分析与数据理解、方法论与算法设计、工具链与部署落地等方面进行展开。重点关注的还是顶层设计，因此涉及到的很多具体的细节没有说太多，仁
工业缺陷检测——Windows 10本地部署AnomalyGPT工业缺陷检测大模型
知来者逆的博客
09-27 4622
在缺陷检测中，由于真实世界样本中的缺陷数据极为稀少，有时在几千甚至几万个样品中才会出现一个缺陷数据。因此，以往的模型只需在正常样本上进行训练，学习正常样品的数据分布。在测试时，需要手动指定阈值来区分每种项目的正常和异常实例，然而这并不适用于实际的生产环境。大型视觉语言模型（LVLMs），诸如 MiniGPT - 4 和 LLaVA，已展现出强大的图像理解能力，在各类视觉任务中取得显著性能。那么，大模型能否应用于工业缺陷检测领域呢？AnomalyGPT 对此展开了深入探索。
《异常检测——从经典算法到深度学习》11 ADS —— 针对大量出现的KPI流快速部署异常检测模型
热门推荐
Smileyan's blog
03-13 1万+
《异常检测——从经典算法到深度学习》 0 概论 1 基于隔离森林的异常检测算法 2 基于LOF的异常检测算法 3 基于One-Class SVM的异常检测算法 4 基于高斯概率密度异常检测算法 5 Opprentice——异常检测经典算法最终篇 6 基于重构概率的 VAE 异常检测 7 基于条件VAE异常检测 8 Donut: 基于 VAE 的 Web 应用周期性 KPI 无监督异常检测 9 异常检测资料汇总（持续更新&抛砖引玉） 10 基于条件 VAE 的鲁棒无监督KPI异常检测 11 针对
深度学习工业缺陷检测异常检测常用模型
03-29
深度学习在工业缺陷检测和异常检测中已经取得了很大的成功。以下是一些常用的深度学习模型： 1. 卷积神经网络（Convolutional Neural Network，CNN）：CNN是一种广泛应用于图像处理任务的深度学习模型。它通过卷...
利用深度学习进行时序数据的异常检测
01-29
神经网络是一种模拟生物学神经的机器学习模型，数据来源于输入层并流经具有各种激活阈值的节点。 递归神经网络是一种在输入被理解之前保持其内部记忆的神经网络，所以它们可以进行数据流中时间依赖的结构的学习。 机器学习早已在许多产品中发挥过威力了，我们日常就与很多打过交道，从像苹果的Siri和谷歌的Now之类的“智能”助手，到像亚马逊建议买新产品的推荐引擎，再到谷歌和Facebook使用的排名系统，凡此种种，不一而足。最近，机器学习由于“深度
工业系统的故障检测与诊断.pdf
07-01
工业系统的故障检测与诊断中文版，主要讲解了多元统计的故障检测和诊断方法
深度学习实现零件缺陷检测源代码
09-12
结合VGG和残差网络实现工业零件的缺陷检测，基于keras和tensorflow可以直接运行使用
MemSeg-半监督工业图像表面缺陷检测方法
03-01
总结来说，MemSeg是一种结合了深度学习、半监督学习和异常检测的工业图像表面缺陷检测方案，通过PyTorch实现，旨在解决制造业中质量控制的关键问题。它提供了一种高效、经济的途径来检测和识别产品表面的缺陷，有助...
MATLAB算法实战应用案例精讲-图像处理缺陷检测-Defect Eye缺陷检测开源工具
12-13
3. 缺陷检测算法：常用的有模板匹配、机器学习（如支持向量机、随机森林等）和深度学习方法（如卷积神经网络）。这些算法通过训练模型，学习正常与异常状态的差异，以识别图像中的缺陷。 4. 后处理：在初步检测结果...
工业缺陷检测深度学习方法综述
2301_80355452的博客
09-16 1205
异常：点异常、 上下文异常和集群异常。点异常：又称为离群值 (outliers)[9], 描述数值上偏离正 常样本的独立数据。与异常相近的概念还包括新颖点(novelty)和分布外数据。上下文异常：同样描述数据点,其数值属于正常范围,但不符合局部上下文规律。集群异常：描述一系列相关数据的集合,集合中的每一个实例的数值在单独考察时都处于正常值域,但集 合整体的相关性特征不服从正常模式。一般的图像异常检测往往仅需区分正常与异常样本,而工业缺陷检测更关注于检测 图像中的异常像素.
文献阅读之《基于深度学习的表面缺陷检测方法综述》
weixin_53618407的博客
07-23 1342
近年来，基于深度学习的表面缺陷检测技术在各种工业场景中广泛应用。本文对近年来基于深度学习的表面缺陷检测方法进行了梳理，根据数据标签的不同将其分为全监督学习模型方法、无监督学习模型方法和其他方法三大类，并对各种典型方法进一步细分归类和对比分析，总结了每种方法的优缺点和应用场景。本文探讨了表面缺陷检测中三个关键问题，介绍了工业表面缺陷常用数据集。最后，对表面缺陷检测的未来发展趋势进行了展望。缺陷的定义在机器视觉任务中，缺陷是基于人类经验的概念，而不是纯粹的数学定义。
基于深度学习的工业品组件缺陷检测技术（一）
qq_54000005的博客
06-25 1457
数据预处理
评论 4
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

yaoxin521123

谢谢您的支持！

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值