(5)ACS控制器Buffer程序记录与解析-第三方驱动器控制电机回零程序

代码如下（示例）：

INT NODE
INT T_AXIS ! Define a variable named of T_AXIS(R_AXIS)
T_AXIS=5! Define axis number (in this case: 4).
FCLEAR
rHomed=0
NODE=3
DISABLE T_AXIS
rHomed=1
EFAC(T_AXIS)=360/456704
SET FPOS(T_AXIS)=FPOS(T_AXIS)-EOFFS(T_AXIS)
! Servotronix CDHD Homing Procedure
ecin(ecgetoffset("Statusword",NODE),StatusWord)
ecout(ecgetoffset("Controlword",NODE),ControlWord)
coewrite/1 (NODE,0x6060,0,8)
wait 500
coewrite/1 (NODE,0x6060,0,6) !6 is Homing mode
I0=coeread/1 (NODE,0x6061,0)
coewrite/1 (NODE,0x6098,0,34) !Homing Method
coewrite/4 (NODE,0x609A,0,50000)!Home Acceleration
ControlWord=6
TILL StatusWord.0=1
ControlWord=7
TILL StatusWord.0=1 & StatusWord.1=1
ControlWord=15
TILL StatusWord.0=1 & StatusWord.1=1 & StatusWord.2=1
!Start Homing Procedure - Bit 4
ControlWord=271
WAIT 200
ControlWord=31
WAIT 200
TILL StatusWord.12=1 & StatusWord.10=1
ControlWord=0
ECUNMAPIN(ecgetoffset("Statusword",NODE))
ECUNMAPOUT(ecgetoffset("Controlword",NODE))
wait 200
coewrite/1 (NODE,0x6060,0,8) !go back to CSP mode
DISABLE T_AXIS
WAIT 50
VEL(T_AXIS)= 30! Set maximum velocity.
ACC(T_AXIS)= 300! Set acceleration.
DEC(T_AXIS)= 300! Set deceleration.
KDEC(T_AXIS)= 3000
JERK(T_AXIS)= 3000! Set jerk.
ENABLE T_AXIS
WAIT 50
PTP/E T_AXIS,0
TILL ^AST(T_AXIS).#MOVE! Wait till motor reaches the index.
SET FPOS(T_AXIS)=FPOS(T_AXIS)-0
rHomed=2
STOP

重要参数修改
1、NODE=3 这个为ACS网络中驱动器的EtherCAT的网络位置
2、EFAC(T_AXIS)=360/456704 这个是DD马达转一圈的脉冲数，这个需要根据实际情况设置
3、StatusWord ControlWord这两个参数有些时候会报错，我们需要进入终端输出#ETHERCAT这个命令，然后分别复制这两个参数然后替换Buffer程序里面原来有的所有的参数，编译后便能解决
4、coewrite/1 (NODE,0x6060,0,6) !6 is Homing mode这个是设置第三方驱动器的模式，这里6是回零模式
5、coewrite/1 (NODE,0x6098,0,34) !Homing Method这个是驱动器内部回零的方式，需要查看驱动器手册