最近看《Unity Shader入门精要》这本书,看到第七章的时候,作者分别实现了在切线空间和世界空间下的法线纹理映射,其中提到也可以在其他空间实现,于是来实践一下在模型空间的实现,代码如下:
Shader "Chapter7/NormalMapObjectSpace"
{
Properties
{
_Color("Color Tint", Color) = (1, 1, 1, 1)
_MainTex("Main Tex", 2D) = "white" {}
_BumpMap("Normal Map", 2D) = "bump" {}
_BumpScale("Bump Scale", Float) = 1.0
_Specular("Specular", Color) = (1, 1, 1, 1)
_Gloss("Gloss", Range(8.0, 256)) = 20
}
SubShader
{
Pass
{
Tags{"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 pos : SV_POSITION;
float4 uv : TEXCOORD0;
float4 TtoW0 : TEXCOORD1;
float4 TtoW1 : TEXCOORD2;
float4 TtoW2 : TEXCOORD3;
float3 lightDir : TEXCOORD4;
float3 viewDir : TEXCOORD5;
};
v2f vert (a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
float3 objPos = v.vertex.xyz;
fixed3 objNormal = v.normal;
fixed3 objTangent = v.tangent.xyz;
fixed3 objBinormal = cross(objNormal, objTangent) * v.tangent.w;
o.TtoW0 = float4(objTangent.x, objBinormal.x, objNormal.x, objPos.x);
o.TtoW1 = float4(objTangent.y, objBinormal.y, objNormal.y, objPos.y);
o.TtoW2 = float4(objTangent.z, objBinormal.z, objNormal.z, objPos.z);
o.lightDir = ObjSpaceLightDir(v.vertex).xyz;
o.viewDir = ObjSpaceViewDir(v.vertex).xyz;
return o;
}
fixed4 frag (v2f i) : SV_Target
{
float3 objPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
fixed3 lightDir = normalize(i.lightDir);
fixed3 viewDir = normalize(i.viewDir);
fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));
bump.xy *= _BumpScale;
bump.z = sqrt(1.0 - saturate(dot(bump.xy, bump.xy)));
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));
fixed3 halfDir = normalize(lightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss);
fixed3 color = ambient + diffuse + specular;
return fixed4(color, 1);
}
ENDCG
}
}
FallBack"Specular"
}
总体写法基本参考的是世界空间的写法,只不过坐标,法线,切线,光线角度,观察角度都是用的模型参数,最终呈现的效果也和其他两个空间一样,记录一下。