Linux0.11源码学习-bootsect.s

Linux0.11源码学习-bootsect.s

BIOS—> bootsect.s —> setup.s —> System模块（head.s—>main.c）

整体说明

BIOS加载了bootsect程序到内存0x7c00处，然后bootsect程序将自身移动到内存的0x90000处，并跳转到移动后的代码相应位置处执行，这里执行的内容就包括将setup加载到紧随其后的位置，而且还执行了加载system的操作。这些都是通过BIOS中断来完成的。最后bootsect跳转到setup处执行。

bootsect.s

1. 为什么要加载到0x7c00
   这里来回答一下这几个问题，加载到0x7c00我们可以看成一个规范，因为BIOS占用了内存低地址，所以引导文件就选择这个位置来加载，更具体的解释可以参见《 为什么主引导记录的内存地址是0x7C00？ 》
2. 怎么移动自身？
   移动自身很简单有相应的汇编代码可以实现（具体下面的源码中会给出），只要理解当前程序只是内存中的比特信息而已，移动它并不会影响当前程序的执行
3. 为什么要移动到0x90000处？
   system代码要移动到0x10000,因此一定要大于0x10000 且 不会覆盖system代码的位置 ,得出的结果是 0x90000.
   0x90000=512K+0x10000.system会被加载到0x10000的位置，因为当时认为system代码长度不会超过512K，所以把bootsect移到0x90000位置处是安全的。
4. 为什么使用BIOS中断加载setup.s到它的后面.
   因为bootsect要想加载文件需要文件系统的帮助，现在显然还不具备条件，其实这时采用的是BIOS的int 0x13号中断向量来处理的加载，前面的bootsect的加载使用的是int 0x19中断向量。前者与后者的不同之处在于前者可以在程序中指定需要加载的程序所在的扇区，而后者是由BIOS执行的，它只能固定的加载软盘第一扇区的代码

!
! SYS_SIZE is the number of clicks (16 bytes) to be loaded.
! 0x3000 is 0x30000 bytes = 196kB, more than enough for current
! versions of linux
!
SYSSIZE = 0x3000  ## 左移4位置等于 3*16^4= 192 kB  ，
!
!   bootsect.s      (C) 1991 Linus Torvalds
!
! bootsect.s is loaded at 0x7c00 by the bios-startup routines, and moves
! iself out of the way to address 0x90000, and jumps there.
!
! It then loads 'setup' directly after itself (0x90200), and the system
! at 0x10000, using BIOS interrupts. 
!
! NOTE! currently system is at most 8*65536 bytes long. This should be no
! problem, even in the future. I want to keep it simple. This 512 kB
! kernel size should be enough, especially as this doesn't contain the
! buffer cache as in minix
!
! The loader has been made as simple as possible, and continuos
! read errors will result in a unbreakable loop. Reboot by hand. It
! loads pretty fast by getting whole sectors at a time whenever possible.
/*
cs的值左移4位加上pc值等于执行的,最终地址.
*/
;定义了一些界定位置的量
SETUPLEN = 4                ! 加载的扇区数
BOOTSEG  = 0x07c0           ! original address of boot-sector 7*16^3+12*16^2 =31k
INITSEG  = 0x9000           ! 会将 boot-sector移动到此处 9*16*4 = 576k
SETUPSEG = 0x9020           ! setup 会加载到这里 INITSEG  + 512
SYSSEG   = 0x1000           ! system loaded at 0x10000 (65536).
ENDSEG   = SYSSEG + SYSSIZE     ! where to stop loading

!这里的ROOT_DEV是根文件系统设备号。
ROOT_DEV = 0x306

