ANSYS APDL实例01：动力学分析

问题描述：

一个铝制容器跌落到一块方形钢板上的动力学分析，已知容器是一个具有5个面的正方形容器，其边长为20in，容器壁厚为0.1in，并分别绕X轴、Y轴和Z轴旋转45°。桌面是一个边长为100in的正方形板，其厚度为0.1in。作用在容器上的载荷是容器本身的重力，它从距离桌面72in的位置落下。

铝材料性能为：弹性模量为10.3e6psi，泊松比为0.334，屈服应力为5000psi，切变模量为20000psi，密度为2.5e-4lb/in³。

钢材料性能为：弹性模量为30.0e6psi，泊松比为0.292，密度7.3e-4lb/in³。

由于在自由落下时，只有重力加速度，假设容器是从距离桌面20in处落下，并给容器一个初速度200in/s，模拟52in的自由落体。假设桌面是刚性的，容器具有双线性随动强化，遵守Von Mises屈服准则。

注意：该问题只能在ANSYS LS-DYNA求解器中分析。

APDL命令流：

FINISH
/CLEAR,START
KEYW,PR_STRUC,1          !指定为结构分析
KEYW,LSDYNA,1              !指定为LY-Dynamic分析
/PREP7
WPRO,,45,                          !分别绕坐标轴X、Y、Z旋转45°
WPRO,,,45
WPRO,45,,
WPSTYLE,,,,,,,,0                !关闭工作平面
BLOCK,-10,10,-10,10,-10,10, !生成一个正方体块
VDELE, 1                           !仅删除块留下面
/PNUM,AREA,1                 !显示面号
APLOT
ADELE, 4                          !删除编号为4的面
/REPLOT
ET,1,SHELL163                !定义单元类型
R,1 !定义实常数
RMODIF,1,1,,,0.1,,,,           !容器壁厚0.1
EDMP,RIGI,1,7,7               !为显示动力学分析定义材料属性
MP,DENS,1,7.3E-4             !定义钢材料密度
MP,EX,1,30E6                    !钢的弹性模量
MP,NUXY,1,0.292              !钢的泊松比
MP,DENS,2,2.5E-4             !定义铝的密度
MP,EX,2,10.3E6                 !铝的弹性模量
MP,NUXY,2,0.334              !铝的泊松比
TB,BKIN,2,,,,                     !定义双线性随动强化的材料属性
TBDATA,1,5000
TBDATA,2,20000
TYPE, 1                              !指定单元分析类型
MAT, 2                                !指定材料类型
REAL,1                               !指定实常数
MSHAPE,2,2D
MSHKEY,1                         !生成映射网格
AMESH,ALL                      !生成面网格
/VIEW,1,1,2,3                     !改变视角方向
/ANG,1
/PNUM,NODE,1                 !显示节点编号
MAT,1                                !指定为第一种材料钢
N,,-50,-20,-50,,,,                 !生成桌面的4个节点
N,,-50,-20,50,,,,
N,,50,-20,50,,,,
N,,50,-20,-50,,,,
E,53,54,55,56                     !生成桌面单元
EPLOT
ESEL,S,MAT,,2                  !选择定义为第2种材料的所有单元
NSLE,S                              !选择依附于单元的所有节点
CM,box,NODE                   !生成一个元件名
ALLSEL,ALL                     !选择所有的实体
ESEL,S,MAT,,1                  !选择指定为第1种材料的所有单元
NSLE,S                              !选择依附于单元的所有节点
CM,table,NODE                 !生成另一个元件名
ALLSEL,ALL
EDCGEN,ASTS,BOX,TABLE,0,0,0,0,0,,,,,0.1 !指定接触参数
FINISH
/SOL
EDVE,VELO,box,0,-200,0,0,0,0,,,,,, !给节点施加初始速度
*DIM,time,ARRAY,2,1,1,,,  !定义一个数组
*SET,time(2,1,1),1              !给数组赋值
*DIM,accg,ARRAY,2,1,1,,,
*SET,accg(1,1,1),386.4
*SET,accg(2,1,1),386.4
EDLOAD,ADD,ACLY,0,box,TIME,accg,0,,,,, !施加载荷
TIME,1.0,                           !设置载荷步结束时间
EDRST,50,                         !指定输出间隔
EDHTIME,50,                    !指定时间历程的输出间隔
EDDUMP,1,                       !指定输出的频率
EDENERGY,1,1,1,1           !指定能量损耗控制
SOLVE
EPLOT
/REPLOT,RESIZE
/VIEW,1,,,1                        !改变视角方向
/PNUM,AREA,0                 !关闭面的编号
/PNUM,NODE,0                !关闭节点的编号
FINISH
/POST1
SET,FIRST                        !读入第一个载荷步的数据
PLNS,S,EQV                     !图形显示Von Mises应力
ANDATA,0.5,,0,0,0,1,0,1    !生成一个动画
/ANFILE,SAVE,stress,AVI !生成动画文件
PLDI,,                               !图形显示位移变化
ANDATA,0.5,,0,0,0,1,0,0   !生成一个动画
/ANFILE,SAVE,displace,AVI !生成动画文件
FINISH
/POST26 !进入时间历程后处理器
/GROPTS,VIEW,1             !改变视图的显示
NSOL,2,27,U,Y,uy             !读出节点27在Y方向的位移
PLVAR,2,,,,,,,,,,
FINISH

结果动画：

跌落位移动画	跌落应力动画

参考文献：龚曙光、谢桂兰、黄云清. ANSYS参数化编程与命令手册[M].