快速 android SDK 接入 Unity

      这几天常常在android平台下接sdk，因为要把sdk打包成jar包到unity中，这一系列操作很耗费时间并且又是重复性劳动，就想偷懒。

     我是在windows平台下工作的，打包jar包也是可以直接使用命令行，除了打包jar包以外的东西都是对文件的复制粘贴的工作，都是可以使用命令行来实现的。

总的来说windows平台下的cmd命令行和苹果的shell脚本相差不大，如果将来需要移植，那也是很容易的。

最后决定写了一个bat 批处理工具，下面就是windows的批处理文件内容。

rem 保持gbk编码

@echo off
rem Unity Android Plugins Path
set u_path=D:\U3d\chahu\chmj2.0\Assets\Plugins\Android
rem Eclipse Path
set e_path=D:\U3d\chahu\安卓工程_游戏包\chahu2.0

echo begin

rem ready
rmdir /q /s %u_path%

echo ________________________end..ready________________________




rem make jar
set temp_path=%u_path%\classes
set jar_name=androidPluginClass.jar
mkdir %temp_path%
xcopy /S /F  %e_path%\bin\classes %temp_path%\

rem remove garbage files
for /R %temp_path% %%s in (R.class,R$*.class,BuildConfig.class) do (
	del /q /s %%s
)

cd /D %temp_path%
jar -cvf %jar_name% *

rem mkdir %u_path%\bin\
xcopy /Y /S /F %temp_path%\%jar_name% %u_path%\bin\
cd..
rmdir /q /s %temp_path%

echo ________________________end..make jar________________________





rem copy libs
set temp_lib_path=%u_path%\tempLibPath
mkdir %temp_lib_path%
xcopy /S /F %e_path%\libs %temp_lib_path%

rem remove unity libs
for /R %temp_lib_path% %%s in (*classes.jar,libunity.so,libmain.so,libmono.so) do (
	del /q /s %%s 
)
xcopy /S /F %temp_lib_path% %u_path%\libs\
rmdir /q /s %temp_lib_path%

echo ________________________end..copy libs________________________




rem copy res and xml
set res=res
set xml=AndroidManifest.xml
xcopy /S /F %e_path%\%res% %u_path%\%res%\
copy %e_path%\%xml% %u_path%\

echo ________________________copy res and xml________________________

exit

如果有童鞋不知道android sdk怎么接入到unity中的，请参考momo大神的文章

有遇到报错的可以看我上一篇：http://blog.csdn.net/biospc/article/details/75332270