entry _start  ！程序入口
_start:
!这里就是实现把bootsect程序从0x7c00移到0x9000处。这里的rep执行执行过程就是从ds[di]移动内容到es[ei]，总共执行ecx次
    mov ax,#BOOTSEG   		！ax寄存器的值设置为0x07c0
    mov ds,ax            	！ds(数据段)寄存器的值设置为0x07c0
    mov ax,#INITSEG			！ax寄存器的值设置为 0x9000
    mov es,ax             	！es寄存器的值设置为 0x9000
    mov cx,#256         	！ cx寄存器的值设为256 ，表示循环次数,
    sub si,si               ！ si寄存器 置0  源地址 ds:si = 0x07C0:0x0000
    sub di,di      			！ di寄存器 置0  目的地址 es:di = 0x9000:0x0000
    rep                 	！ 循环，每循环一次cx减1  
    movw  					！移动一个字， 8086 字长16bit，两个字节，总共移动512字节
!跳转到0x9000：go处执行。这里的涉及到分段机制与寻址的关系。8086是16位CPU，而地址总线是20位，采用段基址加偏移的方式寻址
    jmpi    go,INITSEG		！跳转到go 并将cs 设为0x9000

!这里可以看到数据段寄存器，附加段寄存器，堆栈段寄存器里面都指向了代码段，也就是没有分段，cs段寄存器则是在上面的跳转过程中自动设置的，指向0x90000
go: mov ax,cs       		！后面三句 把ds es都设为0x9000
    mov ds,ax
    mov es,ax
! put stack at 0x9ff00.
    mov ss,ax
    mov sp,#0xFF00      	! arbitrary value >>512

! load the setup-sectors directly after the bootblock.
! Note that 'es' is already set up.

!load_setup用途是利用 BIOS 中断 INT 0x13 将 setup 模块从磁盘第 2 个扇区
! 开始读到 0x90200 开始处，共读 4 个扇区。如果读出错，则复位驱动器，并
! 重试，没有退路。INT 0x13 的使用方法如下：
! 读扇区：
! ah = 0x02 - 读磁盘扇区到内存；al = 需要读出的扇区数量；
! ch = 磁道(柱面)号的低 8 位； cl = 开始扇区(0-5 位)，磁道号高 2 位(6-7)；
! dh = 磁头号； dl = 驱动器号（如果是硬盘则要置位 7）；
! es:bx ?指向数据缓冲区； 如果出错则 CF 标志置位。

!以 第0个驱动器，第0个磁头，第2个扇区，第0个磁道，内存地址512b，结束地址512+SETUPLEN 作为参数调用BIOS中断，读取相应setup的内容。
!这里我们又解答了上面的一个疑问，为什么要用BIOS中断，因为这时内核还没有初始化，也就无法响应中断，只能采用BIOS中断。
!这也是为什么我们不能把程序加载到内存地址从0开始的位置，因为那里还要为BIOS所使用
//因为第一个扇区存放着bootsect.s 事实上第一个分区不止存放着引导文件
load_setup: ！加载setup模块
    mov dx,#0x0000      ! drive 0, head 0
    mov cx,#0x0002      ! sector 2, track 0
    mov bx,#0x0200      ! address = 512, in INITSEG 在前面已经将es设置为0x9000
    mov ax,#0x0200+SETUPLEN ! service 2, nr of sectors
    int 0x13            ! read it
    jnc ok_load_setup       ! ok - continue
    mov dx,#0x0000
    mov ax,#0x0000      ! reset the diskette
    int 0x13
    j   load_setup

ok_load_setup:

! Get disk drive parameters, specifically nr of sectors/track

    mov dl,#0x00
    mov ax,#0x0800      ! AH=8 is get drive parameters
    int 0x13
    mov ch,#0x00
    seg cs
    mov sectors,cx
    mov ax,#INITSEG
    mov es,ax

! Print some inane message    这里是往屏幕打印一些字符
! 通过BIOS中断读取鼠标位置，并输出文字信息
    mov ah,#0x03        ! read cursor pos
    xor bh,bh
    int 0x10
    
    mov cx,#24   		！ 打印字符的数量
    mov bx,#0x0007      ! page 0, attribute 7 (normal)
    mov bp,#msg1        ！ bp指想msg1 ，这个是下一步要实验的该的地方
    mov ax,#0x1301      ! write string, move cursor
    int 0x10            ！显示器中断

