AS3实现单例模式举例

在面向对象的编程中，有时候会要求一个类有且仅存在一个实例，并提供一个全局的访问方法。所以我们在设计这样的类的时候，就需要思考如何避开构造函数，提供
一种机制来实现单例（单一实例）。这就是单例模式。另因为在AS3中无法操作线程，因此我们无需考虑多线程情况下的单例。
单例模式的几种AS3实现

在AS3中有多种方法可以实现Singleton模式。

方法1：

package {
     public class Singleton {
         private static  var _instance:Singleton = new Singleton();
         public function Singleton() {
             if (_instance) {
                 throw new Error("只能用getInstance()来获取实例");
             }
         }
         public static function getInstance():Singleton {
            return _instance;
        }
   }
}

此方法通过静态私有变量_instance来创建Singleton类的实例，通过getInstance方法来访问这个单一实例。另外，由于在AS3中不允许private、protected的构造函数，
只能是public，因此需要防止用构造函数来创建Singleton类的实例。这个方法有个问题就是这个类的实例会在程序一开始就创建。

方法2：

package {
     public class Singleton {
         private static  var _singleton:Boolean=true;
         private static  var _instance:Singleton;
         public function Singleton() {
             if (_singleton) {
                 throw new Error("只能用getInstance()来获取实例");
             }
         }
        public static function getInstance():Singleton{
            if (!_instance) {
                _singleton=false;
                _instance=new Singleton();
                _singleton=true;
            }
            return _instance;
        }
    }
}

此方法通过一个静态私有变量_singleton来控制_instance的创建，保证其唯一性。并且这个方法不存在方法1中的问题，_instance实例只有在调用getInstance()方法
后才会创建。

方法3：

package {
     public class Singleton {
         private static  var singleton : Singleton;
         public function Singleton( caller : Function = null ) {
             if ( caller != hidden ) {
                 throw new Error("只能用getInstance()来获取实例");
             }
             if ( Singleton.singleton != null ) {
                 throw new Error("只能用getInstance()来获取实例");
            }
        }
        public static function getInstance():Singleton {
            if ( singleton == null ) {
                singleton = new Singleton( hidden );
            }
            return singleton;
        }
        private static function hidden():void {
        }
    }
}

此方法通过对构造函数增加参数来控制单个实例的创建。此构造函数只有传入参数为私有方法hidden的时候，才能创建实例。私有方法hidden对外的不可见性保证了单例
的实现。

方法4：

package {
     public class Singleton {
         private static  var _instance:Singleton;
         public function Singleton(singletoner:Singletoner) {
             if (singletoner == null) {
                 throw new Error("只能用getInstance()来获取实例");
             }
         }
         public static function getInstance():Singleton {
            if (_instance == null) {
                _instance = new Singleton(new Singletoner());
            }
            return _instance;
        }
    }
}
internal class Singletoner {
}

此方法和方法3相似。这里利用了包外类对外的不可见性（Singletoner类仅在此as文件内可见）来保证单例的实现。

本人经常用的模式：

public class Singleton{
        private static var instance:Singleton= null;
 
        public function Singleton(){
                if( instance == null ){
 
                }else{
                         throw new Error("Instance is alreally exist");                
                }
        }
 
        public static function getInstance():Singleton{
        	if( instance == null ){
            	instance = new Singleton();
            }
            return instance;
        }
}

还有一个很犀利的写法，我很喜欢，不过前提你自己以后再用到的时候要清楚这个是单例：

package{
public class Singleton{
 
        private static var _instance: Singleton=null;
        public  function Singleton(){
        }
        public static function getInstance():Singleton {
               return instance ||= new Singleton();
        }
    }
}