忘记在哪里找的的shader了,有的我做了简单的修改,有的我只是结合了一下,我会把以转载的方式发出来,以尊重原创开发。
这次的是找到的模型的“裁剪”效果,并不是真正的基于模型的裁剪,并不会影像碰撞等效果,而是基于渲染的裁剪,效果如下:
接下来上代码:
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
//消失效果
//by:puppet_master
//2017.8.11
Shader "SepShader/DissolveEffectX"
{
Properties{
_Diffuse("Diffuse", Color) = (1,1,1,1)
_DissolveColor("Dissolve Color", Color) = (0,0,0,0)
_MainTex("Base 2D", 2D) = "white"{}
_ColorFactor("ColorFactor", Range(0,1)) = 0.7//这个值什么时候光圈在最下边呢,当模型比例为1时最下端点到中心点的Y值差
_DissolveThreshold("DissolveThreshold", Float) = 0
}
CGINCLUDE
#include "Lighting.cginc"
uniform fixed4 _Diffuse;
uniform fixed4 _DissolveColor;
uniform sampler2D _MainTex;
uniform float4 _MainTex_ST;
uniform float _ColorFactor;
uniform float _DissolveThreshold;
struct v2f
{
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float2 uv : TEXCOORD1;
float4 objPos : TEXCOORD2;
};
v2f vert(appdata_base v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
o.objPos = v.vertex;//以模型坐标为标准
//o.objPos = mul(unity_ObjectToWorld, v.vertex);//以世界坐标为标准
return o;
}
fixed4 frag(v2f i) : SV_Target
{
float factor = i.objPos.z - _DissolveThreshold;//这句话我理解为相对于中心在Y方向上的值减去阈值
clip(factor);
//Diffuse + Ambient光照计算
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
fixed3 lambert = saturate(dot(worldNormal, worldLightDir));
fixed3 albedo = lambert * _Diffuse.xyz * _LightColor0.xyz + UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 color = tex2D(_MainTex, i.uv).rgb * albedo;
//等价于下面注释代码的操作
fixed lerpFactor = saturate(sign(_ColorFactor - factor));
return lerpFactor * _DissolveColor + (1 - lerpFactor) * fixed4(color, 1);
/*
if (factor < _ColorFactor)
{
return _DissolveColor;
}
return fixed4(color, 1);*/
}
ENDCG
SubShader
{
Tags{ "RenderType" = "Opaque" }
Pass
{
//不让模型穿帮,关掉了背面裁剪
Cull Off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
ENDCG
}
}
FallBack "Diffuse"
}
注:是基于哪个轴的裁剪需要修改片元着色器中的i.objPos的轴