! ok, we've written the message, now
! we want to load the system (at 0x10000)
! 附加段寄存器指向0x010000，然后读取文件。
    mov ax,#SYSSEG    	 ！将ax寄存器设为0x1000
    mov es,ax      		 ! segment of 0x010000 
    call    read_it      ！ 加载system模块
    call    kill_motor

! After that we check which root-device to use. If the device is
! defined (!= 0), nothing is done and the given device is used.
! Otherwise, either /dev/PS0 (2,28) or /dev/at0 (2,8), depending
! on the number of sectors that the BIOS reports currently.

    seg cs
    mov ax,root_dev
    cmp ax,#0
    jne root_defined
    seg cs
    mov bx,sectors
    mov ax,#0x0208      ! /dev/ps0 - 1.2Mb
    cmp bx,#15
    je  root_defined
    mov ax,#0x021c      ! /dev/PS0 - 1.44Mb
    cmp bx,#18
    je  root_defined
undef_root:
    jmp undef_root
root_defined:
    seg cs
    mov root_dev,ax

! after that (everyting loaded), we jump to
! the setup-routine loaded directly after
! the bootblock:

    jmpi    0,SETUPSEG

! This routine loads the system at address 0x10000, making sure
! no 64kB boundaries are crossed. We try to load it as fast as
! possible, loading whole tracks whenever we can.
!
! in:   es - starting address segment (normally 0x1000)
!
sread:  .word 1+SETUPLEN    ! sectors read of current track
head:   .word 0         ! current head
track:  .word 0         ! current track

read_it:
    mov ax,es
    test ax,#0x0fff
die:    jne die         ! es must be at 64kB boundary
    xor bx,bx       ! bx is starting address within segment
rp_read:
    mov ax,es
    cmp ax,#ENDSEG      ! have we loaded all yet?
    jb ok1_read
    ret
	!判断读取的内容是否已经达到ENDSEG,也就是说system是否已经加载完毕，如果没有读完就继续读，如果读完就返回。
	!整个加载system的过程比较复杂，我们在此加以总结：首先在ok1_read中进行判断即将读取的数据是否超过64KB，
	!如果不超过就调用ok2_read继续读取，如果超过说明之前的操作出了问题，那么重新读取之前的扇区以期望下次可以恢复正常。
	!在ok2_read中实际进行了读盘操作，读完之后需要判断下次读取的位置，首先看一下当前磁道是否读完，如果没有读完，
	!就调用ok3_read继续读取；如果当前磁道读完了，需要判断当前的磁头，如果当前是磁头0，那么下次读取磁头1的同一个磁道；
	!如果当前是磁头1那么下一次就需要读取磁头0的下一个磁道。接下来根据之前实际读盘返回的数据进行判断如果目前已经读取了64KB的数	据，
	!就更新es段寄存器，并复位bx寄存器；接下来继续调用rp_read，在这里面判断是不是已经加载完毕，
	!如果没有，继续回到ok1_read重复整个过程。

ok1_read:
    seg cs
    mov ax,sectors
    sub ax,sread
    mov cx,ax
    shl cx,#9
    add cx,bx
    jnc ok2_read
    je ok2_read
    xor ax,ax
    sub ax,bx
    shr ax,#9
ok2_read:
    call read_track
    mov cx,ax
    add ax,sread
    seg cs
    cmp ax,sectors
    jne ok3_read
    mov ax,#1
    sub ax,head
    jne ok4_read
    inc track
ok4_read:
    mov head,ax
    xor ax,ax
ok3_read:
    mov sread,ax
    shl cx,#9
    add bx,cx
    jnc rp_read
    mov ax,es
    add ax,#0x1000
    mov es,ax
    xor bx,bx
    jmp rp_read



sectors:
    .word 0

msg1:
    .byte 13,10     ！13是ascii码的回车键 10是ascii的换行符
    .ascii "Loading system ..."
    .byte 13,10,13,10   ！两次回车加换行