漫反射实现 - UnityShader

有趣就行

已于 2022-09-23 19:25:48 修改

阅读量420

点赞数

分类专栏： Shader随笔文章标签： unity 游戏引擎

于 2022-09-18 19:41:42 首次发布

本文链接：https://blog.csdn.net/m0_52361859/article/details/126921827

版权

Shader随笔专栏收录该内容

13 篇文章 1 订阅

订阅专栏

漫反射分为两种实现

逐顶点漫反射（主要依靠顶点着色器，计算顶点的光照）
逐片元漫反射（主要依靠片元着色器，计算片元的光照）

使用的公式是兰伯特定律
$c_{diffuse} = (c_{light} \cdot m_{diffuse})\cos{\theta}\tag{1}$
$cos{\theta} = \widehat{n} \cdot \widehat{l}\tag{2}$

在兰伯特的基础上增加亮光（添加两个偏移）
$c_{diffuse} = (c_{light} \cdot m_{diffuse})( \widehat{n} \cdot \widehat{l} * 0.5 + 0.5)\tag{3}$

$c_{light}$ 是光线的颜色， $m_{diffuse}$ 是材质的颜色， $cos{\theta}$ 是指法线与光线方向的角度

逐顶点漫反射

Shader "Lit/DiffuseLitShader1"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
    }
    SubShader
    {
        Pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include <UnityCG.cginc>
            #include <UnityLightingCommon.cginc>
            #include <UnityShaderUtilities.cginc>

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 color : COLOR0;
            };

            fixed4 _Diffuse;

            //逐顶点漫反射
            v2f vert(a2v v)
            {
                v2f o;
                //设置裁剪空间
                o.pos = UnityObjectToClipPos(v.vertex.xyz);
                
                //得到环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                //从物体坐标的法向量变换到全局坐标的法向量
                float3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
                
                //光照方向
                fixed3 litDir = normalize(_WorldSpaceLightPos0.xyz);
                
                //兰伯特定律 c = (c * m) max(0, dot(n.normalize, l.normalize)) = (c * m) * cos
                //fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, litDir));

                //半兰伯特定理 c = (c * m)(0.5 * cos + 0.5), 可实现暗部增强亮光
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * (dot(worldNormal, litDir) * 0.5 + 0.5);
                

                o.color = ambient + diffuse;

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                return fixed4(i.color, 1.0);
            }
            ENDCG
        }
    }
    
    FallBack "Diffuse"
}

逐片元漫反射

Shader "Lit/DiffuseLitShader2"
{
    Properties
    {
        _Diffuse("Diffuse", Color) = (1, 1, 1, 1)
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include <UnityCG.cginc>
            #include <UnityShaderUtilities.cginc>
            #include <UnityLightingCommon.cginc>

            struct a2v
            {
                float4 pos : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float4 worldNormal : TEXCOORD0;
            };

            fixed4 _Diffuse;

            v2f vert(a2v v)
            {
                v2f o;
                
                //得到裁剪空间
                o.pos = UnityObjectToClipPos(v.pos.xyz);

                //获得世界空间的法向量，并保存在 uv 中
                o.worldNormal = float4(UnityObjectToWorldNormal(v.normal.xyz), 1.0);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                //得到 ambient
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                //gl 的 方向
                float3 litDir = normalize(_WorldSpaceLightPos0.xyz);

                //使用 兰伯特定律
                //fixed3 diffuse = _LightColor0.rgb * _Diffuse * saturate(dot(i.worldNormal.xyz, litDir));

                //使用 半兰伯特定律
                fixed3 diffuse = _LightColor0.rgb * _Diffuse * (dot(i.worldNormal.xyz, litDir) * 0.5 + 0.5);

                return fixed4(diffuse + ambient, 1.0);
            }
            ENDCG
        }
    }
    
    FallBack "Diffuse"
}