Unity3D边缘检测滤镜shader实现

实现思路

在屏幕空间下怎么判断一个像素点是边缘点呢？可以回想一下边缘点的特征，即边缘点附近一般亮度变化大。比如一个物体内部和背景的亮度，在边缘处一般会有肉眼可见的突变，我们只要检测出这种变化就能检测出边缘了。
检测方法就是取这个像素周围的一些像素，计算他们的亮度值之后进行比对，如果周围像素亮度值差异大，则判断为边缘，这也就是俗称的‘卷积’。当然在屏幕空间进行边缘检测总会有不准确的地方，这个是无法避免的。

代码实现

最重要的就是计算一个像素当前梯度值的函数了，这个梯度值就代表该像素附近像素的亮度变化，越大就代表亮度变化越大，越有可能是边缘。
具体操作需要声明两个数组，可以看成是3*3的二维数组，代表了以该像素为中心，周围围了一圈的9个像素。当然由于shader里二维数组的限制，所以我们这里用一维数组代替二维数组。
另外还需要分别计算横向和纵向的变化，所以才需要声明两个数组，同时要注意数组里所有数字的合要为1，这个数字代表了对应像素的权值。可以想象一下在9个亮度变化不大的像素中，只有对应的权值合为1，最后计算每个像素值的亮度进行加减之后，这个梯度值才会大致为1。
大致的计算过程就是依次遍历9个像素，用Luminance函数计算对应像素的亮度值，然后依次相加，这个最后的值就是该像素的梯度值了。

            half sobel(v2f i)
            {
                const half Gx[9] =
                {
                    -1, -2, -1,
                    0, 0, 0,
                    1, 2, 1
                };
                const half Gy[9] =
                {
                    -1, 0, 1,
                    -2, 0, 2,
                    -1, 0, 1
                };
                half texColor;
                half edgeX = 0;
                half edgeY = 0;
                for (int index = 0; index < 9; index++)
                {
                    texColor = Luminance(tex2D(_MainTex, i.uv[index]));
                    edgeX += texColor * Gx[index];
                    edgeY += texColor * Gy[index];
                }
                half edge = 1 - abs(edgeX) - abs(edgeY);

                return edge;
            }

在上面的计算中需要用到一个像素点附近的像素uv坐标，这里需要声明一个

half4 _MainTex_TexelSize;

unity就会自动填充单个像素的uv坐标差异了，接着进行计算就可以得到9个点的uv坐标
记得这里的9个点要和前面声明的数组顺序要对应。

o.uv[0] = uv + _MainTex_TexelSize.xy * half2(-1, -1);
o.uv[1] = uv + _MainTex_TexelSize.xy * half2(0, -1);
o.uv[2] = uv + _MainTex_TexelSize.xy * half2(1, -1);
o.uv[3] = uv + _MainTex_TexelSize.xy * half2(-1, 0);
o.uv[4] = uv + _MainTex_TexelSize.xy * half2(0, 0);
o.uv[5] = uv + _MainTex_TexelSize.xy * half2(1, 0);
o.uv[6] = uv + _MainTex_TexelSize.xy * half2(-1, 1);
o.uv[7] = uv + _MainTex_TexelSize.xy * half2(0, 1);
o.uv[8] = uv + _MainTex_TexelSize.xy * half2(1, 1);

在片元着色器中只要对比一下梯度和阈值，接着输出颜色即可。

fixed4 frag(v2f i) : SV_Target
 {
         fixed4 col = tex2D(_MainTex, i.uv[4]);
         half edge = sobel(i);

         if (edge > threshold)
             return col;
         else
             return fixed4(edgeColor, 1);
}

创建一个相机之后挂载脚本最后效果如下，可以看到屏幕空间的边缘查找其实不是特别精确，有很多杂点。

完整代码

屏幕后处理效果都需要一个c#脚本来配合。
c#脚本就是传一下参数

using UnityEngine;


[RequireComponent(typeof(Camera))]
public class EdgeDetection : MonoBehaviour
{
    public Shader shader;
    public Color edgeColor;
    public float threshold;

    private void OnRenderImage(RenderTexture src, RenderTexture dest)
    {
        Material material = new Material(shader);
        material.SetColor("edgeColor", edgeColor);
        material.SetFloat("threshold", threshold);

        Graphics.Blit(src, dest, material);
    }
}

shader代码

Shader "LX/edgeDetection"
{

    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        ZTest Always
        Cull Off
        Zwrite Off

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                half2 uv[9]:TEXCOORD0;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            half4 _MainTex_TexelSize;
            fixed3 edgeColor;
            float threshold;

            half sobel(v2f i)
            {
                const half Gx[9] =
                {
                    -1, -2, -1,
                    0, 0, 0,
                    1, 2, 1
                };
                const half Gy[9] =
                {
                    -1, 0, 1,
                    -2, 0, 2,
                    -1, 0, 1
                };
                half texColor;
                half edgeX = 0;
                half edgeY = 0;
                for (int index = 0; index < 9; index++)
                {
                    texColor = Luminance(tex2D(_MainTex, i.uv[index]));
                    edgeX += texColor * Gx[index];
                    edgeY += texColor * Gy[index];
                }
                half edge = 1 - abs(edgeX) - abs(edgeY);

                return edge;
            }

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                half2 uv = v.uv;
                o.uv[0] = uv + _MainTex_TexelSize.xy * half2(-1, -1);
                o.uv[1] = uv + _MainTex_TexelSize.xy * half2(0, -1);
                o.uv[2] = uv + _MainTex_TexelSize.xy * half2(1, -1);
                o.uv[3] = uv + _MainTex_TexelSize.xy * half2(-1, 0);
                o.uv[4] = uv + _MainTex_TexelSize.xy * half2(0, 0);
                o.uv[5] = uv + _MainTex_TexelSize.xy * half2(1, 0);
                o.uv[6] = uv + _MainTex_TexelSize.xy * half2(-1, 1);
                o.uv[7] = uv + _MainTex_TexelSize.xy * half2(0, 1);
                o.uv[8] = uv + _MainTex_TexelSize.xy * half2(1, 1);


                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.uv[4]);
                half edge = sobel(i);

                if (edge > threshold)
                    return col;
                else
                    return fixed4(edgeColor, 1);
            }
            ENDCG
        }
    }
}

另外代码也传到github仓库里了，大家也可以关注一下哦~
我的github