virtual task
virtual function/task:
Systerm Verilog 中允许父类句柄指向子类对象(向上类型转换),那么子类相对父类扩展出来的方法,对父类句柄是不可见的。
假设子类和父类中都定义了同名的方法为 prints
那么 使用指向子类对象的父类句柄调用该prints方法,调用的实质是父类的prints方法
请看下例:
module test;
class dad;
task prints;
$display("IM DAD!");
endtask
endclass
class son extends dad;
task prints;
$display("IM SON!");
endtask
endclass
initial begin
dad dad1;
son son1;
son1 = new();
dad1 = son1;//父类句柄指向子类对象
dad1.prints();
end
endmodule
结果如下:可以看到调用的是父类的方法。
当在定义方法前加上vritual时,systemverilog会优先按照对象来寻找所调用的方法
(不使用virtual,则优先按照句柄寻找所调用的方法,如上例)
请看下例
module test;
class dad;
virtual task prints;
$display("IM DAD!");
endtask
endclass
class son extends dad;
virtual task prints;
$display("IM SON!");
endtask
endclass
initial begin
dad dad1;
son son1;
son1 = new();
dad1 = son1;//父类句柄指向子类对象
dad1.prints();
end
endmodule
结果如下:可以看到调用的是子类的方法。
注意:
在上面的例子中,我们制造了一个指向子类对象的父类句柄(向上类型转换)。
然后用“父类句柄.virtual方法”成功的调用了一个子类方法。
需要注意的是,完成这样操作的前提是,子类和父类中都有一个叫prints的同名方法。
不要试图使用 父类句柄 调用一个父类中不存在但是子类中存在的方法,那样编译器会报错。
向下类型转换
在上面的篇幅中已经说过,父类句柄指向子类对象,属于向上类型转换。
如果要让这个子类对象重新恢复被子类句柄指向,就要使用cast向下类型转换。
$cast(参数A:子类句柄,参数B:指向子类对象的父类句柄)
(向下类型转换成功的条件是,B的指向对象类型,和A的句柄类型 相同)
请看下例:
module test;
class dad;
task prints;
$display("IM DAD!");
endtask
endclass
class son extends dad;
task prints;
$display("IM SON!");
endtask
endclass
initial begin
dad dad1;
son son1;
son son2;
son1 = new();
dad1 = son1;//父类句柄指向子类对象
dad1.prints();
$cast(son2,dad1);
son2.prints();
end
endmodule
结果如下: