AS3中Object与Dictionary的区别 ！

AS3中的Dictionary类（flash.utils.Dictionary）是一个新的AS类。

Dictionary类和Object唯一的区别在于：

Dictionary对象可以使用非字符串作为键值对的键，而Object只能使用字符串做为键值对的键。

Dictionary 类用于创建属性的动态集合，该集合使用全等运算符 (===) 对非原始对象键进行键比较。 将对象用作键时，会使用对象的标识来查找对象，而不是使用在对象上调用 toString() 所返回的值。 Dictionary 集合中的原始（内置）对象（例如 Number）的行为方式与它们作为常规对象的属性时的行为方式相同。

构造方法：public function Dictionary(weakKeys:Boolean = false)

若要从 Dictionary 对象中删除键，请使用 delete 运算符。

以下用两个简单例子来说明具体的差别：

1、使用Object：

var a:Object = {val:135}
var b:Object = {val:248};   
//注意a,b是Object类型
var obj:Object = new Object();   
obj[a] = 1;        // 键为对象a,值为数字1
obj[b] = 2;        // 键为对象b,值为数字2

for(var p:Object in obj)
{
    trace(p);        // 输出键
    trace(obj[p]);    // 输出此键对应的值
}

输出结果：[object Object]  2

结果分析：
因为前面说了Object的键只能使用字符串，所以当我们使用Object来做键的时候，都会被转为[object Object]，
obj[a] = 1;
obj[b] = 2;
所以在这里，这两句代码的实际效果是这样的
obj["[object Object]"] = 1;
obj["[object Object]"] = 2;
当执行第二句代码的时候，实际上就是更新前面一个的值，所以才输出这样的结果也就不奇怪了。

2、使用Dictionary：

var a:Object = {val:135}
var b:Object = {val:248};   

var obj:Dictionary = new Dictionary();   
obj[a] = 1;        // 键为对象a,值为数字1
obj[b] = 2;        // 键为对象b,值为数字2

for(var p:Object in obj)
{
    trace(p);        // 输出键
    trace(obj[p]);    // 输出此键对应的值
    trace(p["val"]); // 输出键(Object)的val属性的值
}

输出结果：[object Object]  1   135 

[object Object]  2   248

 

结果分析：

因为Dictionary和Object的区别所在，可以使用任意类型数据做键，所以能得到我们想要的结果。

所在在平时我们使用Object或其子类的时候，如果键是字符串，也可以达到键值对的效果，

但当键需要Object时，就需要Dictionary了。

附： === strict equality运算符

测试两个表达式是否相等，但不执行自动数据转换。如果两个表达式（包括它们的数据类型）相等，则结果为 true。

全等运算符 (===) 与等于运算符 (==) 在以下三个方面相同：

• 数字和布尔值按值进行比较，如果它们具有相同的值，则视为相等。
• 如果字符串表达式具有相同的字符数，而且这些字符都相同，则这些字符串表达式相等。
• 表示对象、数组和函数的变量按引用进行比较。如果两个变量引用同一个对象、数组或函数，则它们相等。而两个单独的数组即使具有相同数量的元素，也永远不会被视为相等。

全等运算符 ( ===) 与等于运算符 ( ==) 仅在以下两个方面不同：

• 全等运算符仅针对数字类型（Number、int 和 uint）执行自动数据转换，而等于运算符 () 针对所有的原始数据类型执行自动数据转换。
• 在对 null 和 undefined 进行比较时，全等运算符返回 false。

示例：

var s1:String = "5"; 
var s2:String = "5"; 
var s3:String = "Hello"; 
var n:Number = 5; 
var b:Boolean = true; 
trace(s1 == s2); // true 
trace(s1 == s3); // false 
trace(s1 == n); // true 
trace(s1 == b); // false 
trace(s1 === s2); // true 
trace(s1 === s3); // false 
trace(s1 === n); // false 
trace(s1 === b); // false 
trace(s1 !== s2); // false 
trace(s1 !== s3); // true 
trace(s1 !== n); // true 
trace(s1 !== b); // true