图片转换为Webp

Gif 动图 转 Webp【支持批量拖拽】

写了个批处理，把gif拖上去即可

@echo off

for %%i in (%*) do ( 
	if "%%~xi" EQU ".gif" (
		echo 开始转换【%%~nxi】 为 【%%~ni.webp】......
		@%~dp0bin\gif2webp "%%i" -o "%%~dpi%%~ni.webp" -q 35 -lossy -m 6 -mt
		echo.
	)
)

pause

-lossy 开启有损压缩
-q 75 图片质量百分之75%
-m 6 压缩方法0 到 6 越高越慢，越厉害。
有需要的话，压缩参数还可以自己调整。

静态图片转 Webp【支持批量拖拽】

这个也支持gif但是只会转一帧

@echo off
for %%i in (%*) do ( 
	rem 支持的文件： *.gif, *.jpg, *.bmp, *.png, *.tiff
	if "%%~xi"==".gif" call :foo %%i
	if "%%~xi"==".jpg" call :foo %%i
	if "%%~xi"==".bmp" call :foo %%i
	if "%%~xi"==".png" call :foo %%i
	if "%%~xi"==".tiff" call :foo %%i
)
pause&exit
	
rem 定义函数 
:foo
echo 开始转换【%~nx1】 为 【%~n1.webp】......
@%~dp0bin\img2webp "%1" -o "%~dp1%~n1.webp" -lossy
echo.

用到了 call + 标签 定义函数 foo
%0函数名
%1第1参数
%2第2参数
%3第3参数
类推

webp 转 png【支持批量拖拽】

@echo off

for %%i in (%*) do ( 
	if "%%~xi" EQU ".webp" (
		echo 开始转换【%%~nxi】 为 【%%~ni.png】......
		@%~dp0bin\dwebp "%%i" -o "%%~dpi%%~ni.png" -mt
		echo.
	)
)

pause

使用的工具

libwebp-1.1.0-windows-x64
http://downloads.webmproject.org/releases/webp/index.html
http://storage.googleapis.com/downloads.webmproject.org/releases/webp/libwebp-1.1.0-windows-x64.zip