3D优化之ShadowGun系列二：浓烟，使用面片模拟粒子效果

先看效果：

看一下网格模型：

这就是个面片模型，越靠近边缘的地方，alpha值越低。所以烟有变淡的感觉。

如图：

注意箭头指的地方，面片这里故意做了个折角，这样让烟看起来更有在某个位置受风改变方向的感觉。

看shader参数：

两张贴图，一张做base，一张做2nd。

分别控制：

上面12个参数，控制的是两张贴图的使用方式，

修改的都是uv，speed是x，y方向的滚动速度，amplitude是x，y方向上sin的偏移幅度。freq是x,y方向上uv的频率。

最后两个：

color控制整体颜色变化，Multiplier控制的是颜色再提升的次数。

整体shader的注释：

Shader "MADFINGER/Environment/Scroll 2 Layers Sine AlphaBlended" {
Properties {
    _MainTex ("Base layer (RGB)", 2D) = "white" {}
    _DetailTex ("2nd layer (RGB)", 2D) = "white" {}
    _ScrollX ("Base layer Scroll speed X", Float) = 1.0
    _ScrollY ("Base layer Scroll speed Y", Float) = 0.0
    _Scroll2X ("2nd layer Scroll speed X", Float) = 1.0
    _Scroll2Y ("2nd layer Scroll speed Y", Float) = 0.0
    _SineAmplX ("Base layer sine amplitude X",Float) = 0.5 
    _SineAmplY ("Base layer sine amplitude Y",Float) = 0.5
    _SineFreqX ("Base layer sine freq X",Float) = 10 
    _SineFreqY ("Base layer sine freq Y",Float) = 10
    _SineAmplX2 ("2nd layer sine amplitude X",Float) = 0.5 
    _SineAmplY2 ("2nd layer sine amplitude Y",Float) = 0.5
    _SineFreqX2 ("2nd layer sine freq X",Float) = 10 
    _SineFreqY2 ("2nd layer sine freq Y",Float) = 10
    _Color("Color", Color) = (1,1,1,1)
    
    _MMultiplier ("Layer Multiplier", Float) = 2.0
}

    
SubShader {
    Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" }
    
    Blend SrcAlpha OneMinusSrcAlpha
    Cull Off Lighting Off 
    ZWrite On Fog { Color (0,0,0,0) }
    
    LOD 100
    
    
    
    CGINCLUDE
    #pragma multi_compile LIGHTMAP_OFF LIGHTMAP_ON
    #pragma exclude_renderers molehill    
    #include "UnityCG.cginc"
    sampler2D _MainTex;
    sampler2D _DetailTex;

    float4 _MainTex_ST;
    float4 _DetailTex_ST;
    
    float _ScrollX;
    float _ScrollY;
    float _Scroll2X;
    float _Scroll2Y;
    float _MMultiplier;
    
    float _SineAmplX;
    float _SineAmplY;
    float _SineFreqX;
    float _SineFreqY;

    float _SineAmplX2;
    float _SineAmplY2;
    float _SineFreqX2;
    float _SineFreqY2;
    float4 _Color;

    struct v2f {
        float4 pos : SV_POSITION;
        float4 uv : TEXCOORD0;
        fixed4 color : TEXCOORD1;
    };

    
    v2f vert (appdata_full v)
    {
        v2f o;
        o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
        o.uv.xy = TRANSFORM_TEX(v.texcoord.xy,_MainTex) + frac(float2(_ScrollX, _ScrollY) * _Time);   //先给底图根据时间做uv滚动
        o.uv.zw = TRANSFORM_TEX(v.texcoord.xy,_DetailTex) + frac(float2(_Scroll2X, _Scroll2Y) * _Time); //uv 滚动
        
        o.uv.x += sin(_Time * _SineFreqX) * _SineAmplX;    //给底图x方向上做sin周期扰动
        o.uv.y += sin(_Time * _SineFreqY) * _SineAmplY; //底图y方向上做sin周期扰动
        
        o.uv.z += sin(_Time * _SineFreqX2) * _SineAmplX2;//2nd图的uv存在texcoord的zw中
        o.uv.w += sin(_Time * _SineFreqY2) * _SineAmplY2;
        
        o.color = _MMultiplier * _Color * v.color; //给最终的颜色乘以外面赋进来的color和Multiplier。
        return o;
    }
    ENDCG

    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
//        #pragma fragmentoption ARB_precision_hint_fastest        
        fixed4 frag (v2f i) : COLOR
        {
            fixed4 o;
            fixed4 tex = tex2D (_MainTex, i.uv.xy); //底图取xy
            fixed4 tex2 = tex2D (_DetailTex, i.uv.zw);//2nd图取zw
            
            //o = tex * tex2 * i.color;
            o=tex2*tex*i.color;
                        
            return o;
        }
        ENDCG 
    }    
}
}

效果图中箭头指的地方，有点泛红，这个也是在面片里控制的。

面片中，越靠近火源的点，color的值越偏红。如图：