安装好,相应的环境之后,我们便可以开始创建cocos2d-x 的android 工程了
进入cocs2d-x目录,用文本编辑器打开create-android-project.bat(在Win7上如果正常双击,可能创建时有些文件的权限不足,导致创建工程不成,可以在此文件的第一行加上cd /d %~dp0,然后右键以管理员身份运行)
找到以下几个定义:
@echo off
:: This script is used to create an android project.
:: You should modify _ANDROIDTOOLS _CYGBIN _NDKROOT to work under your environment.
:: Don't change it until you know what you do.
cd /d %~dp0
setlocal
:: Check if it was run under cocos2d-x root
if not exist "%cd%\create-android-project.bat" echo Error!!! You should run it under cocos2dx root & pause & exit 2
if not exist "%~dpn0.sh" echo Script "%~dpn0.sh" not found & pause & exit 3
:: modify it to work under your environment
set _CYGBIN=F:\Cygwin\bin
if not exist "%_CYGBIN%" echo Couldn't find Cygwin at "%_CYGBIN%" & pause & exit 4
:: modify it to work under your environment
set _ANDROIDTOOLS=F:\Android\sdk\tools
if not exist "%_ANDROIDTOOLS%" echo Couldn't find android sdk tools at "%_ANDROIDTOOLS%" & pause & exit 5
:: modify it to work under your environment
set _NDKROOT=F:\Android\ndk\ndk-r7
if not exist "%_NDKROOT%" echo Couldn't find ndk at "%_NDKROOT%" & pause & exit 6
:: create android project
set /P _PACKAGEPATH=Please enter your package path. For example: org.cocos2dx.example:
set /P _PROJECTNAME=Please enter your project name:
if exist "%CD%\%_PROJECTNAME%" echo "%_PROJECTNAME%" exists, please use another name & pause & exit 7
echo "Now cocos2d-x suppurts Android 2.1-update1, 2.2, 2.3 & 3.0"
echo "Other versions have not tested."
call "%_ANDROIDTOOLS%\android.bat" list targets
set /P _TARGETID=Please input target id:
set _PROJECTDIR=%CD%\%_PROJECTNAME%
echo Create android project
mkdir %_PROJECTDIR%
echo Create Android project inside proj.android
call "%_ANDROIDTOOLS%\android.bat" create project -n %_PROJECTNAME% -t %_TARGETID% -k %_PACKAGEPATH% -a %_PROJECTNAME% -p %_PROJECTDIR%\proj.android
call "%_ANDROIDTOOLS%\android.bat" update project -l ../../cocos2dx/platform/android/java -p %_PROJECTDIR%\proj.android
:: Resolve ___.sh to /cygdrive based *nix path and store in %_CYGSCRIPT%
for /f "delims=" %%A in ('%_CYGBIN%\cygpath.exe "%~dpn0.sh"') do set _CYGSCRIPT=%%A
:: Resolve current dir to cygwin path
for /f "delims=" %%A in ('%_CYGBIN%\cygpath.exe "%cd%"') do set _CURRENTDIR=%%A
:: Resolve ndk dir to cygwin path
for /f "delims=" %%A in ('%_CYGBIN%\cygpath.exe "%_NDKROOT%"') do set _NDKROOT=%%A
:: Throw away temporary env vars and invoke script, passing any args that were passed to us
endlocal & %_CYGBIN%\bash --login "%_CYGSCRIPT%" %_CURRENTDIR% %_PROJECTNAME% %_NDKROOT% %_PACKAGEPATH% "windows"
pause
将_CYGBIN=设置为cycgwin\bin安装的的绝对路径。
将_ANDROIDTOOLS设置为android sdk 的tools绝对路径
将_NDKROOT设置为android ndk的绝对路径
修改完毕,保存后
双击create-android-project.bat开始工程创建向导
首先是输入包名(建议按照android的命名规则),如com.android.test
然后输入工程名称(注意不要输入已有的文件夹的名字,如果同名,会被覆盖掉的),如testandroid,如下图:
然后选择target id,
其会列出机器上安装的所有版本的sdk,我们选择6,即2.3.2的sdk.
进入g:\cocos2d-x目录发现多了一个名为testandroid的目录,里面包含三个目录
其中Classes:是存放默认工程的C++文件
proj.android 是android的eclipse工程项目
Resources 资源文件
下来我们开始编译刚创建的testandroid项目
打开cygwin,进入到testandroid/proj.android目录,输入 ./build_native.sh 开始编译如下图:
执行完毕,发现编译出错,如下图:
发现报的是文件 Permission denied 错误,考虑的是Win7的环境,我们看下jni/helloword/mai.cpp的文件的权限。
结果在进jni目录时,边报无权访问了,如下图:
我们不管,因为上面报的是具体文件(main.cpp)文件无权限,而非文件夹,说明编译器已经能访问到文件夹里面了,观察下main.cpp的文件权限:
发现当前用户(ming)都没有读写的权限,编译当然报错了。我们给它赋个完全控制的权限,如下:
点击应用,和确定,再次执行./build_native.sh
还是文件权限的问题,我们按之前的方法,重新赋权一下,再次编译,如果过程中发现还有类似的问题,赋权即可,我为了省麻烦,写了个快速赋权的注册表文件内容如下:(WinXP也有同样的拒绝访问的现象可以一样处理,只是下面文件中的icacls命令要全部改为cacls命令,因为XP下不能使用icacls命令只能用cacls命令,还好两者语法是一样的。如果缺少takeown命令的exe,可以到Win2003的系统文件夹复制或者从网上下载一个,放在本地的system32文件夹下即可。)
Windows Registry Editor Version 5.00
[HKEY_CLASSES_ROOT\*\shell\runas]
@="管理员取得所有权"
"NoWorkingDirectory"=""
[HKEY_CLASSES_ROOT\*\shell\runas\command]
@="cmd.exe /c takeown /f \"%1\" && icacls \"%1\" /grant administrators:F /e /c"
"IsolatedCommand"="cmd.exe /c takeown /f \"%1\" && icacls \"%1\" /grant administrators:F /e /c"
[HKEY_CLASSES_ROOT\exefile\shell\runas2]
@="管理员取得所有权"
"NoWorkingDirectory"=""
[HKEY_CLASSES_ROOT\exefile\shell\runas2\command]
@="cmd.exe /c takeown /f \"%1\" && icacls \"%1\" /grant administrators:F /e /c"
"IsolatedCommand"="cmd.exe /c takeown /f \"%1\" && icacls \"%1\" /grant administrators:F /e /c"
[HKEY_CLASSES_ROOT\Directory\shell\runas]
@="管理员取得所有权"
"NoWorkingDirectory"=""
[HKEY_CLASSES_ROOT\Directory\shell\runas\command]
@="cmd.exe /c takeown /f \"%1\" /r /d y && icacls \"%1\" /grant administrators:F /t /e /c"
"IsolatedCommand"="cmd.exe /c takeown /f \"%1\" /r /d y && icacls \"%1\" /grant administrators:F /t /e /c"
WinXP下所需的 takeown.exe 和grantRegedit.reg文件链接于此。
以管理员身份运行这个文件后,就可以为Win7右键添加取得所有权的菜单(WinXP也一样)。如下图:
如果再次出现有访问权限的问题,右键点击下目录,选择管理员取得所有权。弹出的对话框中选择“当前用户”且不要勾选“保护我的计算机和数据不受未授权程序的活动影响……”即可。
最后编译成功截图如下:
编译成功之后,会直接在testandroid\proj.android\libs\armeabi这个目录底下生成so文件(libgame.so)
编译完毕,下来就是在eclipse里面编译成apk文件,并安装运行一把。
1、将刚编译完的工程导入到eclipse中。
以管理员身份打开eclipse(因为之前都是以管理员身份获取的权限的,否则会出现编译时权限有问题的),选择FILE->New->Android Project,然后选择如下:
运行该工程,右键该工程,选择Run as ->android application(从cocos2d-2.0-rc0a-x-2.0起,支持了open gl es2.0,默认的工程创建是要求运行于open gl es2.0上的,即目前模拟器还未支持,所以必须用真机去调试)
如下: