AS3多线程入门（上）：搭建开发环境

最新的Flash 11.4出了多线程功能，现在就可以体验一把AS3的多线程开发。

我们需要准备的东西：

FlashDevelop-4.1.0-R2383.exe

flashplayer_11_sa.exe

flashplayer_11_sa_debug.exe

flex_sdk_4.6.0.23201B.zip

其中，Flash Player需要11.4版本的，（我用的是11.4 r402）。

安装Flash Develop，这个大家都会，一直“下一步”就行了。

把flex sdk解压缩到一个文件夹下，比如我的是D:\flex_sdk_4.6.0.23201B，然后把Flash Player的两个exe文件，复制到这个文件夹下。

打开Flash Develop，Project->New Project...，新建一个AS3 Project。

然后Projcet->Properties...，在对话框的Output选项卡中，找到Platform，在Flash Player的版本下拉列表中选择11.4，如图：

然后Tools->Program Settings...，会打开一个看起来很复杂的设置对话框，在左边找到AS3Context，在右边找Installed Flex SDKs，点击右边的小按钮打开一个对话框，在这个对话框里点Add，在右边的Path里边找到flex sdk的目录，比如我的就是D:\flex_sdk_4.6.0.23201B，然后OK关闭对话框。

不要关闭这个复杂的设置对话框，在左边再找到FlashViewer，在右边有个External Player Path，如果是空的就设置为刚才拷过去的flashplayer_11_sa_debug.exe，我刚才看到Flash Develop已经自带了一个，所以就不用改了。

打开D:\flex_sdk_4.6.0.23201B\frameworks\libs\player，这里看看，如果没有11.4文件夹，就新建一个文件夹，命名为11.4，然后网上下载一个playerglobal11_4.swc，重命名为playerglobal.swc拷进去，我在看的时候也是Flash Develop自己给添加好了的，所以我也不需要再改什么了。

好的，我们从网上（http://bbs.9ria.com/thread-144587-1-1.html）找到了一个源码，我们先保证项目中有一个Main.as，这个是主类，然后新建一个HelloWorldWorker.as类。

Main.as的代码如下：

package
{
import flash.display.Sprite;
import flash.events.Event;

/**
* ...
* @author
*/

public class Main extends Sprite
{
public function Main():void
{
if (stage)
init();
else
addEventListener(Event.ADDED_TO_STAGE, init);
}

private function init(e:Event = null):void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
// entry point

addChild(new HelloWorldWorker());

}

}

}

HelloWorldWorker.as的代码如下：

package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.system.MessageChannel;
import flash.system.Worker;
import flash.system.WorkerDomain;
import flash.utils.setInterval;

public class HelloWorldWorker extends Sprite
{
protected var mainToWorker:MessageChannel;
protected var workerToMain:MessageChannel;

protected var worker:Worker;

public function HelloWorldWorker()
{

this.addEventListener (Event.ADDED_TO_STAGE,init);
}

private function init(e:Event=null):void
{
removeEventListener (Event.ADDED_TO_STAGE,init);
/**
* Start Main thread
**/
if(Worker.current.isPrimordial){
//Create worker from our own loaderInfo.bytes
//worker = WorkerDomain.current.createWorker(this.loaderInfo.bytes);
worker = WorkerDomain.current.createWorker(parent.loaderInfo.bytes);

//Create messaging channels for 2-way messaging
mainToWorker = Worker.current.createMessageChannel(worker);
workerToMain = worker.createMessageChannel(Worker.current);

//Inject messaging channels as a shared property
worker.setSharedProperty("mainToWorker", mainToWorker);
worker.setSharedProperty("workerToMain", workerToMain);

//Listen to the response from our worker
workerToMain.addEventListener(Event.CHANNEL_MESSAGE, onWorkerToMain);

//Start worker (re-run document class)
worker.start();

//Set an interval that will ask the worker thread to do some math
setInterval(function(){
mainToWorker.send("ADD");
mainToWorker.send(2);
mainToWorker.send(2);
}, 1000);

}
/**
* Start Worker thread
**/
else {

//Inside of our worker, we can use static methods to
//access the shared messgaeChannel's
mainToWorker = Worker.current.getSharedProperty("mainToWorker");
workerToMain = Worker.current.getSharedProperty("workerToMain");
//Listen for messages from the mian thread
mainToWorker.addEventListener(Event.CHANNEL_MESSAGE, onMainToWorker);
}

}

//Main >> Worker
protected function onMainToWorker(event:Event):void {
var msg:* = mainToWorker.receive();
//When the main thread sends us HELLO, we'll send it back WORLD
if(msg == "HELLO"){
workerToMain.send("WORLD");
}
else if(msg == "ADD"){
//Receive the 2 numbers and add them together
var result:int = mainToWorker.receive() + mainToWorker.receive();
//Return the result to the main thread
workerToMain.send(result);
}
}

//Worker >> Main
protected function onWorkerToMain(event:Event):void {
//Trace out whatever message the worker has sent us.
trace("[Worker] " + workerToMain.receive());
}
}
}

保存后，调试运行，这时候你能看到大量的“[Worker] 4”从Output面板出来，Okay，成功了~~