cmake函数参数解析

转自： http://blog.csdn.net/sakaue/article/details/38377661

最近在迁移公司的make系统到cmake上，发现cmake的function参数很奇怪。例如，如果我们向一个function传递list作为参数，在function中，形参会变成如下状况：

set(SRC)  
list(APPEND SRC a.cpp b.cpp)  
list(APPEND SRC c.cpp d.cpp)  
  
function(tst_arguments src_list)  
    message("src_list = "${src_list})  
endfunction()  
  
message("SRC = "${SRC})  
tst_arguments(${SRC})  
  
==== output ====  
SRC = a.cppb.cppc.cppd.cpp  
src_list = a.cpp  

很奇怪的是，这里的${SRC}在function外是完整的4个元素，而在function却只剩下了头一个元素（可能跟list的定长有关）。如果我们要传给function以n个源文件组成的list，这样显然不行。

          一种简单的解决方法是使用ARGV，ARGC配合，他们的含义如同C/C++中main的argv和argc，分别代表参数和参数个数，使用如下方法解析参数：

function(tst_arguments src_list)  
    message("ARGC = "${ARGC})  
    message("ARGV = "${ARGV})  
  
    set(INDEX 0)  
      
    while(INDEX LESS ${ARGC})  
        message("ARG = "${ARGV${INDEX}})  
        math(EXPR INDEX "${INDEX} + 1")  
    endwhile()  
endfunction()  
  
tst_arguments(${SRC})  
  
==== output ====  
ARGC = 4  
ARGV = a.cppb.cppc.cppd.cpp  
ARG = a.cpp  
ARG = b.cpp  
ARG = c.cpp  
ARG = d.cpp   

当然，你也可以使用cmake的foreach循环遍历参数。这招对付只有一个list的参数时十分有效，但是在出现多个参数的情况就很麻烦，如下：

#  
#假设函数link_lib将src_list中的源文件链接成库，根据type制定是链接静态库还是动态库  
#  
function(link_lib src_list type)  
  
        message("ARGC = "${ARGC})  
        message("ARGV = "${ARGV})  
          
        #以下根据参数的实际情做了操作，手动处理，以保证正确获取src_list和type  
        set(INDEX 0)  
        math(EXPR MAX "${ARGC} - 1")  
        while(INDEX LESS ${MAX})  
             #do something to link  
             math(EXPR INDEX "${INDEX} + 1")  
        endwhile()  
endfunction()  
  
link_lib(${SRC} , so)  
  
==== output ====  
ARGC = 5  
ARGV = a.cppb.cppc.cppd.cppso  

原来，ARG把两个参数混在了一起，虽然后面我们使用while进行了特殊处理，但是这对于cmake的函数不具备普遍性，移植起来很麻烦。

决定版的solution是使用cmake的cmake_parse_arguments来解析函数参数，它有点像解析一个map键值对，首先看下它的函数原型：

include (CMakeParseArguments)  #必须包含这个cmake文件才能使用cmake_parse_arguments
  
CMAKE_PARSE_ARGUMENTS(<prefix> <options> <one_value_keywords> <multi_value_keywords> args...)  

首先，prefix是一个前缀，等会儿在引用参数的时候会提到，<option>是一个列表，里面可以包含一些你感兴趣的KeyWord，随后可以通过它来看看你所需要的KeyWord是否被设置。 <one_value_keywords>是一个单值参数的KeyWord列表。 <multi_value_keywords> 是一个多值参数的KeyWord列表（如list），下面举个例子，看看如何使用它们，首先定义所需要的函数，由于参数是由 CMAKE_PARSE_ARGUMENTS来解析的，所以在函数声明中就不需要定义参数了：

function(tst_arguments)  
  CMAKE_PARSE_ARGUMENTS(  
    TEST "ISSET" "NAME;COMMAND;BASELINE"  
       "ARGSLIST"  
       ${ARGN}  
  )  
  
  message("TEST_DEFAULT_ARGS is ${TEST_DEFAULT_ARGS} from ${ARGN}")  
  message("TEST_NAME is ${TEST_NAME}")  
  message("TEST_COMMAND is ${TEST_COMMAND}")  
  message("TEST_ARGSLIST is ${TEST_ARGSLIST}")  
  message("TEST_BASELINE is ${TEST_BASELINE}")  
  message("TEST_ISSET is ${TEST_ISSET}") 
  
endfunction(tst_arguments)  

这里的前缀是TEST， <one_value_keywords>我们设置单值参数的KeyWord（NAME;COMMAND;BASELINE），这将在随后的函数调用中注明KeyWord和Value的关系，<multi_value_keywords>我们设置多值参数的KeyWord（"ARGSLIST"），调用函数：

test_arguments(  
    NAME  
      testiso  
    COMMAND  
      "RunMe"  
    ARGSLIST  
      ${SRC}  
    BASELINE  
      "/home/sakaue/iWork"
    ISSET
)  
  
==== output ====  
TEST_DEFAULT_ARGS is  from NAME;testiso;COMMAND;RunMe;ARGSLIST;a.cpp;b.cpp;c.cpp;d.cpp;BASELINE;/home/sakaue/iWork  
TEST_NAME is testiso  
TEST_COMMAND is RunMe  
TEST_ARGSLIST is a.cpp;b.cpp;c.cpp;d.cpp  
TEST_BASELINE is /home/sakaue/iWork  
TEST_ISSET is TRUE